Test Foro de elhacker.net SMF 2.1

Hola de nuevo, el caso es que necesito editar 291 archivos del tipo srt, que en base es practicamente es lo mismo que un txt, con extension diferente.

Bueno he leido este hilo para poder hacer sustitucion de palabras http://foro.elhacker.net/scripting/acciones_sobre_archivos_de_texto_batch-t242748.0.html. Sin embargo este codigo me da error y no me funciona:

Intento cambiar en el texto los puntos suspensivo con espacios por puntos suspensivos sin espacios.
@echo off
setlocal enabledelayedexpansion
for /f "tokens=* delims=" %%x in ('type C:\Users\Isra\Desktop\Cap 01 B.srt') do (
set linea=%%x
set linea=!linea:. . .=...!
call :show !linea!
)
goto:eof
:show
echo %* >> "C:\Users\Isra\Desktop\Cap 01 B mod.srt"
goto:eof

Alguna idea de que está pasando??

---

Elektro H@cker: No tienes que usar el botón "insertar cita" sinó el de "insertar código".

Cuando estés trabajando con archivos que tengan espacios en su nombre, es preferible agregar comillas dobles, así:
for /f "tokens=* delims=" %%x in ('type "C:\Users\Isra\Desktop\Cap 01 B.srt"') do (

Prueba si así te funciona.

Hola,

Desde luego el fallo en el code salta a la vista y con la corrección del compañero Leo es suficiente.

Pero aparte, Los archivos de subtitulos suelen contener caracteres especiales como el signo de exclamación, El cual lo "destruyes" por completo al habilitar la expansión, Y otros archivos caracteres que debes escapar (>) y/o reemplazar (¡¿ áéíóú ÁÉÍÓÚ ñ).

Ejemplo:
Juego de tronos.srt
00:24:44,884 --> 00:24:46,927
Los hombres cordero
son buenos esclavos!

Así que yo lo dejaría (como mínimo) así, Y ya tu haces los siguientes reemplazamientos necesarios de los caracteres:
@echo off
for /f "tokens=*" %%X in ('type "%userprofile%\Desktop\Cap 01 B.srt"') do (
set "linea=%%X"
Call :Replace
Call Echo %%Linea_final%% >> "%userprofile%\Desktop\Cap 01 B mod.srt"
)
Exit

:Replace
set "linea=%linea:. . .=...%"
set "linea=%linea:>=^>%"
set "linea=%linea:)=^)%"
Set "Linea_final=%LINEA%"
Goto:EOF

Saludos.

Gracias, lo voy a probar y os cuento, desconocía que pudiera insertar doble comilla dentro de otras comillas, no tengo tanto nivel ^^'.

Con respecto a lo del codigo en vez de quote, me ha kedao claro  :silbar:. No volverá a pasar.

@Leo Gutiérrez

Está probado y asi realiza su función aunque como dice EleKtro H@cker, se come ciertos caracteres

@EleKtro H@cker

El código que has puesto funciona pero se come el espacio antes de los numeros de la línea por lo que al editar el srt resultante en aegisub, me inserta todos los subtitulos en una sola linea.

Por cierto, mis srt están codificados en Unicode, podría automatizar el cambio a UTF-8??

Gracias de nuevo.

Cita de: ovichan en  4 Agosto 2012, 15:42 PM
El código que has puesto funciona pero se come el espacio antes de los numeros de la línea

El problema es que "For" no procesa las lineas en blanco de un archivo, Pero bueno por suerte, Como son solo números, Con esto queda arreglado:

@echo off
for /f "tokens=*" %%X in ('type "%userprofile%\Desktop\1.srt"') do (
set /A "linea=%%X" 2>NUL && Echo+ >>"%userprofile%\Desktop\Cap 01 B mod.srt"|| (set "linea=%%X")
Call :Replace
Call Echo %%Linea_final%% >> "%userprofile%\Desktop\Cap 01 B mod.srt"
)
pause
Exit


:Replace
set "linea=%linea:. . .=...%"
set "linea=%linea:>=^>%"
set "linea=%linea:)=^)%"
Set "Linea_final=%LINEA%"
Goto:EOF

Cita de: ovichan en  4 Agosto 2012, 15:42 PMmis srt están codificados en Unicode, podría automatizar el cambio a UTF-8??

No.
Aunque puedes usar el comando type:
Type archivo.srt > archivoNUEVO.srt
El cual automáticamente codifica en formato ANSI, Pero para convertirlo a UTF-8 no hay manera de hacerlo en Batch.
EDITO: Bueno en realidad, Batch por defecto guarda todo lo redireccionado en codificación ANSI...

¿Porque quieres que estén en formato utf-8? (UTF También es Unicode)

Bueno, Necesitas usar alguna herramienta de terceros por linea de comandos (Alguna hay, pero no recuerdo el nombre).
O adaptar este VBS para llamarlo desde Batch usando argumentos:

Cita de: GOOGLE

Código (vb) [Seleccionar] Expandir

Option Explicit

Sub Save2File (sText, sFile)
   Dim oStream
   Set oStream = CreateObject("ADODB.Stream")
   With oStream
       .Open
       .CharSet = "utf-8"
       .WriteText sText
       .SaveToFile sFile, 2
   End With
   Set oStream = Nothing
End Sub

' Example usage: '
Save2File "The data I want in utf-8", "test.txt"

Salu2

Vamos a probar, aunque no entiendo muy bien la linea

set /A "linea=%%X" 2>NUL && Echo+ >>"%userprofile%\Desktop\Cap 01 B mod.srt"|| (set "linea=%%X")

Estableces como variable aritmetica LINEA, pero 2>NUL no se que es ( en C sería 2 mayor que vacio). Lo siguiente seria insertarle la linea con el echo, redireccionar al archivo srt, pero la parte "|| (set "linea=%%X")"; tampoco le pillo.

En cuanto a codificacion del archivo es por aegisub pues al abrirlo me arroja el error: "Parsing Srt: Incomplete file". Si lo paso a UTF8 con notepad no hay problema al abrirlo.

Gracias

Cita de: ovichan en  4 Agosto 2012, 17:38 PM
no entiendo muy bien la linea

Código [Seleccionar] Expandir

set /A "linea=%%X" 2>NUL && Echo+ >>"%userprofile%\Desktop\Cap 01 B mod.srt"|| (set "linea=%%X")
Estableces como variable aritmetica LINEA, pero 2>NUL no se que es ( en C sería 2 mayor que vacio). Lo siguiente seria insertarle la linea con el echo, redireccionar al archivo srt, pero la parte "|| (set "linea=%%X")"; tampoco le pillo.

Exacto, Establezco la variable, Si el string no es númerico entonces el comando SET manda un código de error, Con "2>NUL" redireccionamos la salida del mensaje de error simplemente para que no aparezca en la consola y no moleste.

El "||" es el operador lógico de excepción (Lo que en C equivaldria a throw o catch, creo, No se "C"), Es decir, Que si el comando SET manda un código de error pues se procesa lo que está a la derecha  de las pipes, Y si no manda código de error, Se procesa solamente lo que está a la derecha del operador "&&".

Salu2

En C es try...catch. Mas o menos lo he pillado, es como los asserts. Bueno luego lo pruebo que estoy de bbk. Gracias

Todo bien excepto que el primer numero de linea, lo cambia de 1 a 0. Siendo el primer numero de linea el 0 y el siguiente que le sigue es el 2.

Edito: creo que debe interpretar el 1 como operando logico y lo transforma, o algo raro.

Cita de: ovichan en  6 Agosto 2012, 02:20 AM
Todo bien excepto que el primer numero de linea, lo cambia de 1 a 0. Siendo el primer numero de linea el 0 y el siguiente que le sigue es el 2.

Eso que comentas no me pasa a mi, Los números no se me cambian de orden, ¿Lo que quieres decir es que se agrega una primera linea en blanco, En el nuevo archivo? (Eso sí)

Bueno aparte de eso he encontrado un fallo que se me habia pasado, El problema aparece en las frases que llevan comas, Y es por como se interpretan las comas en el comando Set /A al intentar hacer la operación, Y el string final de las frases con comas no se llega a setear bien, Se setean como "0", Así que te lo hago de otro modo (Este lo he testeado mejor) Y mejoro generalmente el script un poco más:

@echo off

REM El código de páginas para no tener que manipular el string para reemplazar caracteres latinos.
CHCP 1250 >NUL

For /R %%# in (*.srt) Do (
Echo Procesando archivo "%%~nx#"
FOR /F "tokens=*" %%X in ('Type "%%#"') do (
Echo "%%X"| findstr /R ".[^0-9]." >NUL || (Echo+ >> "%TEMP%\%%~nx#.srt")
set "linea=%%X"
Call :Replace
Call Echo %%Linea_final%% >> "%TEMP%\%%~nx#.srt"
)
Type "%TEMP%\%%~nx#.srt" | MORE +1 > "%%~n#.MOD.%%~x#"
Del /Q "%TEMP%\%%~nx#.srt"
)
Exit


