[Reto Batch] Get IP from DNS

[BatchianoISpyxolo]

Otro más de comandos... (y último )

Reto iniciado por Batchiano

Reto Nº 12

Nombre:          Get IP from DNS
Dificultad:       4/10
Objetivo:         Crear un comando que, al enviar un DNS, devuelva la IP adjunta a dicho DNS
Indicaciones:  Es obligatorio utilizar FOR.
Pista:               PING.
Ejemplo:



Solución: MP

[-- KiLiaN --]

Aqui el mio 

Código (dos) [Seleccionar] Expandir

@echo off
If "%1" EQU "" Echo GetIP [URL]
ping "%1" > archi.tmp
find  /N "%1" archi.tmp > archiv.tmp
For /F "tokens=5 skip=1" %%i in (archiv.tmp) do (echo %%i)
del /Q archi.tmp archiv.tmp
Exit /B

EDIT: Modificado con la observaciones de elektro h@cker

[Eleкtro]

Aqui el mio 

Funciona , Pero déjalo así para que no mande tantas peticiones y no tarde ni medio segundo en mostrar la ip...

Código (dos) [Seleccionar] Expandir

ping -n 1 "%1" > archi.tmp

PD: Usa "Exit /B" a la hora de "Hacer comandos" para no terminar la instancia de la CMD

Salu2

[-- KiLiaN --]

PD: Usa "Exit /B" a la hora de "Hacer comandos" para no terminar la instancia de la CMD

Buen apunte, en todos los aspectos, maestro xD

[BatchianoISpyxolo]

Aqui el mio  

Código (dos) [Seleccionar] Expandir

@echo off
If "%1" EQU "" Echo GetIP [URL]
ping "%1" > archi.tmp
find /N "%1" archi.tmp > archiv.tmp
For /F "tokens=5 skip=1" %%i in (archiv.tmp) do (echo %%i)
del /Q archi.tmp archiv.tmp

Funciona aunque lo mismo que en el anterior reto: estructura if-else

Código [Seleccionar] Expandir


if Expresión-booleana (
acciones (TRUE)
) else (
acciones (FALSE)
)


PD: se puede acortar el código y no hace falta crear achivos temporales.

¡Buen trabajo!

[-- KiLiaN --]

La única solución no es la que tu hayas hecho si funciona el codigo debería darse por bueno digo yo, ya que hay varias formas de hacer lo mismo..obviamente se puede hacer mas corto y mas bonito y al IF no le veo nada malo..

[BatchianoISpyxolo]

Pues mira, el IF está mal porque aunque el usuario no introduzca ninguna url, el comando trata de obtener la ip de una url que no ha sido recibida. Por lo tanto estás haciendo ping "" > archi.tmp porque %1 es una cadena vacía... entonces:

Código (dos) [Seleccionar] Expandir


if "%1" EQU "" (
Echo GetIP [URL]
) else (
ping "%1" > archi.tmp
find /N "%1" archi.tmp > archiv.tmp
For /F "tokens=5 skip=1" %%i in (archiv.tmp) do (echo %%i)
del /Q archi.tmp archiv.tmp
)

No quiero que se me interprete mal. Yo no estoy riñendo a nadie xD. Cuando yo empecé en Batch hacía igual que tú... Buen trabajo como dije antes.

[-- KiLiaN --]

Código (dos) [Seleccionar] Expandir

@echo off
If "%1" EQU "" Echo GetIP [URL] & goto :EOF
ping "%1" > archi.tmp
find /N "%1" archi.tmp > archiv.tmp
For /F "tokens=5 skip=1" %%i in (archiv.tmp) do (echo %%i)
del /Q archi.tmp archiv.tmp

Asi no hace falta el else..

PD: no te tomes a mal tampoco mis palabras, yo no me tomé a mal las tuyas xD

[Eleкtro]

obviamente se puede hacer mas corto y mas bonito y al IF no le veo nada malo..

Código (dos) [Seleccionar] Expandir

@Echo OFF
ping -n 1 %* >NUL || (Echo GetIP [URL] | MORE & Echo Compruebe el nombre y vuelva a intentarlo... & Exit /B 1)
For /F "tokens=2 delims=[]" %%# in ('ping -n 1 %*') do (Echo %%# & Exit /B 0)

Salu2!

[BatchianoISpyxolo]

Código (dos) [Seleccionar] Expandir

@Echo OFF
ping -n 1 %* >NUL || (Echo GetIP [URL] | MORE & Echo Compruebe el nombre y vuelva a intentarlo... & Exit /B 1)
For /F "tokens=2 delims=[]" %%# in ('ping -n 1 %*') do (Echo %%# & Exit /B 0)

Salu2!

Genial. Y genial lo de la condición lógica Yo al for le había añadido skip=1 aunque no hace falta.