Crackme Noob 1.0 [batch]

[Binary_Death]

Código [Seleccionar] Expandir


@echo off
title Crackme Noob 1.0 [Binary_Death]
setlocal enabledelayedexpansion
:code
cls
set "dig="
set /p "dig=Password: "
if not defined dig GoTo:code
call:len "%dig%"
if %strlen% LSS 5 (GoTo:code)
set /a "iflen=(%strlen%*%dig:~0,1%%dig:~-1%) %% 5"
if "%iflen%" NEQ "0" (GoTo:lost)
call:algoritm
call:cmp "%cmp%"
exit /b
:algoritm
set /a "dec=%dig%/%strlen%"
set /a "decend=%dig% %% %strlen%"
set ret=0
set int=0
if %dig%%strlen% LSS %dec% (GoTo:lost)
for /l %%y in (%dig%%strlen%,-%dec%,%decend%) do (set /a int+=1)
set /a "strlenpos=%strlen%-1"
for /l %%x in (0,1,%strlenpos%) do (
set /a "ret=!dig:~%%x,1!+!ret!"
)
set /a "cmp=(%ret%*%int%*%strlen%) + (%dig:~0,1%*%dig:~-1%)"
GoTo:EoF
:cmp
if "%~1" NEQ "19445" (GoTo:lost) else (GoTo:win)
exit
:len
set "txt=%~1"
set /a "count=0"
:strlen
call set "text=%%txt:~%count%,1%%"
if defined text (
set /a "count+=1"
GoTo:strlen
) else (
set "strlen=%count%"
GoTo:EoF
)
:lost
cls
echo Has perdido.
pause>nul&exit
:win
cls
echo Has ganado.
pause>nul&exit


Es mi segundo crackme que ya postee en algunos foros.
Yo CREO que es muy sencillo y no esta demasiado bien hecho, pero eso ya os lo dejo a vosotros. Opinad.

Saludos y animaos! suerte!

[---saster---]

mmmm, no te creas que es tan sencillo

no permite batch injections y tiene por ejemplo una funcion de contar la longitud de una cadena que para el que no sepa hacerlo se liara

Ps. ya casi tengo un numero

saludos

[Binary_Death]

Sii saster pero tu pudiste  felicidades 

[---saster---]

si jeje pero me costo lo mio 

saludos