:Replace
set "linea=%linea:>=^>%"
set "linea=%linea:)=^)%"
set "linea=%linea:. . .=...%"
Set "Linea_final=%LINEA%"
Goto:EOF

Salu2

Gracias por tus esfuerzos ahora si que no me entero del codigo pero lo estudiare tranquilamente con una cervecita.

Los subs me quedan asi:

(http://s9.postimage.org/e7p6i6m1b/Captura.png)

Como ves, elimina el primer numero de linea.

Te pongo tu codigo, adaptado a mis necesidades por si la estoy pifiando, pero creo que no.

@echo off
setlocal enabledelayedexpansion

REM El código de páginas para no tener que manipular el string para reemplazar caracteres latinos.
CHCP 1250 >NUL

For /R %%# in (*.srt) Do (
Echo Procesando archivo "%%~nx#"
FOR /F "tokens=*" %%X in ('Type "%%#"') do (
Echo "%%X"| findstr /R ".[^0-9]." >NUL || (Echo+ >> "%TEMP%\%%~nx#.srt")
set "linea=%%X"
Call :Replace
Call Echo %%Linea_final%% >> "%TEMP%\%%~nx#.srt"
)
Type "%TEMP%\%%~nx#.srt" | MORE +1 > "%%~n#.MOD.%%~x#"
Del /Q "%TEMP%\%%~nx#.srt"
)
Exit
Exit

