Saludos a todos;
El siguiente script hace un merge de archivos TXT:
Public Sub FindAndMergeFiles(ByVal sourceDir As String)
Dim fileNames As String() =
{
"CM.txt", "GL.txt",
"IMP6000.txt", "IMP6001.txt", "IMP6002.txt", "IMP6003.txt"
}
Dim curFilename As String = String.Empty
For Each topDir As DirectoryInfo In New DirectoryInfo(sourceDir).GetDirectories("*", SearchOption.TopDirectoryOnly)
' Elimino los archivos principales ("...\topDir\CM.txt", "...\topDir\GL.txt", etc...) de sesiones anteriores.
For Each txtfile As FileInfo In topDir.GetFiles("*.txt", SearchOption.TopDirectoryOnly)
If fileNames.Contains(txtfile.Name, StringComparer.OrdinalIgnoreCase) Then
txtfile.Delete()
End If
Next txtfile
For Each subDir As DirectoryInfo In topDir.GetDirectories("*", SearchOption.AllDirectories)
For Each txtfile As FileInfo In subDir.GetFiles("*.txt", SearchOption.AllDirectories)
If fileNames.Contains(txtfile.Name, StringComparer.OrdinalIgnoreCase) Then
curFilename = fileNames.First(Function(filename) filename.Equals(txtfile.Name, StringComparison.OrdinalIgnoreCase))
Using sr As StreamReader = txtfile.OpenText
Using sw As New StreamWriter(Path.Combine(topDir.FullName, curFilename), append:=True, encoding:=Encoding.Default, bufferSize:=128)
sw.WriteLine(sr.ReadToEnd)
End Using ' sw
End Using ' sr
End If
Next txtfile
Next subDir
Next topDir
Ahora bien en el formulario que usa ese script hay un selector que indica dos opciones A y B; donde si la opción B es la que ha sido seleccionada es nesario buscar en dos archivos particulares una palabra y cambiarla por otra, entiendo que la funcion sería mas o menos así:
Private Sub ReemplazaTexto(ByVal Fichero As String, ByVal Texto_Busca As String, ByVal Texto_Reemplaza As String)
Dim Reader As New StreamReader(Fichero)
Dim Content As String = Reader.ReadToEnd()
Reader.Close()
Content = Regex.Replace(Content, Texto_Busca, Texto_Reemplaza)
Dim Writer As New StreamWriter(FicheroNuevo)
Writer.Write(Content)
writer.Close()
End Sub
Ahora lo que quedaría es que despues que ejecuto el merge es preguntar que opción del combobox está seleccionada, que sería así:
'El usuario selecciono la opcion para cambiar texto
If ComboBox1.SelectedIndex = 0 Then
reemplazatexto("AR.txt","TXTB1","TXTN")
reemplazatexto("AR.txt","TXTB2","TXTN")
reemplazatexto("BR.txt","TXTB1","TXTN")
reemplazatexto("BR.txt","TXTB2","TXTN")
Else
return
End If
Creo que así sería; pero si alguien tiene uuna mejor idea será bien recibida.
Desde ya mil gracias.
El motor RegEx es lento. Si realmente estás usando patrones de expresiones regulares para buscar texto, o si quieres reemplazar texto sin diferenciar mayus/minus entonces te sugiero usar estas extensiones:
( La función StringExtensions.Replace es mucho más rápida que una expresión regular en modo
IgnoreCase )
Imports System.Runtime.CompilerServices
Public Module StringExtensions
<Extension>
Public Function ReplaceRegEx(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
Optional ByVal regexOptions As RegexOptions =
RegularExpressions.RegexOptions.None) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Return Regex.Replace(sender, findWhat, replaceWith, regexOptions)
End If
End Function
<Extension>
Public Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Return StringExtensions.Replace(sender, findWhat, replaceWith, comparisonType, stringBuilderCapacity:=0)
End If
End Function
''' ----------------------------------------------------------------------------------------------------
''' <remarks>
''' Author: Elektro
''' Orig. : http://www.codeproject.com/Articles/10890/Fastest-C-Case-Insenstive-String-Replace?msg=1835929#xx1835929xx
''' </remarks>
''' ----------------------------------------------------------------------------------------------------
''' <param name="stringBuilderCapacity">
''' The initial buffer size of the <see cref="Stringbuilder"/>.
''' This parameter is reserved for testing purposes.
''' </param>
''' ----------------------------------------------------------------------------------------------------
<DebuggerHidden>
<DebuggerStepThrough>
<Extension>
Private Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison,
ByVal stringBuilderCapacity As Integer) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Dim posCurrent As Integer = 0
Dim lenPattern As Integer = findWhat.Length
Dim idxNext As Integer = sender.IndexOf(findWhat, comparisonType)
Dim result As New StringBuilder(capacity:=If(stringBuilderCapacity <= 0, Math.Min(4096, sender.Length), stringBuilderCapacity))
While (idxNext >= 0)
result.Append(sender, posCurrent, (idxNext - posCurrent))
result.Append(replaceWith)
posCurrent = (idxNext + lenPattern)
idxNext = sender.IndexOf(findWhat, posCurrent, comparisonType)
End While
result.Append(sender, posCurrent, (sender.Length - posCurrent))
Return result.ToString
End If
End Function
End Module
CitarPrivate Sub ReemplazaTexto(ByVal Fichero As String, ByVal Texto_Busca As String, ByVal Texto_Reemplaza As String)
Dim Reader As New StreamReader(Fichero)
Dim Content As String = Reader.ReadToEnd()
Reader.Close()
Content = Regex.Replace(Content, Texto_Busca, Texto_Reemplaza)
Dim Writer As New StreamWriter(FicheroNuevo)
Writer.Write(Content)
writer.Close()
End Sub
Usando el módulo de arriba, yo lo dejaría tal que así (pero sin los nombres en Español xD):
Private Sub ReemplazaTexto(ByVal fichero As String,
ByVal texto_Busca As String, ByVal texto_Reemplaza As String,
ByVal comparisonType As StringComparison)
If Not File.Exists(fichero) Then
Throw New FileNotFoundException(message:="File not found", fileName:=fichero)
Else
Dim txt As String = File.ReadAllText(fichero, Encoding.Default).
Replace(texto_Busca, texto_Reemplaza, comparisonType)
File.WriteAllText(fichero, txt, Encoding.Default)
End If
End SubEDITO: Pero vamos, si sabes que la palabra va a ser toda en mayúscula o minúscula o como sea entonces ignora el módulo de arriba y usa un String.Replace normal claro está.
Saludos!
Chamo de pana que tu comes .net....
Q arrech.... Tu codigo....
Tengo varias preguntas:
1.- Al momento de crear el módulo me da error con las variables RegexOptions y Regex; el compilador me indica que no están definidas.
2.- Como lo acoplo esa función en el script que hemos venido trabajando?
Aqui hago el llamado al merge de los archivos:
' Merge text files.
DateUtil.FindAndMergeFiles(Me.fdg.SelectedPath)
Luego de hacer l merge pregunto por el valor del combobox
'El usuario selecciono la opcion para cambiar texto
If ComboBox1.SelectedIndex = 0 Then
ReplaceText("GL.txt","TXT01","TXT1")
ReplaceText("GL.txt","TXT02","TXT1")
ReplaceText("IMP6000.txt","TXT01","TXT1")
ReplaceText("IMP6000.txt","TXT02","TXT1")
Else
return
End If
3.- La función ReplaceText (ya la puse en ingles jejejejejeje)
Private Sub ReplaceText(ByVal txtfile As String,
ByVal txtfind As String, ByVal txtreplace As String,
ByVal comparisonType As StringComparison)
If Not File.Exists(txtfile) Then
Throw New FileNotFoundException(message:="File not found", fileName:=txtfile)
Else
Dim txt As String = File.ReadAllText(txtfile, Encoding.Default).
Replace(txtfind, txtreplace, comparisonType)
File.WriteAllText(txtfile, txt, Encoding.Default)
End If
End Sub
iria dentro del formulario; correcto?
Mil gracias de nuevo pana.
Cita de: elqueteconte en 23 Octubre 2015, 21:42 PM1.- Al momento de crear el módulo me da error con las variables RegexOptions y Regex; el compilador me indica que no están definidas.
Tienes que importar los espacios de nombres o NameSpaces necesarios.
Imports System.Text.RegularExpressionsSinceramente, si tienes pensado seguir utilizando VB.Net para otro tipo de tareas en el futuro, entonces esto es algo a lo que te deberías acostumbrar a poder resolverlo por ti mismo ya que es una situación de lo más común.
Coloca por 1 o 2 segundos el puntero del mouse sobre la orden o el miembro que se marca en rojo en la IDE (en este caso la palabra "RegEx"), aparecerá un icono al final del nombre con una flechita, si le aprietas a la flecha aparecerá una lista con varias opciones resolutivas entre ellas importar "X" namespace (no siempre aparecerá esa opción, pero en este caso debería salir), si le pinchas automaticamente se añadirá la instrucción Imports que sea necesaria.
Cita de: elqueteconte en 23 Octubre 2015, 21:42 PM2.- Como lo acoplo esa función en el script que hemos venido trabajando?
Creo que te refieres a hacer algo así:
Sub...
'El usuario selecciono la opcion para cambiar texto
If (Me.ComboBox1.SelectedIndex = 0) Then
Dim comparisonType As StringComparison = StringComparison.OrdinalIgnoreCase
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "TXT01", "TXT1", comparisonType)
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "TXT02", "TXT1", comparisonType)
FindFileAndReplaceTextIn(sourceDir, "IMP6000.txt", "TXT01", "TXT1", comparisonType)
FindFileAndReplaceTextIn(sourceDir, "IMP6000.txt", "TXT02", "TXT1", comparisonType)
Else
Exit Sub
End If
End Sub+
Public Sub FindFileAndReplaceTextIn(ByVal sourceDir As String, ByVal filenameFind As String,
ByVal txtfind As String, ByVal txtreplace As String,
ByVal comparisonType As StringComparison)
For Each topDir As DirectoryInfo In New DirectoryInfo(sourceDir).GetDirectories("*", SearchOption.TopDirectoryOnly)
For Each txtfile As FileInfo In topDir.GetFiles("*.txt", SearchOption.TopDirectoryOnly)
If txtfile.Name.Equals(filenameFind, StringComparison.OrdinalIgnoreCase) Then
Dim txt As String = File.ReadAllText(txtfile.FullName, Encoding.Default).
Replace(txtfile.FullName, txtfind, txtreplace, comparisonType)
File.WriteAllText(txtfile.FullName, txt, Encoding.Default)
End If
Next txtfile
Next topDir
End SubEl método ReplaceText ya no sería necesario.
Citar3.- La función ReplaceText (ya la puse en ingles jejejejejeje)
Genial, aunque no hacia falta, si te entiendes mejor con la programación en Español entonces no cambies tus hábitos por un comentario que hice, de todas formas así en Inglés está todo mucho mejor ...es algo positivo.
Citariria dentro del formulario; correcto?
Todo código que no forme parte del Form (como el módulo que compartí, o tus funciones de reempalzar texto y tal) deberías aislarlo de la class del form, en la medida de lo posible, es decir, las llamadas a esos métodos las realizas desde la Clas del Form claro está (Form1.vb o lo que sea), pero los bloques de código de esos métodos los declaras en módulos/classes distintas.
Saludos
Ante todo, gracias de nuevo Elektro;
Capté perfectamente el mensaje, de hecho te comparto lo que hice:
1.- En el módulo StringExtensions colgué la función FindFileAndReplaceTextIn
2.- En el módulo DateUtil colgué en la función FindAndMergeFiles justo despues de terminar con el último for la consulta al valor del ComboBox y si el valor es el esperado entonces llamo a la función FindFileAndReplaceTextIn que está en el otro módulo.
Pero hay un detalle y trate de solucionarlo con el mismo asistente que me recomendaste pero no funcionó con ello.
El detalle es que en la función FindFileAndReplaceTextIn se manejan 5 parámetros de los cuales hay uno llamado txtreplace que supuestamente es un String pero debería ser (segun el Visual) StringComparison pero cuando hago el cambo sugerido entonces en la sentencia donde hago el llamado:
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "textbuscar", "textoreemplaza", comparisonType)
Me da un warning y el Visual me sugiere que debo cambiarlo a:
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "textbuscar", CType("textoreemplaza", StringComparison), comparisonType)
Que es lo que realmente hice mal?
Porque me da esos warnings?
Desde ya mil gracias amigo.
Cita de: elqueteconte en 26 Octubre 2015, 17:29 PMQue es lo que realmente hice mal?
Porque me da esos warnings?
Supuestamente no estás haciendo nada mal y tampoco te debería saltar ningún warning.
Los 4 primeros parámetros del método FindFileAndReplaceTextIn son de tipo String, y el quinto parámetro es del tipo
StringComparison, por ende, si tu le estás pasando 4 strings + un
StringComparison entonces no entiendo en absoluto por que te salta el warning, ya que no debería.
Solo se me ocurre que hayas modificado la parametización del método FindFileAndReplaceTextIn cambiando el orden del último parámetro ...¿?
De todas formas, tengas el orden de los parámetros como lo tengas, siempre puedes usar parámetros nombrados (named parameters) para especificar estrictamente a que parámetro correspodne cada valor que le pasas al método:
FindFileAndReplaceTextIn(sourceDir:=sourceDir, filenameFind:="GL.txt",
txtfind:="textbuscar", txtreplace:="textoreemplaza",
comparisonType:=comparisonType)Eso debería solucionar el problema, a menos que hayas modificado algo xD.
Saludos!
Saludos mi pana,
Cada consulta contigo es una clase de .net jejejejejeje ;-)
Esta es la función FindFileAndReplaceTextIn que me pasaste:
Public Sub FindFileAndReplaceTextIn(ByVal sourceDir As String, ByVal filenameFind As String,
ByVal txtfind As String, ByVal txtreplace As String,
ByVal comparisonType As StringComparison)
For Each topDir As DirectoryInfo In New DirectoryInfo(sourceDir).GetDirectories("*", SearchOption.TopDirectoryOnly)
For Each txtfile As FileInfo In topDir.GetFiles("*.txt", SearchOption.TopDirectoryOnly)
If txtfile.Name.Equals(filenameFind, StringComparison.OrdinalIgnoreCase) Then
Dim txt As String = File.ReadAllText(txtfile.FullName, Encoding.Default).
Replace(txtfile.FullName, txtfind, txtreplace, comparisonType)
File.WriteAllText(txtfile.FullName, txt, Encoding.Default)
End If
Next txtfile
Next topDir
End Sub
En la definición de los parámetros está txtreplace como String donde según entiendo debería ser StringComparison; ahora bien si lo cambio entonces en el llamado a la función me da otro warning. Precisamente con ese parámetro.
Entonces hago el llamado a la misma de la siguiente forma:
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "AGENO-02", "AGEN-03", comparisonType)
Gracias nuevamente.
Cita de: Eleкtro en 26 Octubre 2015, 17:55 PM
Supuestamente no estás haciendo nada mal y tampoco te debería saltar ningún warning.
Los 4 primeros parámetros del método FindFileAndReplaceTextIn son de tipo String, y el quinto parámetro es del tipo StringComparison, por ende, si tu le estás pasando 4 strings + un StringComparison entonces no entiendo en absoluto por que te salta el warning, ya que no debería.
Solo se me ocurre que hayas modificado la parametización del método FindFileAndReplaceTextIn cambiando el orden del último parámetro ...¿?
De todas formas, tengas el orden de los parámetros como lo tengas, siempre puedes usar parámetros nombrados (named parameters) para especificar estrictamente a que parámetro correspodne cada valor que le pasas al método:
FindFileAndReplaceTextIn(sourceDir:=sourceDir, filenameFind:="GL.txt",
txtfind:="textbuscar", txtreplace:="textoreemplaza",
comparisonType:=comparisonType)
Eso debería solucionar el problema, a menos que hayas modificado algo xD.
Saludos!
Saludos mi pana,
Probé exactamente lo que indicas y me dió error.
Este es el error:
BC30512 Option Strict On disallows implicit conversions from 'String' to 'StringComparison'. WindowsApplication6 C:\Users\liderapp\Documents\Visual Studio 2015\Projects\WindowsApplication6\WindowsApplication6\StringExtensions.vb 91
Al irme a la linea 91 el error lo da aqui:
Replace(txtfile.FullName, txtfind, [b]txtreplace[/b], comparisonType)Que sugieres hermano...?
Imagino que estas usando esta extensión de método?:
Cita de: http://foro.elhacker.net/net/cambiar_palabras_de_un_archivo_txt-t443323.0.html;msg2044424#msg2044424 Private Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison,
ByVal stringBuilderCapacity As Integer) As String
...
End Function
La cual por cierto no se por que la declaré von visibilidad
Private, modifica el keyword
Private por
Public para poder utilizarla.
Aparte, el parámetro
sender se asigna automaticamente, debes ignorarlo y dejarlo así:
...Replace(txtfind, txtreplace, comparisonType, 128)saludos
Cita de: Eleкtro en 27 Octubre 2015, 02:16 AM
Imagino que estas usando esta extensión de método?:
La cual por cierto no se por que la declaré von visibilidad Private, modifica el keyword Private por Public para poder utilizarla.
Aparte, el parámetro sender se asigna automaticamente, debes ignorarlo y dejarlo así:
...Replace(txtfind, txtreplace, comparisonType)
saludos
Buenos días bro;
Si estoy usando tal cual lo que me diste.
La función queda así:
Private Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison,
ByVal stringBuilderCapacity As Integer) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Return StringExtensions.Replace(findWhat, replaceWith, comparisonType)
End If
Ahora hay otro detalle del que me estoy dando cuenta; tienes dos funciones llamas igual, una privada y otra publica; pero al hacerlas ambas Publicas el VS da error.
Estas son las funciones:
Public Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Return StringExtensions.Replace(sender, findWhat, replaceWith, comparisonType, stringBuilderCapacity:=0)
End If
End Function
Esta es la otra:
Private Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison,
ByVal stringBuilderCapacity As Integer) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Dim posCurrent As Integer = 0
Dim lenPattern As Integer = findWhat.Length
Dim idxNext As Integer = sender.IndexOf(findWhat, comparisonType)
Dim result As New StringBuilder(capacity:=If(stringBuilderCapacity <= 0, Math.Min(4096, sender.Length), stringBuilderCapacity))
While (idxNext >= 0)
result.Append(sender, posCurrent, (idxNext - posCurrent))
result.Append(replaceWith)
posCurrent = (idxNext + lenPattern)
idxNext = sender.IndexOf(findWhat, posCurrent, comparisonType)
End While
result.Append(sender, posCurrent, (sender.Length - posCurrent))
Return result.ToString
End If
End Function
Gracias mil de nuevo amigo.
Tienes razón, no me di cuenta que declaré dos funciones con las prisas xD
Reectifico lo que dije aquí:
CitarLa cual por cierto no se por que la declaré von visibilidad Private, modifica el keyword Private por Public para poder utilizarla.
Está todo bien, solo que tienes que ignorar eso último que dije, tienes que usar la otra función ...la que ya es publica, pues esa función llama a la función privada.
Saludos
Cita de: Eleкtro en 27 Octubre 2015, 18:49 PM
Tienes razón, no me di cuenta que declaré dos funciones con las prisas xD
Reectifico lo que dije aquí:
Está todo bien, solo que tienes que ignorar eso último que dije, tienes que usar la otra función ...la que ya es publica, pues esa función llama a la función privada.
Saludos
El hecho de poder decirte que hay errores me apena... jajajajajaja
Pues te cuento que ya no da error el compilador pero cuando ejecuto el utilitario me está dando un
System.StackOverflowException o
pila sobrecargada en
Public Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison,
ByVal stringBuilderCapacity As Integer) As String
Estaba investigando y encuentro en el VS el siguiente mensaje:
The maximum number of stack frames supported by Visual Studio has been exceeded.
Existe alguna forma de incrementar ese parámetro?
o alguna alternativa para evitar este overflow?
Gracias de nuevo mi pana....
Cita de: elqueteconte en 27 Octubre 2015, 22:19 PMcuando ejecuto el utilitario me está dando un System.StackOverflowException
Esa excepción es síntoma de estar utilizando prácticas recursivas, por algún método/algoritmo con una recursividad excesiva y/o infinita la cual con sus llamadas colapsa el tamaño de la pila o stack, provocando así un overflow.
No puedo reproducir el conflicto con el código que te mostré en lo que denominariamos "circunstancias normales" (no llevando al límite las capacidades para provocar un stack-overflow intencionado).
Muestra el código que estás utilizando ahora.
Por cierto, ¿de cuantos archivos de texto (o veces que se llama el método "Replace" y se adjunta texto al objeto "StringBuilder") estamos hablando exactamente?, es que, para que te diera esa excepción debería ser un número de veces colosal, pero no descartaré la posibilidad ya que no se cuanta magnitud de datos estás trabajando.
Saludos!
Cita de: Eleкtro en 28 Octubre 2015, 03:29 AM
Esa excepción es síntoma de estar utilizando prácticas recursivas, por algún método/algoritmo con una recursividad excesiva y/o infinita la cual con sus llamadas colapsa el tamaño de la pila o stack, provocando así un overflow.
No puedo reproducir el conflicto con el código que te mostré en lo que denominariamos "circunstancias normales" (no llevando al límite las capacidades para provocar un stack-overflow intencionado).
Muestra el código que estás utilizando ahora.
Por cierto, ¿de cuantos archivos de texto (o veces que se llama el método "Replace" y se adjunta texto al objeto "StringBuilder") estamos hablando exactamente?, es que, para que te diera esa excepción debería ser un número de veces colosal, pero no descartaré la posibilidad ya que no se cuanta magnitud de datos estás trabajando.
Saludos!
Buenos días bro...
Feliz día del Ingeniero!
Hagamos algo mejor...
Te voy a enviar en un PM un enlace para que bajes los archivos y la solucion.
Saludos y de nuevo mil gracias.
Cita de: Eleкtro en 28 Octubre 2015, 03:29 AM
Esa excepción es síntoma de estar utilizando prácticas recursivas, por algún método/algoritmo con una recursividad excesiva y/o infinita la cual con sus llamadas colapsa el tamaño de la pila o stack, provocando así un overflow.
No puedo reproducir el conflicto con el código que te mostré en lo que denominariamos "circunstancias normales" (no llevando al límite las capacidades para provocar un stack-overflow intencionado).
Muestra el código que estás utilizando ahora.
Por cierto, ¿de cuantos archivos de texto (o veces que se llama el método "Replace" y se adjunta texto al objeto "StringBuilder") estamos hablando exactamente?, es que, para que te diera esa excepción debería ser un número de veces colosal, pero no descartaré la posibilidad ya que no se cuanta magnitud de datos estás trabajando.
Saludos!
Saludos mi amigo,
Cuando puedas dale un vistazo al mensaje privado que te envié.
Gracias.
Cita de: elqueteconte en 30 Octubre 2015, 22:36 PM
Para reproducir el error haz lo siguiente ejecuta el script y en Empresa selecciona Mi Diario.
El problema está aquí:
If (cb.SelectedIndex = 1) Then
'MessageBox.Show("Selecciono {0}", "Mensaje", MessageBoxButtons.OK, MessageBoxIcon.Error)
'cmbemp.Focus()
Dim comparisonType As StringComparison = StringComparison.OrdinalIgnoreCase
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "MCBO-02", "MBO-03", comparisonType)
FindFileAndReplaceTextIn(sourceDir, "GL.txt", "MCBO-03", "MBO-03", comparisonType)
FindFileAndReplaceTextIn(sourceDir, "IMP6000.txt", "TXT01", "MBO-03", comparisonType)
FindFileAndReplaceTextIn(sourceDir, "IMP6000.txt", "TXT02", "MBO-03", comparisonType)
Else
Exit Sub
End If Public Sub FindFileAndReplaceTextIn(...)
...
Dim txt As String = File.ReadAllText(txtfile.FullName, Encoding.Default).
Replace(txtfind, txtreplace, comparisonType, 128)
...
End Sub Public Function Replace(...) As String
Return StringExtensions.Replace(sender, findWhat, replaceWith, comparisonType, stringBuilderCapacity:=0)
End FunctionLa función Replace se llama a si misma de forma infinita, y eso causa el colapso de la pila.
Se te pasó por alto a ti o a mi añadir la otra función que compartí, el "
Replace" que era privado.
Para solucionarlo, reemplaza esto:
Public Sub FindFileAndReplaceTextIn(...)
...
Dim txt As String = File.ReadAllText(txtfile.FullName, Encoding.Default).
Replace(txtfind, txtreplace, comparisonType, 128)
...
End Subpor esto otro:
Public Sub FindFileAndReplaceTextIn(...)
...
Dim txt As String = File.ReadAllText(txtfile.FullName, Encoding.Default).
Replace(txtfind, txtreplace, comparisonType)
...
End SubY reemplaza el contenido del modulo "
StringExtensions", por esto:
' ESTE MODULO ESTÁ INCOMPLETO, SOLO LE AÑADÍ LAS FUNCIOENS DE REEMPLAZAMIENTO DE TEXTO.
' SI QUIERES EL CÓDIGO FUENTE COMPLETO CON MÁS FUNCIONES INTERESANTES, PUEDES DESCARGARLO AQUÍ:
' https://github.com/ElektroStudios/VBNetSnippets/blob/master/String/String%20Extensions.vb
#Region " Public Members Summary "
#Region " Functions "
' String.Replace(String, String, StringComparison) As String
' String.ReplaceRegEx(String, String, RegExOptions) As String
#End Region
#End Region
#Region " Option Statements "
Option Strict On
Option Explicit On
Option Infer Off
#End Region
#Region " Imports "
Imports System
Imports System.Linq
Imports System.Diagnostics
Imports System.Runtime.CompilerServices
Imports System.Text
Imports System.Text.RegularExpressions
#End Region
Namespace Tools
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Contains custom extension methods to use with a <see cref="String"/>.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
Public Module StringExtensions
#Region " Public Extension Methods "
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Replaces text using a regular expression.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim str As String = "Hello World!".ReplaceRegEx("world", "kitty", RegexOptions.IgnoreCase)
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="sender">
''' The source <see cref="String"/>.
''' </param>
'''
''' <param name="findWhat">
''' The <see cref="Regex"/> find expression.
''' </param>
'''
''' <param name="regexOptions">
''' The <see cref="RegexOptions"/>.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <exception cref="ArgumentNullException">
''' findWhat
''' </exception>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' The replaced string.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
<Extension>
Public Function ReplaceRegEx(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
Optional ByVal regexOptions As RegexOptions =
RegularExpressions.RegexOptions.None) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Return Regex.Replace(sender, findWhat, replaceWith, regexOptions)
End If
End Function
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Replaces text using the specified string comparison type.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim str As String = "Hello World!".Replace("world", "kitty", StringComparison.OrdinalIgnoreCase)
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="sender">
''' The source <see cref="String"/>.
''' </param>
'''
''' <param name="findWhat">
''' The <see cref="Regex"/> find expression.
''' </param>
'''
''' <param name="comparisonType">
''' The string comparison type.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <exception cref="ArgumentNullException">
''' findWhat
''' </exception>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' The replaced string.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
<Extension>
Public Function Replace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison) As String
If String.IsNullOrEmpty(sender) Then
Return sender
ElseIf String.IsNullOrEmpty(findWhat) Then
Throw New ArgumentNullException(paramName:="findWhat")
Else
Return StringExtensions.InternalReplace(sender, findWhat, replaceWith, comparisonType, stringBuilderCapacity:=-1)
End If
End Function
#End Region
#Region " Private Methods "
''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Replaces text using the specified string comparison type.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code>
''' Dim str As String = "Hello World!".Replace("world", "kitty", StringComparison.OrdinalIgnoreCase)
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="sender">
''' The source <see cref="String"/>.
''' </param>
'''
''' <param name="findWhat">
''' The <see cref="Regex"/> find expression.
''' </param>
'''
''' <param name="comparisonType">
''' The string comparison type.
''' </param>
'''
''' <param name="stringBuilderCapacity">
''' The initial buffer size of the <see cref="Stringbuilder"/>.
''' This parameter is reserved for testing purposes.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' The replaced string.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
<DebuggerHidden>
<DebuggerStepThrough>
Private Function InternalReplace(ByVal sender As String,
ByVal findWhat As String,
ByVal replaceWith As String,
ByVal comparisonType As StringComparison,
ByVal stringBuilderCapacity As Integer) As String
Dim posCurrent As Integer = 0
Dim lenPattern As Integer = findWhat.Length
Dim idxNext As Integer = sender.IndexOf(findWhat, comparisonType)
Dim result As New StringBuilder(capacity:=If(stringBuilderCapacity <= 0, Math.Min(4096, sender.Length), stringBuilderCapacity))
While (idxNext >= 0)
result.Append(sender, posCurrent, (idxNext - posCurrent))
result.Append(replaceWith)
posCurrent = (idxNext + lenPattern)
idxNext = sender.IndexOf(findWhat, posCurrent, comparisonType)
End While
result.Append(sender, posCurrent, (sender.Length - posCurrent))
Return result.ToString
End Function
#End Region
End Module
End NamespaceSaludos
Saludos amigo,
Estoy testeando la app y le he encontrado un solo detalle y es que luego de que hace el merge de los archivos está dejando una linea en blanco en el archivo final (no se si me explico?) :-\
Revisando y estudiando el código me doy cuenta que el problema está en la función FindAndMergeFiles, pienso que despues de hacer el merge hay que hacer un barrido del mismo archivo para quitar las lineas vacias, la rutina por lo que he leido sería mas o menos así:
archivotxt = Regex.Replace(archivotxt, "^\r|\n\r|\n$", "")
La pregunta sería en que parte y como incluiría esa sentencia en la funcion FindAndMergeFiles.
Desde ya mil gracias de nuevo amigo.
RegEx es lento, intenta evitarlo.
En el método FindAndMergeFiles realiza esta modificación:
Using sr As StreamReader = txtfile.OpenText
Using sw As New StreamWriter(Path.Combine(topDir.FullName, curFilename), append:=True, encoding:=Encoding.Default, bufferSize:=4096)
Dim content As String = sr.ReadToEnd.Replace(Environment.NewLine, "")
If Not String.IsNullOrEmpty(content) Then
sw.WriteLine(content)
End If
End Using ' sw
End Using ' sr
La linea que queda en blanco al final del archivo es normal, ya que se está llamando al método WriteLine.
Saludos
Cita de: Eleкtro en 5 Noviembre 2015, 16:39 PM
RegEx es lento, intenta evitarlo.
En el método FindAndMergeFiles realiza esta modificación:
Using sr As StreamReader = txtfile.OpenText
Using sw As New StreamWriter(Path.Combine(topDir.FullName, curFilename), append:=True, encoding:=Encoding.Default, bufferSize:=4096)
Dim content As String = sr.ReadToEnd.Replace(Environment.NewLine, "")
If Not String.IsNullOrEmpty(content) Then
sw.WriteLine(content)
End If
End Using ' sw
End Using ' sr
La linea que queda en blanco al final del archivo es normal, ya que se está llamando al método WriteLine.
Saludos
Saludos Elektro;
Gracias por responder.
He aplicado el cambio y hace tan bien el trabajo que hasta quita el espacio de fin de registro y junta las lineas ;-), es decir, no toma en cuenta el fin del registro o linea, sino que al final de la linea toma la de abajo y lo concatena con la primera y así sucesivamente.
La idea es que quite las lineas en blanco pero respete la estructura del registro
Gracias mil de nuevo hermano por todo tu apoyo y colaboración.
Ejemplo:
Estado InicialCAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
Estado FinalCAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
CAMPO1;CAMPO2;CAMPO3;CAMPO4;CAMPO5;CAMPON
Espero haberme explicado.
Gracias de nuevo....
prueba con :
sw.WriteLine(content & Environment.NewLine)
Saludos
Cita de: Eleкtro en 5 Noviembre 2015, 17:56 PM
prueba con :
sw.WriteLine(content & Environment.NewLine)
Saludos
No sirvió con eso pues me colocaba una linea con el registro y una linea vacia.
Investigando logré encontrar un código con el que sí funcionó; entonces cambié esto:
Dim content As String = sr.ReadToEnd.Replace(Environment.NewLine, "")
If Not String.IsNullOrEmpty(content) Then
sw.WriteLine(content & Environment.NewLine)
End If
Por esto:
While Not sr.EndOfStream
Dim content As String = sr.ReadLine
If content.Length > 0 Then
sw.WriteLine(content)
End While
Que te parece?
Con esto está haciendo lo que inicialmente se me pidio, ahora tengo que ir con la segunda fase del esto que se está convirtiendo en un proyecto muy interesante.
Te agradezco la ayud que me haz brindado hasta este momento y espero poder seguir contando con ella.
Gracias mil de nuevo.