saludos compañeros, verán estoy intentando lo siguiente en windows 8 he creado una carpeta y en ella tengo 2 archivos de texto, el primero se llama 1.txt y el segundo 2.txt dentro de 1.txt solo hay una linea que dice hola y en 2.txt tambien hay una sola linea pero dice chao
entonces he creado un batch con el siguiente codigo
@echo off
type 1.txt>>resp.txt
echo como_estas>>resp.txt
type 2.txt>>resp.txt
pause
y el resultado que obtengo en el archivo resp.txt es
holacomo_estas
chao
pero yo quiero que me salga
holacomo_estaschao
ya he intentado de todo y no lo he logrado por eso recurro a su gran ayuda gracias
Si no me equivoco se puede usar el comando edlin para borrar el salto de linea.
@Meine programmen
EDLIN es para XP
@tiernohack
Puedes crear un procedimiento para setear una variable añadiendo el texto que contienen los archivos, te pongo un ejemplo:
@echo off
Set "String="
REM Call :Append_String STRING_or_TEXTFILE
Call :Append_String "1.txt"
Call :Append_String "como_estas"
Call :Append_String "2.txt"
Echo %String%
Echo %String%>"Resp.txt"
Pause&Exit
:Append_String
If Not Exist "%~1" (
Set "String=%String%%~1"
) ELSE (
For /F "Usebackq Delims=" %%# in ("%~1") Do (
Call Set "String=%%String%%%%#"
)
)
GOTO:EOF
Output:
holacomo_estaschao
Presione una tecla para continuar . . .
Me sirvió muchas gracias ;-)
Nadie como tu EleKtro H@cker para aclarar dudas de batch ;-)
Saludos..!