Creacion de Batch para evitar copia de archivos a USB

[syst3m98]

Que tal eh Investigado en foros y no encuentro como hacer un archivo batch para impedir la copia de archivos a las memorias USB, se que se tiene que editar la clave de registro de windows en la ruta siguiente:

Haz clic en Inicio > Ejecutar, escribe el comando regedit y presiona Enter
Ve a: HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control
Crea una nueva clave y nómbrala StorageDevicePolicies
Selecciona la clave StorageDevicePolicies, haz clic derecho y selecciona Nuevo > Valor de DWORD (32 bits) y ponle de nombre WriteProtect:
Establece su valor en 1 para evitar que otros usuarios copien información a memorias USB
Para revertir los cambios, establece el valor en 0

El problema a lo que veo es que tendria que hacer 2 archivos batch uno para activar la copia o "1" y el otro para desactivarlo "0" el problema es que no tengo mucha idea de como hacerlo me podrian orientar, por su atencion gracias.

Si el tema no va en esta sección de favor algun moderador muevalo

[osmel92]

Abres el Block de Notas, copias y pegas este codigo:

Código (dos) [Seleccionar] Expandir

@echo off
MODE CON COLS=80 LINES=35
title Activar/Desactivar Escritura
color 0A
:START
cls
echo ===============================================================================
echo =                                                                             =
echo =                      [ A ] - Activar Escritura USB                          =
echo =                                                                             =
echo =                      [ B ] - Desactivar Escritura USB                       =
echo =                                                                             =
echo =                      [ C ] - Salir                                          =
echo =                                                                             =
echo ===============================================================================
choice /c ABC /n /m "Selecciona la Opcion: "
if "%ERRORLEVEL%"=="1" (goto :ACTIVAR)
if "%ERRORLEVEL%"=="2" (goto :DESACTIVAR)
if "%ERRORLEVEL%"=="3" (exit)
goto :START

:ACTIVAR
reg add "HKLM\System\CurrentControlSet\Control\StorageDevicePolicies" /v "WriteProtect" /t REG_DWORD /d "1" /f >nul
echo Escritura USB -^> ACTIVADA &timeout /t 2 /nobreak >nul
goto :START

:DESACTIVAR
reg add "HKLM\System\CurrentControlSet\Control\StorageDevicePolicies" /v "WriteProtect" /t REG_DWORD /d "0" /f >nul
echo Escritura USB -^> DESACTIVADA &timeout /t 2 /nobreak >nul
goto :START

Guardas con el nombre que quieras y al final con la extesion ".bat" sin las comillas

Por Ejemplo: USBEscritura.bat

Y Listo!! Saludos