REMOVABLE DRIVE AUTORUN PROTECTOR RDAP.CMD

[0x0309]

Esta es una Secuencia de comandos de Windows NT.
Sirve para proteger los pendrives, de los malwares que colocan archivos autorun.inf
Si les sirve o les gusta, por favor coméntenlo, y si les gustaría obtener el mismo resultado desde un programa, digánmelo y lo portaré a c.

Actualizado para quienes obtuvieron versiones anteriores.


Version 11:47 28-02-2009
Textos traducidos al inglés para mayor portabilidad.

Version 6:33 28-02-2009
Actualizado el código para ser compatible con Windows Vista, y proteger unidades con sistema de archivos FAT32 y NTFS.

Version 2:36 28-02-2009
Creación de archivo NUL en el supuesto caso que el sistema de archivos sea NTFS dónde la carpeta si es borrable por medios normales, aunque mi pendrive tiene sistema de archivos FAT32.

Version 1:44 28-02-2009
Unlocker 1.8 no puede borrar la carpeta, Gnu Linux tampoco puede.

Código [Seleccionar] Expandir


@ECHO OFF
:: RDAP.CMD
:: REMOVABLE DRIVE AUTORUN PROTECTOR Version 11:47 28-02-2009
:: - EXCLUSIVE SCRIPT FOR ELHACKER.NET - ::
::
:: COMPATIBLE WITH WINDOWS 2000, XP, VISTA
::
:: SCRIPT THAT MAKE INDELIBLE FOLDER CALLED AUTORUN.INF IN REMOVABLE DISK.
:: USE WITH MEASURE DISABLE AUTORUN:
::
:: http://wiki.elhacker.net/seguridad/windows/autorun
::
:: MOST MALWARE CAN NOT CREATE A AUTORUN.INF FILE WITH THIS MEASURE.
:: THIS PREVENTED A SELF UNINTENTIONALLY IN COMPUTER THAT DOES NOT HAVE DISABLE AUTORUN.
::
:: AUTHOR: 0x0309
:: THANKS TO THE SUGGESTION OF Germaniac, berz3k, sirdarckcat.
::
TITLE REMOVABLE DRIVE AUTORUN PROTECTOR
SETLOCAL ENABLEEXTENSIONS
ECHO\Detecting removable drives . . .
SET "TXT=530054004F00520041"
REG QUERY HKLM\SYSTEM\MOUNTEDDEVICES | FIND "%TXT%" 9>NUL 1>&9 2>&1 || SET "TXT=550053004200530054"
FOR /F "DELIMS=\: TOKENS=0X3" %%^^ IN ('REG QUERY HKLM\SYSTEM\MOUNTEDDEVICES ^| FIND "%TXT%"') DO (
VOL %%^^: 8>NUL 1>&8 2>&1 && (
ECHO\Found removable drive %%^^:
IF EXIST %%^^:\AUTORUN.INF (DEL /F /Q /A %%^^:\AUTORUN.INF 7>NUL 1>&7 2>&1)
IF EXIST %%^^:\AUTORUN.INF (RD /Q /S \\?\%%^^:\AUTORUN.INF 6>NUL 1>&6 2>&1)
(MD \\?\%%^^:\AUTORUN.INF\...\) 5>NUL 1>&5 2>&1
(RD /Q /S \\?\%%^^:\AUTORUN.INF\...) 4>NUL 1>&4 2>&1
(CD.>\\?\%%^^:\AUTORUN.INF\NUL) 3>NUL 1>&3 2>&1
IF EXIST %%^^:\AUTORUN.INF (ECHO\The removable drive %%^^: was protected.)
)
)
(0>NUL SET /P %%=Press a key to quit . . . )
PAUSE >NUL
GOTO :EOF



[Darioxhcx]

esta bien el codigo al parecer
pero no seria mejor blokear la ejecucion del autorun ?

saludos

[Kobra5]

Orale!!

Muy bueno
voy a probarlo....

[Germaniac]

Buen script.
yo protejo mi usb asi, por ejemplo si es la unidad G

mkdir G:\AUTORUN.INF\
mkdir G:\AUTORUN.INF\....\
mkdir G:\AUTORUN.INF\....\CON\

y algo que vi en el code es que haces dir a la unidad pero si esta esta vacia no la protege, seria mejor usar el comando vol

[berz3k]

No va en windows vista :-/ , vere si puedo fixearlo con tiempo, en "teoria" a como veo el script deberia funcionar.

-berz3k.

[0x0309]

Buen script.
yo protejo mi usb así, por ejemplo si es la unidad G

mkdir G:\AUTORUN.INF\
mkdir G:\AUTORUN.INF\....\
mkdir G:\AUTORUN.INF\....\CON\

y algo que vi en el code es que haces dir a la unidad pero si esta esta vacia no la protege, seria mejor usar el comando vol

Hey Germaniac al principio me pasó desapercibido tu forma de proteger, y es mucho mejor que mi método, gracias, corregiré el script para implementar tu método, guau 

[0x0309]

Gracias a la sugerencia de Germaniac he actualizado el script, y ahora quedó mucho mejor, aunque lo dejé para que no se vea ninguna carpeta dentro.

Nota: Lo probé con el Unlocker 1.8 y no pudo eliminar la carpeta.

[[u]nsigned]

Muchas gracias, yo tube un problema en un pen que cuando ingresaba a mi pc y le daba dblclk se me abria en una nueva ventana, para arreglarlo tube que borrar ese archivo. Lo hice desde mi Adrenalinux, para evitar que se cree de nuevo.

Este script sirve para XP tmb?

[0x0309]

[quote author=nsigned link=topic=244992.msg1188332#msg1188332 date=1235789204]
Muchas gracias, yo tube un problema en un pen que cuando ingresaba a mi pc y le daba dblclk se me abria en una nueva ventana, para arreglarlo tube que borrar ese archivo. Lo hice desde mi Adrenalinux, para evitar que se cree de nuevo.

Este script sirve para XP tmb?
[/quote]

Pues, yo lo he probado solamente desde XP, y funciona.
¿En que versión de windows lo probaste?

[[u]nsigned]

2000

Nota: mis disculpas por el post tan corto, pero hay que ser conciso eh ir directo al grano en esta vida, no?