Bueno, que tal!
Tengo una funcion para detectar cuando un arreglo es nulo, el problema que para cada tipo de dato del arreglo tengo que diseñar una nueva funcion. Me gustaria crear una funcion para cualquier tipo de dato, como podria hacerlo?
function isArrayNullEntero(arreglo() as integer) as boolean
...
end function
function isArrayNullNuevoTipo(arreglo() as nuevotipo) as boolean
...
end function
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal Destination As Any, ByVal Source As Any, ByVal Length As Long)
Private Declare Function VarPtrA Lib "msvbvm60.dll" Alias "VarPtr" (ByRef Ptr() As Any) As Long
Private Function ItsArrayIni(ByVal lngPtr As Long, Optional LnBytes As Long = 4) As Boolean
Dim lng_PtrSA As Long
If lngPtr <> 0 And LnBytes > 0 Then
Call CopyMemory(ByVal VarPtr(lng_PtrSA), ByVal lngPtr, LnBytes)
ItsArrayIni = Not lng_PtrSA = 0
End If
End Function
'//uso:
if (ItsArrayIni(VarPtrA(iArray()))) then
' Haz algo...
end if
Temibles Lunas!¡.
Que bien compadre!
Gracias, es perfecto! ;)
HOLA!!!
Vi a karcrack hacer este codigo para ver eso:
dim b() as variant ' o el tipo que sea
If (Not Not b) = False Then '
'no se inicializo (hay que dimensionarlo)
Else
'esta inicializado
End If
GRACIAS POR LEER!!!
También con el truco del NotNot podemos comprobar si está iniciado el array:
If Not Not iArray Then
'// Haz algo...
End If
Es la forma más rápida, en el IDE puede dar problemas pero compilado funciona 100%.
Para prevenir el bug en el IDE haz:
Private Form_Load()
Dim IDEbug&()
'// Prevenir el NotNot bug.
Debug.Assert Not IDEbug Or App.hInstance
End Sub
Advertencia - mientras estabas escribiendo, una nueva respuesta fue publicada. Probablemente desees revisar tu mensaje.
:-\
DoEvents! :P
Es que la idea original era esta:
Private Function isArrayNull(tarray() As integer) As Boolean
Dim i As Integer
On Error GoTo tError
i = UBound(tarray)
Exit Function
tError:
isArrayNullAnimal = True
End Function
Private Sub Form_Load()
Dim a() as Integer
Msgbox isArrayNull(a)
End Sub
El problema es que para un array String(por ejemplo) tendria que cambiar el tipo recibido a String... Pero con lo de Black esta solucionado... salud!
en este post ya se hablo del tema:
coo saber si existe una variante? (http://foro.elhacker.net/programacion_vb/coo_saber_si_existe_una_variante-t270378.0.html;msg1325173)
.
No les recomiedno usar Not para ver si esta inicializada la variable , en codigos largos y complejos causa errores muy desagradables es por eso que le di el codigo de CopyMemory.
Edito------>
Cita de: Mr.Frog™ en 29 Abril 2011, 21:25 PM
Es la forma más rápida, en el IDE puede dar problemas pero compilado funciona 100%.
Para prevenir el bug en el IDE haz:
Extraño a mi con mi ctl ListViewEx compilado o no, me dio bastantes errores... que se solucionaban separando un monton de variables, haciendo los cats, reduciendo operaciones uff... muchos errores.
El error exacto era:
Expresión Demasiado compleja@seba123neoEn esa liga, el código que esta ( el que publiscaste ) es bueno pero hace demasiadas cosas ya que un array dinámico NULO (sin dimensiones) es un apuntador de 4 bytes ( aqrquitectura 32bytes lo digo solo como dato general ) del mismo apuntando a la estructura SafeArray dado que si no existe ( puntero NULO ) es que no esta inicializado el array, en caso contrario se apuntaría al SafeArray y simplemente usaríamos Ubound() y Lbound() que es lo mismo que en aquel código de la liga otorgas pero el caso no es saber las dimensiones ni los estados si no mas bien saber si esta inicializado o no el array o mejor dicho saber si ya hay memoria reservada para el mismo.
* Los array con declaración estática no apuntan al safearray de echo el puntero de la variable es a esta estructura...
typedef struct FARSTRUCT tagSAFEARRAY {
unsigned short cDims; // Count of dimensions in this array.
unsigned short fFeatures; // Flags used by the SafeArray
// routines documented below.
#if defined(WIN32)
unsigned long cbElements; // Size of an element of the array.
// Does not include size of
// pointed-to data.
unsigned long cLocks; // Number of times the array has been
// locked without corresponding unlock.
#else
unsigned short cbElements;
unsigned short cLocks;
unsigned long handle; // Used on Macintosh only.
#endif
void HUGEP* pvData; // Pointer to the data.
SAFEARRAYBOUND rgsabound[1]; // One bound for each dimension.
} SAFEARRAY;
.. en todo caso lo que importa es solo saber si ya tiene memoria reservada (Inicializado)... pero bueno. Mas Info SafeArray (http://msdn.microsoft.com/en-us/library/ms221482.aspx).
Temibles Lunas!¡.
Cita de: BlackZeroX▓▓▒▒░░ en 30 Abril 2011, 10:42 AM
.
No les recomiedno usar Not para ver si esta inicializada la variable , en codigos largos y complejos causa errores muy desagradables es por eso que le di el codigo de CopyMemory.
Dulces Lunas!¡.
¿Compilado también? :huh:
DoEvents! :P
Si, de hecho lo tenia co Not(Not array) en todo caso prefiero ya hacerlo bien xP evitando el uso de not para estas cosas... al igual que LSet y otras cosillas que en proyectos medianos a grandes me han dado problemas
P.D.:
Option Explicit
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal Destination As Any, ByVal Source As Any, ByVal Length As Long)
Private Declare Function VarPtrA Lib "msvbvm60.dll" Alias "VarPtr" (ByRef Ptr() As Any) As Long
Private Function ItsArrayIni(ByVal lngPtr As Long, Optional LnBytes As Long = 4) As Boolean
Dim lng_PtrSA As Long
If lngPtr <> 0 And LnBytes > 0 Then
Call CopyMemory(ByVal VarPtr(lng_PtrSA), ByVal lngPtr, LnBytes)
ItsArrayIni = Not lng_PtrSA = 0
End If
End Function
Private Sub Form_Load()
Dim aVar() As Integer
MsgBox ItsArrayIni(VarPtrA(aVar()))
ReDim aVar(0 To 10)
MsgBox ItsArrayIni(VarPtrA(aVar()))
Erase aVar()
MsgBox ItsArrayIni(VarPtrA(aVar()))
End Sub
Dulces Lunas!¡.