¿Cómo puedo cambiar el ultimo octeto de una IP con un batch?

[Platanito Mx]

Realmente no supe cómo poner la pregunta en el tema de este post, pero espero que con mi explicación quede mas claro

Manejo 4 segmentos de IP's
Quiero configurar la tarjeta de red mediante un sript
Quiero que el script solo pida el ultimo octeto

El proceso seria:
Ejecutar el script
Aparece el menu para elegir el segmento
Elegimos un segmento
Pedir que se escriba el ultimo octeto
Se configurar con el script la IP, la mascara, el gateway, el DND primario y el DND secundario

Este es mi script pero no sé cómo hacerle para que pida capturar el ultimo acteto y se agregue a la IP

@echo off
:menu
echo Cconfiguración de IP
echo.

echo 1. Segmento 192.168.1.X
echo 2. Segmento 192.168.2.X
echo 3. Segmento 192.168.3.X
echo 4. Segmento 192.168.4.X
echo 5. Salir

set /p opcion=opcion:
if %opcion%==1 goto 1
if %opcion%==2 goto 2
if %opcion%==3 goto 3
if %opcion%==2 goto 4
if %opcion%==3 goto 5

:1

netsh interface ip set address name="Conexi¢n de  rea local" static 192.168.1.X 255.255.255.0 192.168.1.1
netsh interface ip set dns name="Conexi¢n de  rea local" static 8.8.8.8
netsh interface ip add dns name="Conexi¢n de  rea local" 8.8.4.4 index=2

goto menu

:2

netsh interface ip set address name="Conexi¢n de  rea local" static 192.168.2.X 255.255.255.0 192.168.2.1
netsh interface ip set dns name="Conexi¢n de  rea local" static 8.8.8.8
netsh interface ip add dns name="Conexi¢n de  rea local" 8.8.4.4 index=2

goto menu


:3

netsh interface ip set address name="Conexi¢n de  rea local" static 192.168.3.X 255.255.255.0 192.168.3.1
netsh interface ip set dns name="Conexi¢n de  rea local" static 8.8.8.8
netsh interface ip add dns name="Conexi¢n de  rea local" 8.8.4.4 index=2

goto menu

:4

netsh interface ip set address name="Conexi¢n de  rea local" static 192.168.4.X 255.255.255.0 192.168.4.1
netsh interface ip set dns name="Conexi¢n de  rea local" static 8.8.8.8
netsh interface ip add dns name="Conexi¢n de  rea local" 8.8.4.4 index=2

goto menu


:5

exit

Espero puedan ayudarme, gracias de antemano!!!

[Eleкtro]

Código (dos) [Seleccionar] Expandir

@echo off
Title Configuración de IP

:: By Elektro H@cker

:Menu
Echo Configuraci¢n de IP:       
Echo -------------------        | MORE
Echo: 1 ^> Segmento [192.168.1.X]
Echo: 2 ^> Segmento [192.168.2.X]
Echo: 3 ^> Segmento [192.168.3.X]
Echo: 4 ^> Segmento [192.168.4.X]
Echo: 5 ^> Salir
Echo.                           | MORE

choice /C 12345 /M "elige una opci¢n"

For %%# in (%ERRORLEVEL%) DO (
If %%# EQU 1 (Set "Segmento=192.168.1.")
If %%# EQU 2 (Set "Segmento=192.168.2.")
If %%# EQU 3 (Set "Segmento=192.168.3.")
If %%# EQU 4 (Set "Segmento=192.168.4.")
If %%# EQU 5 (Exit /B 0)
Call :Set_Digitos
Call :Set_IP
)
GOTO :MENU

:Set_Digitos
CLS
Echo Segmento elegijo [%Segmento%XXX] | MORE
Set /P "Ultimo=Escriba el ultimo bloque de digitos >>"
If "%Ultimo%" EQU "" (GOTO :Set_Digitos)
Echo "%Ultimo%"|Findstr "^\"[0-9]*\"$" && GOTO:EOF || (GOTO :Set_Digitos)

:Set_IP
Echo Configurando IP [%Segmento%%ultimo%] | MORE
netsh interface ip set address name="Conexi¢n de  rea local" static %Segmento%%ultimo% 255.255.255.0 %Segmento%1
netsh interface ip set dns name="Conexi¢n de  rea local" static 8.8.8.8
netsh interface ip add dns name="Conexi¢n de  rea local" 8.8.4.4 index=2
GOTO:EOF

Saludos

[Platanito Mx]

Muchas gracias por tu ayuda EleKtro H@cker