.bat Que recoja la puerta de enlace y la busque en el buscador?

[TakeSkate]

Hola comunidad de elhacker.net hoy vengo a pedir un poco de ayuda y consejo en el siguiente .bat lo que quiero es que busque la dirección de la puerta de enlace predeterminada  y luego abra el navegador y la busque (ya sabeis http://192.168.1.1/...) lo tengo casi todo en el siguiente codigo el problema esta a la hora de abrir el explorer porque no encuentro manera de introducirle la dirección.
¿Alguna idea?

Código [Seleccionar] Expandir

@echo off
REM Buscamos en el comando ipconfig la palabra/s "Dirección IPv4"
ipconfig|FINDSTR "Dirección IPv4" > ip.txt
ipconfig|FINDSTR "predeterminada" > gateway.txt

FOR /F "tokens=13,14,15,16,17,18,19 delims=:." %%I IN (ip.txt) DO @echo La dirección ip de tu maquina es: %%L.%%M.%%N.%%O

FOR /F "tokens=7,8,9,10,11,12,13 delims=:." %%I IN (gateway.txt) DO @echo Tu puerta de enlace predeterminada es: %%I.%%J.%%K.%%L

FOR /F "tokens=7,8,9,10,11,12,13 delims=:." %%I IN (gateway.txt) DO @echo%%I.%%J.%%K.%%L > gateway.txt
start iexplore.exe < gateway.txt

DEL ip.txt
DEL gateway.txt
pause

[Eleкtro]

Si guiendo el ejemplo que ya tenías, puedes hacerlo de la siguiente manera:

Código (dos) [Seleccionar] Expandir

@Echo OFF & SetLocal EnableDelayedExpansion & (CHCP 1252)1>Nul

Set "arg="

FOR /F "tokens=13,14,15,16,17,18,19 delims=:." %%I In (
'IPConfig.exe ^| Find /I "IPv4"'
) DO (
Echo La dirección ip de tu maquina es.....:%%L.%%M.%%N.%%O
)

FOR /F "tokens=7,8,9,10,11,12,13 delims=:." %%I In (
'IPConfig.exe ^| Find /I "predeterminada"'
) DO (
Set "arg=%%I.%%J.%%K.%%L"
Set "arg=!arg:~1!"
Echo Tu puerta de enlace predeterminada es: !arg!
)

Start /B "" "IExplore.exe" "%arg%"

Pause&Exit

¡Saludos!.

[TakeSkate]

Excelente funciona,  muchas gracias por la ayuda andaba perdido con el start iexplore.exe