enviar por ftp txt determinado tiempo

[asdexiva]

asi es como dice el titulo necesito saber si despues de determinado tiempo se puede enviar un txt ami ftp ¿?

[Eleкtro]

Hola,

(CORREGIDO

Código (dos) [Seleccionar] Expandir

@Echo OFF

REM By Elektro H@cker

:: Tiempo de espera
Set "Minutos=10"

:SENDER
Set /A "Segundos=Minutos*60"
Ping -n %SEGUNDOS% localhost >NUL & (

(
Echo open "tu dirección ftp"
        REM Echo user "Nombre de usuario" "Contraseña"
REM Echo CD "/carpeta"
Echo put "Archivo.txt"
Echo bye
)> "%TEMP%\ftp.txt"
ftp.exe -s:"%TEMP%\ftp.txt"

)
GOTO:SENDER


EDITO: Otra versión algo modificada:

Código (dos) [Seleccionar] Expandir

@Echo OFF


REM By Elektro H@cker


:: Tiempo de espera
Set "Minutos=1"

:SENDER
Set /A "Segundos=Minutos*60"

For /L %%@ in (%SEGUNDOS%,-1,0) DO (
Ping -n 2 localhost >NUL
CLS
Echo: Faltan %%@ segundos ...
)

(
Echo open "tu dirección ftp"
REM Echo user "Nombre de usuario" "Contraseña"
REM Echo CD "/carpeta"
Echo put "Archivo.txt"
Echo bye
)> "%TEMP%\ftp.txt"
ftp.exe -s:"%TEMP%\ftp.txt"

GOTO :SENDER

[ovichan]

Buenas, este script que pones valdria para poder conectarme con mi ftp y enviar un archivo, sin que me pida confirmacion de sobreescritura???

[Eleкtro]

valdria para enviar un archivo, sin que me pida confirmacion de sobreescritura???

si, put sobreescribe el archivo

un saludo

[ovichan]

Entonces este codigo serái valido?

Código [Seleccionar] Expandir

@echo off
Title Conexion a FTP remoto

rem set servidor=nombre_de_mi_servidor

::Definimos variables del archivo temporal

set "user=mi_usuario"
set "pass=***********"
set "arch=%UserProfile%\Documents\Base_datos.adb"

:Creamos archivo temporal

(
echo %user%
echo %pass%
echo cd carpeta
echo put %arch%
echo close
echo bye
)>>"%temp%\orden_FTP.txt"

::Comunicacion con el servidor

ftp -s:"%temp%\orden_FTP.txt" IP
del "%temp%\orden_FTP.txt"

exit

EDITO: Entra en bucle la creacion del archivo orden_FTP.txt y no se porque  

[Eleкtro]

Entonces este codigo serái valido?

Me equivoqué al escribir la sintaxis del user/pass, pero de todas formas tut ambién la tenías mal, prueba así:

Código (dos) [Seleccionar] Expandir

@echo off
Title Conexion a FTP remoto

set servidor=nombre_de_mi_servidor

::Definimos variables del archivo temporal

set "user=mi_usuario"
set "pass=g"
set "arch=%UserProfile%\Documents\Base_datos.adb"

::Creamos archivo temporal

(
echo user "%user%" "%pass%"
echo cd carpeta
echo put %arch%
echo close
echo bye
)>"%temp%\orden_FTP.txt"


::Comunicacion con el servidor

ftp -s:"%temp%\orden_FTP.txt" "%SERVIDOR%"
del /Q "%temp%\orden_FTP.txt"
exit

saludos

[ovichan]

Pues al final lo he hecho funcionar con este, que es similar:

Código [Seleccionar] Expandir

@echo off
Title Conexion a FTP remoto

::Definimos variables del archivo temporal
set "user=******"
set "pass=*******"
set "arch=C:\Prueba.txt"

::Creamos archivo temporal
(
echo open IP
echo %user%
echo %pass%
echo cd OVERDRIVE
echo put C:\Users\Isra\Documents\Prueba.txt
echo close
echo bye
)>"%temp%\orden_FTP.txt"

::Comunicacion con el servidor
ftp.exe -i -s:"%temp%\orden_FTP.txt"
del /q "%temp%\orden_FTP.txt"
pause&exit

Gracias ElectroCrack