COmo podria'??....... [batch]

[_CrisiS_]

se puede hacer que un bat se active cada ves que se elimine un archivo de cualquier disco duro?.

P.D> no lo ago con fines malvados, todo lo contrario

[Novlucker]

Que se active?

No, para eso tendrías que tener algo más verificando que dicho archivo sea creado .. o eso o directamente creas un bat que verifique si existe, si no existe, entonces haces "algo"

Saludos

[<ИΘZIЭ(ŦB>]

Que tal Crisis! Aprovecho que te veo conectado para decirte que sí hay una forma de hacer lo que pides. Hace unos días leí tu pregunta y me dediqué a hallar la manera. Ya logré algo, pero hay unos detalles que estoy terminando. Si te quedas un rato tal vez lo veas; estoy por terminarlo. Espera...

[Novlucker]

Claro que hay manera, pero por eso digo, .. la manera es tener un programa/script corriendo que haga la verificación 

Saludos

[<ИΘZIЭ(ŦB>]

Listo. Después de varias pruebas, este es el que mejor me corrió, aunque debo mencionar que no es 100% efectivo. Una que otra vez pasa por alto algún borrado, pero creo que es inevitable, pues se toma ciertos segundos para verificar, y en eso si casualmente se borra un archivo, puede que no lo registre.
De todos modos quedó bueno.

Lo primero que hace es pedir que se configure la ruta a chequear, la cual queda guardada en Settings.ini, en la misma carpeta, lo que impide que se vuelva a configurar en próximas ejecuciones. En caso de querer cambiarla posteriormente se puede borrar el archivo o modificar la ruta en el mismo (CheckPath).

A partir de entonces el programa queda verificando el contenido de la ruta, y guarda el registro del mismo en Content.log, también en la misma carpeta. Esta solo se actualiza cuando se borra o agrega un archivo en la ruta chequeada. Ahora bien, el programa guarda otro registro en la carpeta %temp% que si se actualiza todo el tiempo. Esa fue la única forma en que logré que la verifiación fuese más efectiva.

Por último, el programa va mostrando en pantalla cada archivo que se borra y a su vez lo guarda un registro llamado DelReg.log, que almacena la fecha y la hora del borrado, junto al nombre del archivo.

Aquí se los dejo. Lo llamé Delete Checker v1.0:

Código (dos) [Seleccionar] Expandir


@echo off
cls
title Delete Checker [v1.0] By ^<N0ZI3(FB^>
echo. & echo  Iniciando... & sleep 1
If not exist "%~dp0Settings.ini" (call:Define) else (call:Read)
cls
call:CheckMsj
dir /a /b /s "%checkPath%" >"%~dp0Content.log"
call:List

:List
set match=0
For /f "useback tokens=*" %%R in ("%~dp0Content.log") do (
    set "regValue=%%R"
    If not exist "%%R" call:DelMsj
)
If %match% == 1 (
    call:CheckMsj
    set match=0
    dir /a /b /s "%checkPath%" >"%~dp0Content.log"
)
dir /a /b /s "%checkPath%" >"%temp%\Content.log"
call:Compare
goto List

:Compare
fc /c "%temp%\Content.log" "%~dp0Content.log" >nul
If %errorlevel% == 0 (goto:eof) else (move /y "%temp%\Content.log" "%~dp0Content.log" >nul)
goto:eof

:CheckMsj
echo. & echo  Chequeando (%checkPath%)... & echo.
goto:eof

:DelMsj
If "%time:~0,1%" == " " (set "hora=0%time:~1%") else (set "hora=%time%")
echo   ELIMINADO (%hora%): %regValue%
(echo ELIMINADO ^(%date% %hora%^): %regValue%)>>"%~dp0DelReg.log"
set match=1
goto:eof

:Read
For /f "useback tokens=*" %%R in ("%~dp0Settings.ini") do (set "settValue=%%R")
set "checkPath=%settValue:~10%"
If not exist "%checkPath%" (
    echo. & echo La ruta pre-configurada ya no existe.
    call:Define m
)
goto:eof

:Define
set sender=%1
If not defined sender echo. & echo  Debe configurar el sistema en su primer uso. & echo.
set /p _Path=Indique el disco o directorio a procesar:
If not exist %_Path% call:Define r
For %%s in (%_Path%) do (
    set "checkPath=%%~dpns"
)
(echo CheckPath=%checkPath%)>"%~dp0Settings.ini"
goto:eof


Espero saber si te resulta útil Crisis, y a cualquiera que lo use.

[hkire]

Muy buen aporte cyman, gracias.

Habra forma de que se abre en segundo plano/minimizado?
De ultima uso algun soft como el minime y fue.

Saludos.
PD: apenas me libero del facu/laburo sale aprender batch, viendo lo que uno puede hacer con el...

[<ИΘZIЭ(ŦB>]

La verdad creo que no hay manera de lograr eso; al menos yo no la sé. Lo que hago cuando quiero que se ejecute así es convertirla en .exe con un software llamado Quick Batch File Compiler. Este permite crear la aplicación en modo "ghost" (fantasma), o sea que no queda visible. Solo puedes verlo en el administrador de tareas.

Saludos.