Pues eso hoy en clases nos mostraron como reproducir wav con mmcontrol y me gustaría saber como sería para reproducir un mp3 :)
Gracias de antemano, por cierto he visto varios reproductores pero no es la idea aprender a copiar sino a hacer :)
Gracias
Wenas, yo los reproduzco con el componente Windows Media Player.
un saludo
PD:con mmcontrol no se :xD
aja pero como se usaria el comtrol de WMP? lo malo es que al usarlo dependeria de que estuviera instalado en el PC el Windows Media no?
Utiliza la API mciSendString
Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" (ByVal lpstrCommand As String, ByVal lpstrReturnString As String, ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long
Saludos ;)
Si, lo del Media Player seria eso, si no esta instalado el reproductor no sirve, de todas formas con lo q ha dicho aaronduran2 ya puedes hacerlo :D
un saludo
PD:No hace falta q este instalada el Windows Media, solo coje el .ocx de un ordenador q si lo tenga :P (creo q es wmp.ocx/wmp.dll, una de las dos)
Lo siento pero no se usar APIs llevó recién un mes haciendo experimentos y me quedó pegado en términos :(
Esto iría en un módulo? O similar... Gracias
seria bueno elabora alguno o colocar algunas de las herramientas que hay que utiliza para realizar un reproducir un MP3 en Visual Basic
Cita de: WestOn en 28 Noviembre 2008, 21:15 PM
Si, lo del Media Player seria eso, si no esta instalado el reproductor no sirve, de todas formas con lo q ha dicho aaronduran2 ya puedes hacerlo :D
un saludo
PD:No hace falta q este instalada el Windows Media, solo coje el .ocx de un ordenador q si lo tenga :P (creo q es wmp.ocx/wmp.dll, una de las dos)
Exactamente como dice el amigo WestOn, hasta con un scrip un ejemplo seria:
Set Wmp = CreateObject("WMPlayer.OCX.7")
Wmp.URL = "mi sonido.mp3" ;---------Puede ser mp3,wav,wma
Wmp.Controls.Play
wscript.sleep 5000 ;--------------Tiempo de reproduccion en ms.
Este ejemplo por aqui lo vi en un post.
Ó talvez estoy entendiendo mal lo que quieres hacer.
La idea principal más que usar un reproductor es usar el mismo visual basic para reproducir, osea abrir el media player (o embedarlo) no es la idea.
No hay ninguna forma de reproducir con visual basic un mp3?
Wenas, vi un ejemplo de estos q hacen lo de micro$oft:
Añade un CommonDialog, y dos botones
Private Declare Function mciSendString Lib "winmm.dll" Alias _
"mciSendStringA" (ByVal lpstrCommand As String, ByVal _
lpstrReturnString As Any, ByVal uReturnLength As Long, ByVal _
hwndCallback As Long) As Long
Private Sub Command1_Click()
CommonDialog1.ShowOpen
Debug.Print CommonDialog1.filename
Debug.Print mciSendString( _
"open " & CommonDialog1.filename & " alias testfile", 0&, 0, 0)
' To work around the long file name limitation use the next line
' instead of the previous line, which adds quotes around the path
' and file name.
'Debug.Print mciSendString( _
"open " & """" & CommonDialog1.filename & """" _
& " alias testfile", 0&, 0, 0)
Debug.Print mciSendString("play testfile wait", 0&, 0, 0)
End Sub
Private Sub Command2_Click()
Debug.Print mciSendString("close testfile", 0&, 0, 0)
End Sub
Private Sub Form_Load()
Command1.Caption = "Open and Run"
Command2.Caption = "Close MDI file"
End Sub
El CommonDialog es el control "Microsoft Common Dialog Control 6.0".
De todas formas si quieres echale un vistazo: http://support.microsoft.com/kb/191089/es (http://support.microsoft.com/kb/191089/es)
un saludo ;)
Hola, desde visual basic sonidos los podes reproducir de muchas formas...un .wav basicamente se reproduce con una api llamada PlaySound,archivos Wav, MP3 y Midi los podes reproducir con la api llamada mciExecute,y tambien con el control ese que vos decis el MMControl podes reproducir .wav y .avi videos,o con la api mciSendString podes reproducir sonidos y videos tambien...
saludos.
Cita de: seba123neo en 29 Noviembre 2008, 14:51 PM
Hola, desde visual basic sonidos los podes reproducir de muchas formas...un .wav basicamente se reproduce con una api llamada PlaySound,archivos Wav, MP3 y Midi los podes reproducir con la api llamada mciExecute,y tambien con el control ese que vos decis el MMControl podes reproducir .wav y .avi videos,o con la api mciSendString podes reproducir sonidos y videos tambien...
saludos.
Seba disculpa no tienes un ejemplo por ahi? para saber como rayos se usa una API? te lo agradeceria un monton ;)
wenas no se si habras visto esta pag. pero aqui te la dejo aqui habla todo sobre api espero que te sirva de ayuda Salu2 ;)
http://www16.brinkster.com/eduroam/api/ (http://www16.brinkster.com/eduroam/api/)
y para qeu se suene un tema al abrir el programa??? ti po los crack o keygens.... como se haria??
Ps,
Cita de: Shell Killer en 30 Noviembre 2008, 20:22 PM
y para qeu se suene un tema al abrir el programa??? ti po los crack o keygens.... como se haria??
Creo que se deberia poner el COD en el Load_
Saludos!!!
Con el mmcontrol debería ser suficiente, el sonido puede ser wav o midi (con midi no he probado) y un mute o botón pa silenciar ya que a veces sí no es buena o agradable la canción puede molestar :)
ya dije que podes reproducir los sonidos con api ,no hace falta ningun control, busca , o sino bajate el api-guide ahi hay ejemplos de todo...
buenas e visto k ablan sobre esto de la musica en el formulario....yo lo probé hace un tiempo y no me funcionaba...no me acuerdo que puse...pues soy algo nuevo con esto y nunca e hecho lo del sonido.....
me podrian poner un ejemplo para oír un .......mp3 al iniciar el form
en el form load k s pondria plis¿?
i s podria poner el sonido dentro del programa¿? al stilo d k ste dentro guardado y no en la carpeta del programa porfa¿?
muxas gracias por todo
para que este dentro guardado simplemente lo guardas en un archivo de recursos y al iniciar lo pasas al disco y de ahi lo reproducis...si no sabes lo que es entonces averigua primero porque nadie te va a explicar la teoria, eso lo tenes que saber vos...pero para reproducir un mp3 podes hacer con la api mciSendString...o con mciExecute...busca porque nadie te va a poner el ejemplo si no sabes todavia lo que es una api....
saludos.
no m *****!! ;D klaro k s lo k s una api....mpeze hace un tiempo a programar en VB6 ...aunque no s demasiado..pero lo suficiente,,,....tngo programas chorras y demas...weno a lo que iva ...gracias por la info buskare por el semi dios google....thnks
4 CommandButton: Command1 (Play) , Command2(stop) , Command3 (Pause) y Command4 (Abrir archivo)
Un Commondialog1
Un Label1: Para mostrar el Path
Option Explicit
'Función Api GetShortPathName para obtener _
los paths de los archivos en formato corto
Private Declare Function GetShortPathName _
Lib "kernel32" _
Alias "GetShortPathNameA" ( _
ByVal lpszLongPath As String, _
ByVal lpszShortPath As String, _
ByVal lBuffer As Long) As Long
'Función Api mciExecute para reproducir los archivos de música
Private Declare Function mciExecute _
Lib "winmm.dll" ( _
ByVal lpstrCommand As String) As Long
Dim ret As Long, path As String
'Le pasamos el comando Play
Private Sub Command1_Click()
ejecutar ("Play ")
Habilitar "Play"
End Sub
Private Sub Command2_Click()
'Le pasamos el comando Stop
ejecutar ("Stop ")
Habilitar "Stop"
End Sub
'Le pasamos el comando Pause
Private Sub Command3_Click()
ejecutar ("Pause ")
Habilitar "Pause"
End Sub
'Le pasamos el comando Close a MciExecute para cerrar el dispositivo
Private Sub Form_Unload(Cancel As Integer)
mciExecute "Close All"
End Sub
'Botón para abrir seleccionar los archivos de audio
Private Sub Command4_Click()
With CommonDialog1
.Filter = "Archivos Wav|*.wav|Archivos Mp3|*.mp3|Archivos MIDI|*.mid"
.ShowOpen
If .FileName = "" Then
Habilitar "Iniciar"
Exit Sub
Else
'Le pasamos a la sub que obtiene con _
el Api GetShortPathName el nombre corto del archivo
PathCorto .FileName
Label1 = .FileName
'cerramos todo
mciExecute "Close All"
'Para Habilitar y deshabilitar botones
Habilitar "Stop"
End If
End With
End Sub
'Sub que obtiene el path corto del archivo a reproducir
Private Sub PathCorto(archivo As String)
Dim temp As String * 250 'Buffer
path = String(255, 0)
'Obtenemos el Path corto
ret = GetShortPathName(archivo, temp, 164)
'Sacamos los nulos al path
path = Replace(temp, Chr(0), "")
End Sub
'Procedimiento que ejecuta el comando con el Api mciExecute
'************************************************************
Private Sub ejecutar(comando As String)
If path = "" Then MsgBox "Error", vbCritical: Exit Sub
'Llamamos a mciExecute pasandole un string que tiene el comando y la ruta
mciExecute comando & path
End Sub
Private Sub Form_Load()
Command1.Caption = "Play >>"
Command2.Caption = "Stop ||||"
Command3.Caption = "Pause ||"
Command4.Caption = ":::: Abrir archivo de música ::::"
Habilitar "Iniciar"
Label1 = "": Label1.AutoSize = True
End Sub
Private Sub Habilitar(Accion As String)
Select Case Accion
Case "Iniciar"
Command1.Enabled = False
Command2.Enabled = False
Command3.Enabled = False
Case "Play"
Command1.Enabled = False
Command2.Enabled = True
Command3.Enabled = True
Case "Stop"
Command1.Enabled = True
Command2.Enabled = False
Command3.Enabled = False
Case "Pause"
Command1.Enabled = True
Command2.Enabled = True
Command3.Enabled = False
End Select
End Sub
Fuente : http://www.recursosvisualbasic.com.ar/htm/listado-api/api-53-mciexecute.htm
Espero que les sirva....aunque un poco tarde xD