Hola amigos soy nuevo en la comunidad, ahora tengo una gran duda pues realizare un proyecto y tratando de salir un poco de lo rudimentario quisiera hacer algo inovador, quisiera poder programar un pic para poder usar diferentes rutinas al pulsar "push botons" por ejemplo el GIRO De UN MOTOR ACTIVARLO POR (Boton1) --> 5 min, BOTON 2 --> 10 min. ETC ETC y con que pic lo haria! ( Eh manejado PIC16F84A y programaba con Pic Simulator!
:¬¬
Cita de: 16BITS en 13 Febrero 2014, 02:59 AM
Hola amigos soy nuevo en la comunidad, ahora tengo una gran duda pues realizare un proyecto y tratando de salir un poco de lo rudimentario quisiera hacer algo inovador, quisiera poder programar un pic para poder usar diferentes rutinas al pulsar "push botons" por ejemplo el GIRO De UN MOTOR ACTIVARLO POR (Boton1) --> 5 min, BOTON 2 --> 10 min. ETC ETC y con que pic lo haria! ( Eh manejado PIC16F84A y programaba con Pic Simulator!
Hola:
1. ¿Puedes decir que tipo de motor usas, si es un motor DC normalito, un motor pasp a paso (PAP)?
2. ¿Puedes explicar mejor paso a paso cuántos botones quieres para el PIC16F84A?
3. ¿También puedes explicar otras cosas más detallado para entenderte? POr ejemplo, dices que si pulsas un botón el motor gira. No entiendo que quieres decir 5 minutos y luego 10 minutos.
Un cordial saludo.
Pues Es Un Motor DC, y pues la idea es programar un pic para poder hacer que gire por determinados tiempos, EJEMPLIFICANDO:
Quisiera tener digamos 3 Pulsadores, con estos mismos poder accionar el motor en tiempos diferentes,
Pulsador1 - Que active el motor por 5 min
Pulsador2 - Que active el motor por 10 min
Pulsador3 - Que lo active por 20 min
Quiero saber como podria hacer eso! :C
Buenas:
Te entiendo mejor, aún así te falta más información que te diré ahora. De entrada se puede hacer. No has dicho si lo vas hacer bajo ASM o en C o otro lenguaje.
Si tienes ya pulsado el botón 2 que dura 10 minutos el motor encendido. ¿Qué ocurre al PIC si pulsas otro botón si aún no se ha acabado el tiempo?
Lo pregunto porque en este sentido no has comentado nada.
Si pulsando el botón 2 se activa durante 10 minutos, luego me da por pulsar el botón 1. ¿Qué ocurre?
Pues depende como lo programes, en este caso no hace nada hasta que acabe los 10 minutos, o se interrumpe el tiempo ya empezado y empieza los 5 minutos desde cero del botón 1.
¿Cómo lo deseas?
Hay que indicar paso por paso lo que quieres realmente.
Otra cosa. ¿No has pensado en un 4º botón para cancelar los tiempos y detener el motor?
Un saludo.
Bueno Tocaste un buen punto, pensandolo creo que seria factible que al oprimir un segundo boton mediante el proceso ya iniciado, estaria bien que se "sustituya el tiempo por el boton oprimido.
Puntos Claves.
Si Ya Se Inicio Una Rutina Podria Cambiar El Tiempo Oprimiendo Otro Botón.
Al Igual Que Contar Con Un RESETEO
Pretendo Programarlo En El Lenguaje Mas Noble (Debido A Que No Cuento Con Los Conocimientos Para Usar Uno Muy Complejo.
Quisiera Tambier Saber Como Poder Mover El Motor Con El Pic, Debido a que tiene sus salidas de 5V. y el motor es de 12V ? Necesito un integrado
Ya me di a la busqueda de tutoriales, y Mas.
De Antemano GRACIAS!
Hola:
Quiero saber más información. ¿El motor solo irá en un sentido?
El motor necesita un driver o controlador, el mñas usado es este L293D o L293B. La diferencia son que el primero aguanta 0.6 A. y tiene los diodos de protecciónincluido, el otro aguanta 1 A. y los diodos tienes que usarlo al exterior como el 1N4007.
Aquí hay ejemplos.
(http://pic16f84a.org/images/stories/proteus/Fig2909_MotorDC.GIF)
http://pic16f84a.org/proteus.html#Proteus_Capitulo_29
Aquí un código en asm, para controlar motores está bien. No tiene nada que ver con tu propuesta, está bien para coger ideas.
;************************************* MotorDC_01.asm **********************************
;
; ===================================================================
; Del libro "MICROCONTROLADOR PIC16F84. DESARROLLO DE PROYECTOS"
; E. Palacios, F. Remiro y L. López. www.pic16f84a.com
; Editorial Ra-Ma. www.ra-ma.es
; ===================================================================
;
; Programa de control para un motor de corriente continua en funcionamiento y sentido de
; giro. Con RA0=0, el motor se pone en marcha y su sentido de giro dependerá del valor
; que tenga RA4.
;
; ZONA DE DATOS **********************************************************************
LIST P=16F84A
INCLUDE <P16F84A.INC>
__CONFIG _CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
#DEFINE EntradaMarcha PORTA,0 ; Interruptor de puesta en marcha.
#DEFINE EntradaSentido PORTA,4 ; Interruptor de sentido de giro.
; ZONA DE CÓDIGOS ********************************************************************
ORG 0
Inicio
bsf STATUS,RP0
bsf EntradaMarcha ; Configura las líneas de entrada.
bsf EntradaSentido
clrf PORTB ; Las líneas del Puerto B configuradas como salida.
bcf STATUS,RP0
Principal
clrw ; Con esta combinación se detiene el motor.
btfsc EntradaMarcha ; Comprueba el estado del interruptor de funcionamiento.
goto ActivaSalida
movlw b'00010010' ; Gira en un sentido.
btfsc EntradaSentido ; Comprueba el sentido de giro deseado.
movlw b'00010001' ; Gira en el otro sentido.
ActivaSalida
movwf PORTB
goto Principal
END
Ya que has nombrado el Reset, pues otra propuesta fácil de hacer es. Si tienes pulsado el botón 2 a 10 minutos, si pulsas otro botó, por ejemplo el botón 1. No se interrumpirá el proceso hasta que acabes el tiempo exceptuando que pulses Reset. Se detendrá todo. Está bien como seguridad.
Pregunta opcional.
¿Para qué es este experimento?
Saludo.
Es para un proyecto de la escuela es para un prototipo de calentar carnes pero mediando tiempos.
Enviado desde mi XT1032 mediante Tapatalk
Hola:
¿Qué es lo que dices, no lo encuentro por google?
En cuanto al código te lo haré, deja acabar. Luego lo pruebas. ¿Tienes para grabar el PIC?
¿Tienes el circuito montado?
Un saludo.
Si tengo un cargador de pic
Enviado desde mi XT1032 mediante Tapatalk
Y tengo el circuito armado. No está en Google es pura innovación o eso se pretende
Enviado desde mi XT1032 mediante Tapatalk
Hola:
Lo tengo medio terminado y estoy haciendo pruebas. Hay una cosa que aún no me has escrito, ::)
Por ejemplo, ¿el motor DC siempre funciona en un sentido o hay cambios de sentido?
Si hay cambios de sentidos el esquema de abajo te vale.
(http://pic16f84a.org/images/stories/proteus/Fig2909_MotorDC.GIF)
Si solo tiene un sentido, con un transistor y un diodo de protección te irá bien com indica abajo.
(http://embedded-lab.com/blog/wp-content/uploads/2010/12/Circuit_SingleTransistorDCMotor.png)
Motorcito. Rercuerda, dime que tensión usa el motor.
(http://embedded-lab.com/blog/wp-content/uploads/2010/12/Img_DC_Motor.jpg)
(http://davidhunt.ie/wp-content/uploads/2012/08/Motor1.jpg)
Esperando tus respuestas.
Puedes poner fotos de tu proyecto.
Saludo.
Que tal compañero muchas gracias por el apoyo, bueno el motor si gira para un solo lado no cambia el sentido. (http://s2.subirimagenes.com/imagen/previo/thump_8815926captura.png)
Unas Fotos adjuntas de el proyecto, te agradeceria si me muestras un diagrama como irian los pulsadores y todo.
(http://s2.subirimagenes.com/imagen/previo/thump_8815927proyecto1.png)
Buenas:
1) ¿Cómo hiciste ese dibujo? ¿Con AudoCAD?
2) Voy a ponerme manos a la obra. Motor sin sentido, 4 pulsadores:
Pulsador 1 --> 5 minutos.
Pulsador 2 --> 10 minutos.
Pulsador 3 --> 20 minutos.
Reset --> Para detener los tiempos. Es como si fuera un STOP. En realidad resetea el PIC y lo pone en modo inicio, esperando que pulses un botón.
3) Haré un esquema eléctrico y te comento los componentes que necesitas.
4) ¿Cuántos voltios aguanta el motor y cuanto consume? (Lo comento proque el PIC agauanta 5V y el motor puede ser más, así que deberás usar dos fuentes alimetación. En este momento de lo que me digas, hay que usar ciertos componentes o no).
En cuanto a grabar el archivo compilado llamado archivo.hex del PIC16F84A, aquí dejo dos tutoriales de como hacerlo. Uno con el famoso y popular grabador IC-Prog y el otro WinPIC800:
http://electronica-pic.blogspot.com.es/2009/03/manual-ic-prog.html
http://electronica-pic.blogspot.com.es/2009/03/manual-basico-del-winpic800.html
:)
@Meta faltaría el reset del pic no? Ya que por el esquema que veo no se usa la interrupción ni el MCLR del pic.
Yo para hacer un reset de tiempo, mediante el MCLR se puede realizar ya que lo que se hace es un reset del programa (es como apagar y encender) aunque trabajando con motores lo ideal es hacerlo mediante interrupción, éste pic por lo que veo tiene una, la INT0.
Yo pondría un pulsador de reset en la INT0 donde pausara el contador de tiempo reseteandolo. Además puedes añadir algo mas de código por si te interesa hacer algo al cancelar la temporizacion.
El dibujo lo hize en Google Sketchup, El motor es de 12V. Muchas Gracias Por Apoyarme Con Esto Amigo!
Enviado desde mi XT1032 mediante Tapatalk
Hola:
Me habías respondido desde ayer y no me había dado cuenta que ya pasó a la página 2.
En cuanto al INT, lo puedo poner, pero no hará efecto, ya que los tiempos son mediante subrutinas (http://electronica-pic.blogspot.com.es/2012/02/retardos-para-pic12f-16f-y-18f.html) y el PIC queda como esclavo, es decir, no puedes interrumpir una tarea ya comenzada hasta que esta se acabe. Sirve si usas un Timer 0 con interrupción, lo malo que no alcanza los 20 minutos de tiempo para ello, pero si en las subrutinas. Gracias por aportar ideas.
Por lo que se ve, ahora es esto:
Pulsador 1 --> 5 minutos.
Pulsador 2 --> 10 minutos.
Pulsador 3 --> 20 minutos.
Reset --> Para detener los tiempos. Es como si fuera un STOP. En realidad resetea el PIC y lo pone en modo inicio, esperando que pulses un botón.
Motor DC 12V.
PIC16F84A 5V.
¿Qué tecnología te gusta o driver para controlarlo?
Con un transistor y resistencias o con un IC L293D.
Usted elige, antes de que empiece hacer el esquema y programarlo en asm. También haré adaptaciones a otros PIC como 16F627A, 16F628A, 16F648A y 16F88 por si en algún funturo te haga falta.
Un saludo.
Hay ahí de el driver no se mucho, preferiría eso a tu criterio. En cuanto a lo otro preferiría un IC L293D.
Enviado desde mi XT1032 mediante Tapatalk
Hola:
Si prefieres el L293D (http://www.youtube.com/watch?v=j7loGQ-dYGU), es más fácil, no hay que calcular nada ya que este IC aguanta de 4.5V a 36V hacia ese driver.
(http://www.adafruit.com/adablog/wp-content/uploads/2012/05/L293.png)
Ver vídeo para que te hagas una idea como funcona el driver.
[youtube=640,360]http://www.youtube.com/watch?v=j7loGQ-dYGU[/youtube]
De los tres motores que ves arriba, se usará en la parte arriba derecha.
Ya voy a empezar a programar..............
¿Alguna otra pregunta?
Saludo.
Es todo amigo muchisimas gracias!
Enviado desde mi XT1032 mediante Tapatalk
Hola
Para que no te sientas avandonado, estoy con el código. Por ahora te muesto uno incompleto y no útil, solo para que sepas que estoy trabajando.
Edito:
Ya he acabado.
(http://www.subeimagenes.com/img/router-zyxel-850060.png)
Saludo.
Hola de nuevo:
He acabado esquema como el código. Quiero saber si todo está correcto y eches un ojo a todo. Haz pedido el "esquema 1" lo mensionado antes.
(http://www.subeimagenes.com/img/router-zyxel-850049.png)
Mi otra propuesta es este "esquema 2" de abajo. Se ha incluido un pulsador más para el STOP, por ahora no es funcional, estoy en ello por si lo logro. Por ahora sigue siendo el Reset. Otra cosa que he incluido son 3 Led, para que en todo momento tengas la seguridad en que tiempo tienes activo el temporizador actualmente.
(http://www.subeimagenes.com/img/router-zyxel-850073.png)
Lista de componentes para el segundo esquema:CitarResistencias:
R1, R2, R3, R4, R5 = 10 K - 1/4W.
R7, R8, R9 = 330 Ohm - 1/4 W.
R6 = 100 Ohm - 1/4 W.
Condensadores:
C1, C2 = 22 pF / 6V
C3 = 100 nF / 6V
Diodos:
D1, D2, D3 = Led de 3 ó 5 mm color rojo, verde o naranja. 2V/25 mA.
Oscilador de cuarzo:
X1 = 4 MHz
Circuitos integrados:
IC1 = PIC16F84A-04
IC2 = L293D
Otros componentes:
M1 = Motor DC 12 V.
5 micropulsadores.
Aunque montes el primer esquema, la programación es del 2º y te funcionan igual.
¿Alguna otra sugerencia, pregunta, ayuda?
un saludo.
Creo que te quedo todo perfecto, la programacion me la pasarias por mi correo o aqui mismo lo subirias es que quisiera montarlo ya que cuento con el cargador de PIC. Muchas Gracias Por Tu Ayuda!
Hola:
La programación está aquí.
Muchas suerte.
Quiero si es posible y tu tiempo lo permite que, cuando tengas montado aunque sea protoboard o PCB, muestres fotos reales del proyecto, y si incluye un vídeo, mejor que mejor. Con tu permiso, subiré esas fotos y vídeos a mi blog con el proyecto completo gracias a ti.
(http://www.subeimagenes.com/img/motor-dc-pic16f84a-2-850192.png)
El código fuente:
; ZONA DE DATOS **********************************************************************
LIST P=16F84A ; Procesador.
INCLUDE <P16F84A.INC> ; Definición de las etiquetas del PIC.
__CONFIG _CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
__IDlOCS 0001 ; Versión del programa.
Variables UDATA_SHR
RAM RES 1
RAM_1 RES 1
RAM_2 RES 1
RAM_3 RES 1
RAM_4 RES 1
RAM_5 RES 1
RAM_6 RES 1
RAM_7 RES 1
RAM_8 RES 1
RAM_9 RES 1
RAM_10 RES 1
RAM_11 RES 1
RAM_12 RES 1
RAM_13 RES 1
RAM_14 RES 1
RAM_15 RES 1
RAM_16 RES 1
RAM_17 RES 1
#DEFINE Pulsador_1 PORTA,4 ; Pulsador conectado a RA4.
#DEFINE Pulsador_2 PORTA,3 ; Pulsador conectado a RA3.
#DEFINE Pulsador_3 PORTA,2 ; Pulsador conectado a RA2.
#DEFINE Pul_STOP PORTA,1 ; Pulsador de parada del motor.
#DEFINE Motor PORTB,7 ; Línea donde se conecta el motor.
#DEFINE Led_1 PORTB,6 ; Led 1.
#DEFINE Led_2 PORTB,5 ; Led 2.
#DEFINE Led_3 PORTB,4 ; Led 3.
; ZONA DE CÓDIGOS ********************************************************************
ORG 0 ; El programa comienza en la dirección 0.
Inicio
bsf STATUS,RP0 ; Acceso al Banco 1.
bsf Pulsador_1 ; La línea RA4 se configura como entrada.
bsf Pulsador_2 ; La línea RA3 se configura como entrada.
bsf Pulsador_3 ; La línea RA2 se configura como entrada.
bsf Pul_STOP ; La línea RA1 se configura como entrada.
bcf Motor ; Se configura como salida.
bcf Led_1 ; Led de aviso 5 minutos en activo.
bcf Led_2 ; Led de aviso 10 minutos en activo.
bcf Led_3 ; Led de aviso 20 minutos en activo.
bcf STATUS,RP0 ; Acceso al Banco 0.
bcf Motor ; En principio Motor apagado igual
bcf Led_1 ; que los Leds.
bcf Led_2
bcf Led_3
Principal
btfsc Pulsador_1 ; ¿Pulsador presionado?, ¿(Pulsador)=0?
goto Fin ; No. Vuelve a leerlo.
call Retardo20ms ; Espera que se estabilicen los niveles de tensión.
btfsc Pulsador_1 ; Comprueba si es un rebote.
goto Fin ; Era un rebote y sale fuera.
bsf Motor ; Activa el motor y
bsf Led_1 ; enciende el Led 1 que significa
call Retardo5m ; los 5 minutos encendido.
bcf Motor ; Apaga el motor y
bcf Led_1 ; el Led 1.
EsperaDejePulsar_1
btfss Pulsador_1 ; ¿Dejó de pulsar?. ¿(Pulsador)=1?
goto EsperaDejePulsar_1 ; No. Espera que deje de pulsar.
Fin
btfsc Pulsador_2 ; ¿Pulsador presionado?, ¿(Pulsador)=0?
goto Fin2 ; No. Vuelve a leerlo.
call Retardo20ms ; Espera que se estabilicen los niveles de tensión.
btfsc Pulsador_2 ; Comprueba si es un rebote.
goto Fin2 ; Era un rebote y sale fuera.
bsf Motor ; Activa el motor y
bsf Led_2 ; enciende el Led 2 que significa
call Retardo10m ; los 10 minutos encendido.
bcf Motor ; Apaga el motor y
bcf Led_2 ; el Led 2.
EsperaDejePulsar_2
btfss Pulsador_2 ; ¿Dejó de pulsar?. ¿(Pulsador)=1?
goto EsperaDejePulsar_2 ; No. Espera que deje de pulsar.
Fin2
btfsc Pulsador_3 ; ¿Pulsador presionado?, ¿(Pulsador)=0?
goto Fin3 ; No. Vuelve a leerlo.
call Retardo20ms ; Espera que se estabilicen los niveles de tensión.
btfsc Pulsador_3 ; Comprueba si es un rebote.
goto Fin3 ; Era un rebote y sale fuera.
bsf Motor ; Activa el motor y
bsf Led_3 ; enciende el Led 3 que significa
call Retardo20m ; los 10 minutos encendido.
bcf Motor ; Apaga el motor y
bcf Led_3 ; el Led 3.
EsperaDejePulsar_3
btfss Pulsador_3 ; ¿Dejó de pulsar?. ¿(Pulsador)=1?
goto EsperaDejePulsar_3 ; No. Espera que deje de pulsar.
Fin3 goto Principal
; Subrutinas ****************************************************************
Retardo20ms
;199993 cycles
movlw 0x3E
movwf RAM_8
movlw 0x9D
movwf RAM_9
Retardo20ms_0
decfsz RAM_8, f
goto $+2
decfsz RAM_9, f
goto Retardo20ms_0
;3 cycles
goto $+1
nop
;4 cycles (including call)
return
Retardo5m
;299999995 cycles
movlw 0x54
movwf RAM_10
movlw 0xA1
movwf RAM_11
movlw 0xFD
movwf RAM_12
movlw 0x02
movwf RAM_13
Retardo5m_0
decfsz RAM_10, f
goto $+2
decfsz RAM_11, f
goto $+2
decfsz RAM_12, f
goto $+2
decfsz RAM_13, f
goto Retardo5m_0
;1 cycle
nop
;4 cycles (including call)
return
Retardo10m
;599999992 cycles
movlw 0xA9
movwf RAM_4
movlw 0x41
movwf RAM_5
movlw 0xFA
movwf RAM_6
movlw 0x04
movwf RAM_7
Retardo10m_0
decfsz RAM_4, f
goto $+2
decfsz RAM_5, f
goto $+2
decfsz RAM_6, f
goto $+2
decfsz RAM_7, f
goto Retardo10m_0
;4 cycles
goto $+1
goto $+1
;4 cycles (including call)
return
cblock
RAM
RAM_1
RAM_2
RAM_3
endc
Retardo20m
;1199999995 cycles
movlw 0x54
movwf RAM_14
movlw 0x82
movwf RAM_15
movlw 0xF3
movwf RAM_16
movlw 0x08
movwf RAM_17
Retardo20m_0
decfsz RAM_14, f
goto $+2
decfsz RAM_15, f
goto $+2
decfsz RAM_16, f
goto $+2
decfsz RAM_17, f
goto Retardo20m_0
;1 cycle
nop
;4 cycles (including call)
return
END
Espero que te vaya de maravilla, en el simulador me funciona bien, lo probaré también en realidad realidad.
Suerete...
Me gustaría que me pasaras tu cuenta de PayPal para apoyarte por apoyarme compañero
Enviado desde mi XT1032 mediante Tapatalk
Meta yo soy más de programación de PICs en C y toco poco de ASM, y me quedé impresionado del trabajo que hiciste sin llevarte nada a cambio a parte de las gracias. Espero que el usuario se moleste en hacer unas fotos y un vídeo una vez lo tenga montado...
Una posible mejora sería añadir control del motor por PWM para moderar la velocidad de giro a la que se asa la carne, aunque no sé si sería útil o es mejor hacerlo a una velocidad constante.
Otra sería añadir protección contra sobrecorriente del motor y así evitar quemarlo en el caso de que hubiera algún fallo. Se podría hacer fácilmente con un comparador e interrupciones, aunque no sé si ese modelo tiene comparadores la verdad.
En fin solo eran ideas para exprimir el PIC un poquito más.
EDITO: bueno retiro lo dicho ya que no vi que 16BITS había publicado... y yo también me quedo a la espera de ver el proyecto montado ;D
Un saludo!
Cita de: 16BITS en 18 Febrero 2014, 23:48 PM
Me gustaría que me pasaras tu cuenta de PayPal para apoyarte por apoyarme compañero
Enviado desde mi XT1032 mediante Tapatalk
Hola campeón:
He tardado en hacerlo porque tuve que mirar los libros viejos para recordar ciertas cosas del asm, ejejjejeej. Al final, el circuito funciona. Gracias a los apoyos, puedomos conseguir recursos que la gente me pidan para hacer proyectos de este tipo y más complejos, incluido tutoriales.
No esperaba una donación tan pronto para este año y es de agradecer. :)
El enlace está en el botón pequeño de donar, abajo.
http://electronica-pic.blogspot.com.es/2010/11/dona-y-ayudas-para-futuros-proyectos.html
Puede comentar cualquier cosa para el futuro. Ahhhhh, adaptaré para otros PIC similares del 16F84A para que la gente tenga más opción de montarlo si no encuentra el indicado. 16F27A/628A/648A, 16F87/88 y 16F886. Si una persona no encuentra uno en su tienda habitual, encuentra otro. Lo publicaré en el Blog (http://electronica-pic.blogspot.com.es/) las actuallizaciones.
Gracias de nuevo por seguir adelante con el proyecto sin que te canses. Me di cuenta que este tema, tiene muchos visitantes.
Cita de: xiruko en 18 Febrero 2014, 23:58 PM
Meta yo soy más de programación de PICs en C y toco poco de ASM, y me quedé impresionado del trabajo que hiciste sin llevarte nada a cambio a parte de las gracias. Espero que el usuario se moleste en hacer unas fotos y un vídeo una vez lo tenga montado...
Una posible mejora sería añadir control del motor por PWM para moderar la velocidad de giro a la que se asa la carne, aunque no sé si sería útil o es mejor hacerlo a una velocidad constante.
Otra sería añadir protección contra sobrecorriente del motor y así evitar quemarlo en el caso de que hubiera algún fallo. Se podría hacer fácilmente con un comparador e interrupciones, aunque no sé si ese modelo tiene comparadores la verdad.
En fin solo eran ideas para exprimir el PIC un poquito más.
EDITO: bueno retiro lo dicho ya que no vi que 16BITS había publicado... y yo también me quedo a la espera de ver el proyecto montado ;D
Un saludo!
Hola Xiruko:
El C me estaba metiendo hace poco con CCS, ahora me dio por Arduino. Estoy aprendiendo y me queda mucho, ejejjejeje. El que sepa hacer este proyecto en C, es bienvenido, pruebo el código, hago pruebas en mi casa haber si sirve realmente que no sea simuladores, y lo subo al Blog si lo desean.
Le animo que muestre fotos y vídeos del proyecto si lo desea. Siento curiosidad, de todas maneras, en estos momentos, estoy adaptando el PIC16F84A al PIC16F88 porque es el que tengo ahora en este mismo momento.
En cuanto a exprimir el PIC un poquito más, más bien sería con el 16F88 que tiene más funciones. En cuanto a PWM, como es velocidad constante, no hace falta. Por cierto, se me olvidó poner el esquema, el condensador de protección del motor en paralelo. Lo actualizaré cuando pueda.
(http://2.bp.blogspot.com/-BpQusSXao7U/T5-4L-nEZ3I/AAAAAAAAAR4/bzB52rVzp2g/s1600/motor+cc+con+220nF.jpg)
Gracias por la sugerencia, gracias por seguir leyendo y aún así, me sorprende que en 5 días haya muchos visitante por este tema.
;)
Muchas Gracias, Una PRegunta en que programa puedo montar la programacion para montarlo al pic :C
Ya Aporte Mi Donacion!
(http://dangerousprototypes.com/wp-content/media/2011/12/21086.jpg)
Hola:
El MPLAP X lo puedes descargar en cualquier Sistema Operativo Windows, Linux y Mac en este enlace (http://www.microchip.com/pagehandler/en-us/family/mplabx/). Te viene con asm incluido. No olvidar que MPLAB X es un IDE.
Descarga directa pinchando aquí:
Windows:
MPLAB X v2.00 - DESCARGAR (http://www.microchip.com/mplabx-ide-windows-installer).
Linux:
MPLAB X v2.00 - DESCARGAR (http://www.microchip.com/mplabx-ide-linux-installer).
Mac:
MPLAB X v2.00 - DESCARGAR (http://www.microchip.com/mplabx-ide-osx-installer).
Muchos ánimos.
Edito:
He recibido donación para apoyar Blog (http://electronica-pic.blogspot.com.es/2010/11/dona-y-ayudas-para-futuros-proyectos.html).
Muchísimas gracias y a los demás también por las sugerencias.
Hola de nuevo:
Dejo el esquema mejorado, ya que se ha incorporado un condensador en el L293D y en el propio motor.
(http://www.subeimagenes.com/img/esquema-proteus-motor-dc-16f84a-850726.png)
Lista de componentes:CitarResistencias:
R1, R2, R3, R4, R5 = 10 K - 1/4W.
R7, R8, R9 = 330 Ohm - 1/4 W.
R6 = 100 Ohm - 1/4 W.
Condensadores:
C1, C2 = 22 pF / 6V
C3,C5 = 100 nF / 6V
C4 = 250 n / 16V
Diodos:
D1, D2, D3 = Led de 3 ó 5 mm color rojo, verde o naranja. 2V/25 mA.
Oscilador de cuarzo:
X1 = 4 MHz
Circuitos integrados:
IC1 = PIC16F84A-04
IC2 = L293D
Otros componentes:
Z1 = Zócalo de 18 pines.
Z2 = Zócalo de 16 pines.
M1 = Motor DC 12 V.
5 micropulsadores.
Cosas que debes tener en cuenta. Si es la misma fuente alimenteción de los 5V y 12V, no le pasará nada. Si son de fuentes diferenes conectado a la misma masa, no funcionará.
(http://www.subeimagenes.com/img/router-zyxel-850850.png)
Código más optimizado y corregido.
; ZONA DE DATOS **********************************************************************
LIST P=16F84A ; Procesador.
INCLUDE <P16F84A.INC> ; Definición de las etiquetas del PIC.
__CONFIG _CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
__IDlOCS 0001 ; Versión del programa.
Variables UDATA_SHR 0x0C
RAM RES 1
RAM_1 RES 1
RAM_2 RES 1
RAM_3 RES 1
RAM_4 RES 1
RAM_5 RES 1
RAM_6 RES 1
RAM_7 RES 1
RAM_8 RES 1
RAM_9 RES 1
RAM_10 RES 1
RAM_11 RES 1
RAM_12 RES 1
RAM_13 RES 1
RAM_14 RES 1
RAM_15 RES 1
RAM_16 RES 1
RAM_17 RES 1
#DEFINE Pulsador_1 PORTA,4 ; Pulsador conectado a RA4.
#DEFINE Pulsador_2 PORTA,3 ; Pulsador conectado a RA3.
#DEFINE Pulsador_3 PORTA,2 ; Pulsador conectado a RA2.
#DEFINE Pul_STOP PORTA,1 ; Pulsador de parada del motor.
#DEFINE Motor PORTB,7 ; Línea donde se conecta el motor.
#DEFINE Led_1 PORTB,6 ; Led 1.
#DEFINE Led_2 PORTB,5 ; Led 2.
#DEFINE Led_3 PORTB,4 ; Led 3.
; ZONA DE CÓDIGOS ********************************************************************
ORG 0 ; El programa comienza en la dirección 0.
Inicio
bsf STATUS,RP0 ; Acceso al Banco 1.
bsf Pulsador_1 ; La línea RA4 se configura como entrada.
bsf Pulsador_2 ; La línea RA3 se configura como entrada.
bsf Pulsador_3 ; La línea RA2 se configura como entrada.
bsf Pul_STOP ; La línea RA1 se configura como entrada.
bcf Motor ; Se configura como salida.
bcf Led_1 ; Led de aviso 5 minutos en activo.
bcf Led_2 ; Led de aviso 10 minutos en activo.
bcf Led_3 ; Led de aviso 20 minutos en activo.
bcf STATUS,RP0 ; Acceso al Banco 0.
bcf Motor ; En principio Motor apagado igual
bcf Led_1 ; que los Leds.
bcf Led_2
bcf Led_3
Principal
btfsc Pulsador_1 ; ¿Pulsador presionado?, ¿(Pulsador)=0?
goto Fin ; No. Vuelve a leerlo.
call Retardo20ms ; Espera que se estabilicen los niveles de tensión.
btfsc Pulsador_1 ; Comprueba si es un rebote.
goto Fin ; Era un rebote y sale fuera.
bsf Motor ; Activa el motor y
bsf Led_1 ; enciende el Led 1 que significa
call Retardo5m ; los 5 minutos encendido.
bcf Motor ; Apaga el motor y
bcf Led_1 ; el Led 1.
EsperaDejePulsar_1
btfss Pulsador_1 ; ¿Dejó de pulsar?. ¿(Pulsador)=1?
goto EsperaDejePulsar_1 ; No. Espera que deje de pulsar.
Fin
btfsc Pulsador_2 ; ¿Pulsador presionado?, ¿(Pulsador)=0?
goto Fin2 ; No. Vuelve a leerlo.
call Retardo20ms ; Espera que se estabilicen los niveles de tensión.
btfsc Pulsador_2 ; Comprueba si es un rebote.
goto Fin2 ; Era un rebote y sale fuera.
bsf Motor ; Activa el motor y
bsf Led_2 ; enciende el Led 2 que significa
call Retardo10m ; los 10 minutos encendido.
bcf Motor ; Apaga el motor y
bcf Led_2 ; el Led 2.
EsperaDejePulsar_2
btfss Pulsador_2 ; ¿Dejó de pulsar?. ¿(Pulsador)=1?
goto EsperaDejePulsar_2 ; No. Espera que deje de pulsar.
Fin2
btfsc Pulsador_3 ; ¿Pulsador presionado?, ¿(Pulsador)=0?
goto Fin3 ; No. Vuelve a leerlo.
call Retardo20ms ; Espera que se estabilicen los niveles de tensión.
btfsc Pulsador_3 ; Comprueba si es un rebote.
goto Fin3 ; Era un rebote y sale fuera.
bsf Motor ; Activa el motor y
bsf Led_3 ; enciende el Led 3 que significa
call Retardo20m ; los 10 minutos encendido.
bcf Motor ; Apaga el motor y
bcf Led_3 ; el Led 3.
EsperaDejePulsar_3
btfss Pulsador_3 ; ¿Dejó de pulsar?. ¿(Pulsador)=1?
goto EsperaDejePulsar_3 ; No. Espera que deje de pulsar.
Fin3 goto Principal
; Subrutinas ****************************************************************
Retardo20ms
;199993 cycles
movlw 0x3E
movwf RAM_8
movlw 0x9D
movwf RAM_9
Retardo20ms_0
decfsz RAM_8, f
goto $+2
decfsz RAM_9, f
goto Retardo20ms_0
;3 cycles
goto $+1
nop
;4 cycles (including call)
return
Retardo5m
;299999995 cycles
movlw 0x54
movwf RAM_10
movlw 0xA1
movwf RAM_11
movlw 0xFD
movwf RAM_12
movlw 0x02
movwf RAM_13
Retardo5m_0
decfsz RAM_10, f
goto $+2
decfsz RAM_11, f
goto $+2
decfsz RAM_12, f
goto $+2
decfsz RAM_13, f
goto Retardo5m_0
;1 cycle
nop
;4 cycles (including call)
return
Retardo10m
;599999992 cycles
movlw 0xA9
movwf RAM_4
movlw 0x41
movwf RAM_5
movlw 0xFA
movwf RAM_6
movlw 0x04
movwf RAM_7
Retardo10m_0
decfsz RAM_4, f
goto $+2
decfsz RAM_5, f
goto $+2
decfsz RAM_6, f
goto $+2
decfsz RAM_7, f
goto Retardo10m_0
;4 cycles
goto $+1
goto $+1
;4 cycles (including call)
return
Retardo20m
;1199999995 cycles
movlw 0x54
movwf RAM_14
movlw 0x82
movwf RAM_15
movlw 0xF3
movwf RAM_16
movlw 0x08
movwf RAM_17
Retardo20m_0
decfsz RAM_14, f
goto $+2
decfsz RAM_15, f
goto $+2
decfsz RAM_16, f
goto $+2
decfsz RAM_17, f
goto Retardo20m_0
;1 cycle
nop
;4 cycles (including call)
return
END
Si quieres una sugerencia más, añado dos salidas, por si pones un altavoz o un zumbador piezoeléctrico. Cuando termine el tiempo, a parte de apagarse el motor, suena un pitido como el microondas. Ya me dirás si te interesa, lo programo ingernamente, aunque físicamente no lo vayas a usar, si en el futuro decides ponerlo, solo es ponerlo, ya que la programación está hecha.
Ya me dirás la respuesta.
Sigo mejorando si puedo por si acaso...
Muchas gracias de nuevo.
Edito:Ya he sacado otro código con ayuda de amigos bajo el timer 0. Te podrás ahorrar el pulsador y las resistencias del RESET. La nueva función funciiona tal como la querías desde el principio. Por ejemplo:
Si has pulsado el pulsador P2 de 10 minutos, mientras sigue el motor encendido, pulso cualquier pulsador, por ejeplo, el P1 de 5 minutos, ahora el temporizador empezará desce 0 y cuenta los 5 minutos. También tiene la posibilidad de pulsar el botón de Stop en cualquier momento, se detiene el proceso, puedes interrumpir el proceso y sin resetear el PIC.
Si al final lo quieres así, me avisas, preparo el código mejor para que se entienda.
Edito 2:A parte del nuevo código de asm, también tengo el de C bajo XC8. Lo subiré después de revisarlos. ;)
Saludo.
Me Interesa el codigo que me comentas para poder, detenerlo y cambiar el tiempo, ademas el diagrama del zumbador, Suena Aun mejor. Otra cosa me podrias apoyar mostrandome como usar el MPLAB para hacer el proyecto y cargar el PIC.
De Verdad Que Muchas Gracias Compañero!
Hola:
Nuevo esquema. Se incluye un pequeño altavoz como los que usan los ordenadores o PC viejos o un zumbador piezo eléctrico. A pesar de que funcioinan los dos al mismo tiempo, a la hora de montar el circuito, decidirás mmontar físicamente un altavoz o un zumbador. El zumbador te puede dejar zumbado y funciona 5V directamente. El altavoz requiere un trasistor y una resistencia. Es tu elección final.
(http://www.subeimagenes.com/img/router-zyxel-852043.png)
Estoy con el programa nuevo para adaptor los códigos del altavoz y zumbador.
(http://www.fadishop.eu/WebRoot/StorePiensa/Shops/ec2286/4F82/B199/D3BB/A4BB/8FDE/AC10/1414/A686/SOUNDER.jpg)
Programando y haciendo un tutorial sobre el MPLAB con Word. Esto es trabajo de horas y como comprenderás, tardaré en publicarlo. Te daré el aviso cuando lo acabe.
Saludo.
Edito:
Hecho un minitutorial en pdf.
https://drive.google.com/file/d/0B6HKwsbbpgrLQTBUckNaUTMzYUU/edit?usp=sharing
Saludo.
Holas:
El proyecto sigue en pie, probando bajo PIC16F88 con un motor de 5Vdc, para los lectores les dejo un montaje de prototipo.
(http://www.subeimagenes.com/img/router-zyxel-857849.png)
Gracias por visitar.
Hola
Ya que algunos usuarios me piden código, se los paso por ahora en asm para el PIC16F88. Ahor funciona todo. Cuando pueda, presento lomismo para el lenguaje C bajo XC8.
list P=16F88 ; Procesador.
include <p16F88.inc> ; Definición de las etiquetas del PIC.
__CONFIG _CONFIG1, _FOSC_INTOSCIO & _WDTE_OFF & _PWRTE_ON & _MCLRE_ON & _BOREN_ON & _LVP_OFF & _CPD_OFF & _WRT_OFF & _CCPMX_RB3 & _CP_OFF
__CONFIG _CONFIG2, _FCMEN_ON & _IESO_ON
;***************************************
;Declaracion de variables y constantes
;***************************************
#define p1 PORTA,4 ; Pulsador 1.
#define p2 PORTA,3 ; Pulsador 2.
#define p3 PORTA,2 ; Pulsador 3.
#define p4 PORTA,1 ; Pulsador 4.
#define motor PORTB,7 ; Motor DC.
#define led1 PORTB,6 ; Diodo Led 1.
#define led2 PORTB,5
#define led3 PORTB,4
#DEFINE Altavoz PORTB,3 ; Altavoz.
#DEFINE Zumbador PORTB,2 ; Zumbador piezoeléctrico.
ctte_5_min equ .5 ; constante para 5 minutos
ctte_10_min equ .10 ; constante para 10 minutos
ctte_20_min equ .20 ; constante para 20 minutos
ctte_min equ .60 ; para 1 minuto
ctte_timer equ .16 ; para 1 segundo
carga_timer equ .12 ;
variables udata 0x20
cont_timer RES 1
cont_seg RES 1 ; contador de segundos
cont_min RES 1 ; contador de minutos
tiempo_fijado RES 1
PDel0 RES 1
PDel1 RES 1
W_TEMP RES 1
STATUS_TEMP RES 1
PCLATH_TEMP RES 1
RAM RES 1
RAM_1 RES 1
RAM_2 RES 1
RAM_3 RES 1
RAM_4 RES 1
RAM_5 RES 1
RAM_6 RES 1
;**************************************
org 0x00
goto configuracion
org 0x04
;**********************************************************************
; Rutinas de interrupciones
;**********************************************************************
rutina_de_interrupcion
PUSH
MOVWF W_TEMP
SWAPF STATUS,W
CLRF STATUS
MOVWF STATUS_TEMP
MOVF PCLATH,W
MOVWF PCLATH_TEMP
CLRF PCLATH
btfss INTCON,TMR0IF ;verifica si es interrupción temporizada
goto salida_timer0 ;sale de la rutina de interrupción
movlw carga_timer ;
movwf TMR0 ;carga al timer0 para reiniciar cuenta
movfw cont_timer ;
xorlw ctte_timer ;compara si llego al segundo
btfss STATUS,Z
goto salida_timer0 ;sale de la rutina de interrupción si no es 1 segundo
clrf cont_timer ;
incf cont_seg ;se incrementa cada segundo
movfw cont_seg
xorlw ctte_min ;compara si es un minuto
btfss STATUS,Z
goto salida_timer0 ;sale de la rutina de interrupción
clrf cont_seg
incf cont_min ;se incrementa cada minuto
salida_timer0
incf cont_timer
bcf INTCON,TMR0IF
POP
MOVF PCLATH_TEMP,W
MOVWF PCLATH
SWAPF STATUS_TEMP,W
MOVWF STATUS
SWAPF W_TEMP,F
SWAPF W_TEMP,W
retfie
;***********************************************
;Subrutinas
;***********************************************
reiniciar_tiempo
movlw carga_timer
movwf TMR0
clrf cont_timer
clrf cont_seg
clrf cont_min
banksel OPTION_REG
bcf OPTION_REG,T0CS ; timer0 inicia la cuenta
banksel PORTA
bsf INTCON,GIE ; interrupciones habilitadas
bsf motor
return
;*************************************************************
pulsador1
call retardo_10ms
btfsc p1
return
;***********************************************************
btfss p1 ; espera hasta que se suelte el pulsador
goto $-1 ;
;***********************************************************
movlw ctte_5_min
movwf tiempo_fijado
clrf PORTB
call reiniciar_tiempo
call PitidoCorto
bsf led1
return
;*************************************************************
pulsador2
call retardo_10ms
btfsc p2
return
;***********************************************************
btfss p2 ; espera hasta que se suelte el pulsador
goto $-1 ;
;***********************************************************
movlw ctte_10_min
movwf tiempo_fijado
clrf PORTB
call reiniciar_tiempo
call PitidoCorto
bsf led2
return
;*************************************************************
pulsador3
call retardo_10ms
btfsc p3
return
;***********************************************************
btfss p3 ; espera hasta que se suelte el pulsador
goto $-1 ;
;***********************************************************
movlw ctte_20_min
movwf tiempo_fijado
clrf PORTB
call reiniciar_tiempo
call PitidoCorto
bsf led3
return
;*************************************************************
pulsador4
call retardo_10ms
btfsc p4
return
;***********************************************************
btfss p4 ; espera hasta que se suelte el pulsador
goto $-1 ;
;***********************************************************
call detener_tiempo
call Pitido
return
;*************************************************************
detener_tiempo
clrf PORTB
banksel OPTION_REG
bsf OPTION_REG,T0CS ; timer0 detenido
banksel PORTA
bcf INTCON,GIE ; interrupciones desactivadas
;*************************************************************
retardo_10ms
movlw .8
movwf PDel0
PLoop1
movlw .249
movwf PDel1
PLoop2
clrwdt
clrwdt
decfsz PDel1,1
goto PLoop2
decfsz PDel0,1
goto PLoop1
PDelL1
goto PDelL2
PDelL2
clrwdt
return
;******************************************************
; Subrutinas "PitidoLargo", "Pitido" y "PitidoCorto"
;*******************************************************
PitidoLargo
bsf Altavoz
bsf Zumbador
call Retardo_500ms
;******************************************************
Pitido
bsf Altavoz
bsf Zumbador
call Retardo_200ms
;******************************************************
PitidoCorto
bsf Altavoz
bsf Zumbador
call Retardo_20ms
bcf Altavoz
bcf Zumbador
return
;**************************************************
Retardo_500ms
movlw 0x03
movwf RAM
movlw 0x18
movwf RAM_1
movlw 0x02
movwf RAM_2
Retardo_500ms_0
decfsz RAM, f
goto $+2
decfsz RAM_1, f
goto $+2
decfsz RAM_2, f
goto Retardo_500ms_0
goto $+1
return
;******************************************************
Retardo_200ms
movlw 0x3E
movwf RAM_3
movlw 0x9D
movwf RAM_4
Retardo_200ms_0
decfsz RAM_3, f
goto $+2
decfsz RAM_4, f
goto Retardo_200ms_0
goto $+1
nop
return
;******************************************************
Retardo_20ms
movlw 0x9E
movwf RAM_5
movlw 0x10
movwf RAM_6
Retardo_20ms_0
decfsz RAM_5, f
goto $+2
decfsz RAM_6, f
goto Retardo_20ms_0
goto $+1
nop
return
;**********************************************
configuracion
;**********************************************
; configuracion del oscilador interno
;**********************************************
banksel OSCCON ;bank 1
movfw OSCCON
iorlw 0x60 ;oscilador interno a 4Mhz
movwf OSCCON
banksel PORTA ;bank 0
;**********************************************
; Configuración de puertos de entrada y salida
;**********************************************
clrf PORTA ;porta=0
clrf PORTB ;portb=0
banksel ANSEL ;bank 1
clrf ANSEL ;puertos i/o digitales
movlw 0xff ;w=255
movwf TRISA ;porta como entradas
clrf TRISB ;portb como salidas
;***********************************************
;Configuraciond de las interrupcion temporizada
;***********************************************
movlw b'11110111' ;prescaler asignado a timer0, prescaler=256
movwf OPTION_REG
banksel INTCON
movlw b'00100000' ;
movwf INTCON ;interrupciones globales desactivados e interrupción timer0 activado
clrf TMR0
;**********************************************
clrf cont_min
movlw 0xff
movwf tiempo_fijado
bucle
btfss p1
call pulsador1
btfss p2
call pulsador2
btfss p3
call pulsador3
btfss p4
call pulsador4
movfw cont_min
xorwf tiempo_fijado,W
btfss STATUS,Z
goto bucle
incf cont_min
call detener_tiempo
call PitidoLargo ;************************************
goto bucle
;***********************************************************
end
Un saludo.