Test Foro de elhacker.net SMF 2.1

Buenas foro, tengo un script escrito en batch, el cual funciona bien, el tema es que necesito que cada vez que se ejecute ponga la fecha/hora de cuando se ejecuto.
Aqui les dejo el script, este script lo uso en una GPO de win2008 para saber q programas tienen instalados las pc clientes y se guarda en el servidor,

####################################
INICIO SCRIPT
####################################

@echo off
@echo.
@echo.
@echo.
@echo. ############################################################
@echo.             "Por Favor no cerrar, terminara en unos instantes."
@echo. ############################################################
@echo.
@echo.
@echo.
regedit /a %TEMP%\filename.reg "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
for /f "Skip=1 Tokens=*" %%i in ('type %TEMP%\Filename.reg') do set line="%%i"&call :parse
goto :EOF
:parse
set work=%line:~2,11%
set work=%work:"=%
If NOT "%work%" EQU "DisplayName" goto :EOF
set work=%line:~16,120%
set work=%work:"=%
@echo %work%
@echo %work% >> \\ruta a mi server\%COMPUTERNAME%.txt

###########################################
FIN SCRIPT
###########################################

Lo que hace este pequeño script lee una clave del registro donde se encuentran todos los programas instalados, crea un txt con el nombre de la pc cliente y dentro del txt guarda la salida.
Lo que deseo hacer es que cada vez que se ejecute este script a la salida txt le ponga la fecha y hora.
Por otro lado necesito concatenar este script con otro, osea hacer que este script llame a otro script, cual seria los comandos.

Mil Gracias

Pablo

Cita de: soptec en 23 Noviembre 2011, 17:28 PM
Lo que deseo hacer es que cada vez que se ejecute este script a la salida txt le ponga la fecha y hora.

Así de fácil:
Echo %Date% ^| %Time:~0,-6% >> \\ruta a mi server\%COMPUTERNAME%.txt

Cita de: soptec en 23 Noviembre 2011, 17:28 PM
Por otro lado necesito concatenar este script con otro, osea hacer que este script llame a otro script, cual seria los comandos.

Igual de fácil xD:
Call "Tu_Script.bat"


Espero que te sirva, saludos!

Mejora tu script así:

@echo off
setlocal enabledelayedexpansion
regedit /a filename.reg "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
for /f "tokens=2 delims==" %%a in ('type "filename.reg" ^| find /i "displayname"') do (
set "program=%%a"
set program=!program:"=!
echo Programa: !program!
)
goto:eof