:Replace
set "linea=%linea:. . .=...%"
set "linea=%linea:¿ =¿%"
set "linea=%linea:¡ =¡%"
set "linea=%linea:Klilyn=Krilin%"
set "linea=%linea:Ginew=Ginyu%"
set "linea=%linea:>=^>%"
set "linea=%linea:)=^)%"
Set "Linea_final=%LINEA%"
Goto:EOF

Gracias

Cita de: ovichan en  6 Agosto 2012, 19:35 PM
Los subs me quedan asi:

Como ves, elimina el primer numero de linea.

Eso lo hice a propósito, Porque el script, Cuando encuentra un número identificador, Primero escribe una linea en blanco en el archivo MOD, Y luego escribe ese número, Así que por pura lógica la primera linea del archivo MOD siempre será una linea en blanco, Pero no comprendo porqué en las capturas que has puesto de tu SRT no sucede como debería :S

Pero bueno, Simplemente elimina lo que he marcado en rojo en la siguiente linea (Es el comando para comerse la primera linea del archivo MOD) y ya te debería funcionar como tú quieres:

CitarType "%TEMP%\%%~nx#.srt" | MORE +1 > "%%~n#.MOD.%%~x#"

Saludos

Sencillamente genial, me va a ser de gran ayuda. Ademas con esto tengo tarea para estudiar, no entiendo ni la mitad jeje. Gracias

Siento el repost pero he encontrado un fallo en la edicón de los subs, te pongo una captura:

