programita para crear un acceso directo (.bat con vbs)

[P3NDULO]

Buenas aca les dejo ese programita que busque y pues acomode...
Primero chequeo que tipo de de SO, para luego crear un acceso directo en el esritorio del usuario que lo ejecute.

Código (dos) [Seleccionar] Expandir


@ECHO OFF
REM XP Check
ver | findstr /i "5\.1\." > nul
IF %ERRORLEVEL% EQU 0 SET VER=XP-%PROCESSOR_ARCHITECTURE%

REM 7 Check
ver | findstr /i "6\.1\." > nul
IF %ERRORLEVEL% EQU 0 SET VER=WIN7-%PROCESSOR_ARCHITECTURE%

::REM 8 Check
::ver | findstr /i "6\.2\." > nul
::IF %ERRORLEVEL% EQU 0 SET VER=WIN8-%PROCESSOR_ARCHITECTURE%

ECHO %VER%
if %VER%==WIN7 (set coco=%userprofile%/desktop) else (set coco=%userprofile%/Escritorio)
cd %coco%
echo Set WshShell = WScript.CreateObject("WScript.Shell") > "ad.vbs"
echo Set Link = WshShell.CreateShortcut("Compensacion Bicentenario.lnk") >> "ad.vbs"
echo With Link >> "ad.vbs"
echo .TargetPath = "%PROGRAMFILES%\CompensacionBicentenario\1.5\BacosiRegional.jar" >> "ad.vbs"
echo .WindowStyle = 1 >> "ad.vbs"
echo .Hotkey = "" 'HotKey >> "ad.vbs"
echo .IconLocation = "%PROGRAMFILES%\carpeta\1.5\BacosiRegional.jar" >> "ad.vbs"
echo .Description = "" >> "ad.vbs"
echo .WorkingDirectory = "%PROGRAMFILES%" >> "ad.vbs"
echo .Save >> "ad.vbs"
echo End With >> "ad.vbs"
ad.vbs
del ad.vbs
Exit /B


Nota: este programa los monto en la pagina de intranet de la empresa para que los usuairo lo puedan ejecutar, sin tener que ingresar al equipo y crearles el acceso direccto..

[Eleкtro]

Veo que al final te serviste de VBS como te indiqué, aquí tienes una pequeña simplificación del código por si quieres:

Código (dos) [Seleccionar] Expandir

@ECHO OFF

For /F "Tokens=1-2 Delims=." %%X In (
'wmic.exe os get version ^| FINDSTR "[0-9]"'
) Do (

If %%X%%Y EQU 51 (
REM XP
set "COCO=%UserProfile%\Escritorio"
) Else (
REM Vista, 7, 8
set "COCO=%UserProfile%\Desktop"
)
)

(
Echo Set Link = WScript.CreateObject^("WScript.Shell"^).CreateShortcut^("%COCO%\Compensacion Bicentenario.lnk"^)
Echo With Link
Echo .TargetPath = "%PROGRAMFILES%\CompensacionBicentenario\1.5\BacosiRegional.jar"
Echo .WindowStyle = 1
Echo .IconLocation = "%PROGRAMFILES%\carpeta\1.5\BacosiRegional.jar"
Echo .WorkingDirectory = "%PROGRAMFILES%\CompensacionBicentenario\1.5\"
Echo .Save
Echo End With
) > "%TEMP%\ad.vbs"

Wscript.exe "%TEMP%\ad.vbs"

Exit /B 0

Saludos