(http://s7.postimage.org/c89oljnaj/Captura_subs.png)

Al parecer los signos de interrogacion de izquierdas (¿) los cambia a los de derechas (?). Cuando se encuentra signos exclamativos, lo procesa o no. Qué locura!!!  :laugh:

Cita de: ovichan en  7 Agosto 2012, 01:33 AM
he encontrado un fallo en la edicón de los subs
los signos de interrogacion de izquierdas (¿) los cambia a los de derechas (?).
Cuando se encuentra signos exclamativos, lo procesa o no. Qué locura!!!  :laugh:

Hola,

El último script que puse funciona perfectamente con todos los caracteres (Si, Procesa los signos que están al revés, Todo).

Pero Batch no puede leer (correctamente) Unicode, Debes pasar primero los SRT a UTF-8 o ANSI con aquél VBS por ejemplo, O así:

@Echo OFF
CHCP 1250
Type archivoUNICODE.srt>ArchivoANSI.srt
(Ojo, El código de páginas es necesario para que convierta bien los caracteres latinos...)

NOTA: Y para que el script reconozca los caracteres ¡¿áéíóú, etc... de los SRT, Debes guardar tanto los SRT como el BAT en la misma codificación.

Osea:
set "linea=%linea:¿ =¿%"
set "linea=%linea:¡ =¡%"
Si usas eso desde un BAT ANSI sobre un SRT UTF-8, O desde un BAT UTF-8 sobre SRT ANSI, va a hacer una catástrofe, Como lo hace con los SRT en unicode.

EDITO: Después de testear un poco, Puedo decir que el extraño inconveniente que tenia el script, Que se te comia la primera linea del archivo, Era por probar el bat sobre un archivo SRT en distinta codificación que el Bat. Seguramente el resto de errores de conversión que has sufrido antes con el SRT haya sido por el mismo motivo.

Saludos

Sigo en este comentario,

Creo que te toca hacer alguna conversion...

1º - De Unicode a ANSI (Porque de Unicode a UTF-8 no se hacerlo directamente sin aplicaciones, Y sin perder los caracteres especiales) para usar el bat.
2º - De ANSI a lo que quieras:


@Echo off
wscript.exe convert.vbs "archivo"

PD:
objStream.Charset = AQUÍ EL CHARSET

NOTA: No intentes pasar de ANSI a utf-8 con este vbs porque se corrompen todos los caracteres de nuestro idioma ::(. Pero puedes pasarlo a Unicode,iso-8859-2, o ascii sin perder nada.

Convert.vbs
Option Explicit

Dim objFSO, strFileIn, strFileOut

strFileIn = WScript.Arguments.Item(0)

Set objFSO = CreateObject( "Scripting.FileSystemObject" )
strFileOut = objFSO.GetBaseName( strFileIn ) & "_utf8.txt"
Set objFSO = Nothing

UTF8 strFileIn, strFileOut


Function UTF8( myFileIn, myFileOut )
' UTF8()  Version 1.00
' Written by Rob van der Woude
' http://www.robvanderwoude.com

   Dim objStream

   ' Valid Charset values for ADODB.Stream
   Const CdoBIG5        = "big5"
   Const CdoEUC_JP      = "euc-jp"
   Const CdoEUC_KR      = "euc-kr"
   Const CdoGB2312      = "gb2312"
   Const CdoISO_2022_JP = "iso-2022-jp"
   Const CdoISO_2022_KR = "iso-2022-kr"
   Const CdoISO_8859_1  = "iso-8859-1"
   Const CdoISO_8859_2  = "iso-8859-2"
   Const CdoISO_8859_3  = "iso-8859-3"
   Const CdoISO_8859_4  = "iso-8859-4"
   Const CdoISO_8859_5  = "iso-8859-5"
   Const CdoISO_8859_6  = "iso-8859-6"
   Const CdoISO_8859_7  = "iso-8859-7"
   Const CdoISO_8859_8  = "iso-8859-8"
   Const CdoISO_8859_9  = "iso-8859-9"
   Const cdoKOI8_R      = "koi8-r"
   Const cdoShift_JIS   = "shift-jis"
   Const CdoUS_ASCII    = "us-ascii"
   Const CdoUTF_7       = "utf-7"
   Const CdoUTF_8       = "utf-8"

   ' ADODB.Stream file I/O constants
   Const adTypeBinary          = 1
   Const adTypeText            = 2
   Const adSaveCreateNotExist  = 1
   Const adSaveCreateOverWrite = 2

   On Error Resume Next
   
   Set objStream = CreateObject( "ADODB.Stream" )
   objStream.Open
   objStream.Type = adTypeText
   objStream.Position = 0
   objStream.Charset = CdoUTF_8
   objStream.LoadFromFile myFileIn
   objStream.SaveToFile myFileOut, adSaveCreateOverWrite
   objStream.Close
   Set objStream = Nothing
   
   If Err Then
       UTF8 = False
   Else
       UTF8 = True
   End If
   
   On Error Goto 0
End Function

Saludos.

Lo probare porque esto me va a llevar un rato, pero seguro que funciona. Muxas gracias por tomarte las molestias de ayudarme. Saludos

Probado sin exito total. Vamos que por lo que he observado se come este signo "!". He probado a cambiar los charset de ambos archivos, poniendos ambos en el mismo y sigue comiendoselos.

Te dejo los archivos en cuestion, no sea que estén mal.

https://dl.dropbox.com/u/19135067/Cap%2062%20B.srt

https://dl.dropbox.com/u/19135067/Modificando%20subs.bat

Saludos y gracias por adelantado.

Ayer probé de pasar con CHCP + Type un SRT en Unicode a ANSI y no perdiío el charset, Pero con el SRT que has subido no he tenido éxito, Así que mejor descarga esta APP:
http://www.gbordier.com/gbtools/stringconverter.htm

@echo off
CHCP 1250 >NUL

For /R %%# in (*.srt) Do (stringconverter.exe "%%#" "%%~n#.ANSI%%~x#" /ANSI)

For /R %%# in (*ANSI.srt) Do (
Echo Procesando archivo "%%~nx#"
FOR /F "tokens=*" %%X in ('Type "%%#"') do (
Echo "%%X"| findstr /R ".[^0-9]." >NUL || (Echo+ >> "%TEMP%\%%~nx#.srt")
set "linea=%%X"
Call :Replace
Call Echo %%Linea_final%% >> "%TEMP%\%%~nx#.srt"
)
Type "%TEMP%\%%~nx#.srt" | more +1 > "%%~n#.MOD.%%~x#"
Del /Q "%TEMP%\%%~nx#.srt", "%%~nx#"
)
Exit

:Replace
set "linea=%linea:. . .=...%"
set "linea=%linea:¿ =¿%"
set "linea=%linea:¡ =¡%"
set "linea=%linea:Klilyn=Krilin%"
set "linea=%linea:Ginew=Ginyu%"
set "linea=%linea:>=^>%"
set "linea=%linea:)=^)%"
Set "Linea_final=%LINEA%"
Goto:EOF



PD: No uses setlocal enabledelayedexpansion

Saludos

Gracias lo probable, esto es una tarea imposible.