[Batch] Poner el resultado de un comando en una variable

[moikano→@]

No sé si se puede hacer sin pasarlo antes por un archivo de texto, pero el caso es que intento meter el resultado del comando "ver" para ver la versión de windows.

Lo que quiero es que detecte que versión es de windows. Es decir, que busque el caracter adecuado (en este caso el 5 de versión de windows NT 5.1) y confirme que es windows XP.

Voy a poner lo que he probado, porsupuesto no funciona.

Código (dos) [Seleccionar] Expandir

@echo off
ver=var
set var2=%var:~1,5%
echo %var2%
pause > nul

Por otro lado si pongo este code si que funciona bien

Código (dos) [Seleccionar] Expandir

@echo off
ver=var
%var% > ver.txt
pause > nul

Gracias de antemano =)

[xassiz~]

Código (dos) [Seleccionar] Expandir

for /f "tokens=*" %%%% in ('ver') do (set var=%%~%%)

[leogtz]

Como ya te indicaron:

Código (dos) [Seleccionar] Expandir

for /f "tokens=*" %%a in ('ver') do (
    set "v=%%a"
)

[moikano→@]

Ok gracias a los dos. =)

Una cosa, a ver si lo e entendido.

"Tokens=*" >>>>esto quiere decir que para todas las lineas y letras?
in ('ver') >>>>>en el comando ver.
do (set var=%%a:~0,1) >>>> le aplica el comando set para crear la variable y sacarle el dígito que quiera?

[leogtz]

tokens=* obtienes todos los trozos de cadena, tokens no se refiere a lineas, sino a tokens.

('ver') comando a ejecutar y obtener su salida.

Código [Seleccionar] Expandir

set var=%%a

Se obtiene la salida del comando ver.

Fuera del ciclo haces la extracción de caracteres.

[moikano→@]

Ok gracias de nuevo. =)
Me tocará mirar lo de los tokens que nunca lo entendí muy bien.

[Diego_Schneider]

Código (dos) [Seleccionar] Expandir

for /f "tokens=*" %%a in ('ver') do (
   set "v=%%a"
)
set var=%v:~1,5%
echo %var%
pause
exit

[FerJGS]

Hola moikano, llevo bastante tiempo sin visitar el foro. Bueno, te explico lo de for. Aquí te dejo un trozod el tutorial que escribí hace tiempo, algo resumindo:

For es una función muy variada y completa. Nos permite analizar segmentos de la salida de comandos, funciones y el contenido de archivos. En realidad la definición más correcta de FOR es "Comando que ejecuta el comando para cada uno de los archivos especificados en el conjunto de archivos". Ya hemos dicho que para hacer bucles usamos un marcador, pero también ponemos usar for pero es algo más complicado que con marcadores. Pero generalmente, para cosas que no son bucles: Enumeración de archivos.

La sintaxis de este comando es
FOR %%var IN (conjunto) DO (acciones)   
La sintaxis es algo compleja pero muy eficaz. Analicémosla:

%%var=nombre de la variable...siempre tiene que estar precedido de dos %% si está en una línea de comandos, el nombre de la variable solo puede ser una letra, y se distinguen entre mayúsculas y minúsculas. (EJ %%O, %%A, %%a etc....)
(Conjunto)=archivos o dígitos con los que queremos trabajar, lo podemos separar con espacios, comas o punto y comas.
(Acciones)=Un comando con el que queremos ejecutar todo el conjunto. El comando puede llevar sus variantes (ejemplo: ...DO (echo %%var.,...DO del /f /q %%var...)

FOR %%a IN (archivo1.txt archivo2.exe archivo3.ini) DO del /f /q %%a
Lo que haríamos en esta línea sería lo siguiente

En el conjunto cogemos a archivo1.txt, a archivo2.exe y a archivo3.ini. Para llamar al conjunto entero usaremos la variable %%a. Luego con el comando del /f /q (%%a) borramos cada parte del conjunto que contiene la variable %%a

FOR %%var IN (d*) DO echo %%var
Lo que hacemos con el for es que nos muestre todos los archivos que comiencen por la letra "d" en el directorio predeterminado o el especificado por cd\push o popd (comando CD: posicionarse en otra carpeta)

*.exe = Todos los archivos que acaben en .exe
?.exe = Todos los archivos que tengan UNA letra y acaben en .exe

*= caracteres cualquiera
?=único carácter (cualquiera)

Veamos cómo usar FOR para los bucles

Hemos de añadir el modificador /L (de loop – bucle)

For /L %%variable (valor inicial, incremento por repetición, final (detención)) do (comandos)

Definiremos el valor inicial de la variable pero con los dos por cientos al principio. Después, entre paréntesis, pondremos el valor inicial, después la condición para que se siga repitiendo el bucle (mientras), y por último, el cambio por repetición. Do (hacer) especifica (entre paréntesis) los comandos que se hacen durante el bucle.

FOR /L %%x in ( 0,1,5 ) Do ( echo %%x )

te devuelve

0
1
2
3
4
5

Aquí lo vemos claramente: 0 es el valor inicial, aumenta 1 cada repetición y el final se da cuando la variable alcanza 5. Se mostrarán esos números porque hemos elegido en "do" que echo muestre el valor de la variable en cada repetición. Cualquiera de los tres valores puede ser una variable.

for /l %%i in (2 1 %potencia%) do (
set /a resultado=resultado * %base%
)

Esto nos puede servir para mostrar un resultado de "ir probando". Por ejemplo, a la hora de calcular una raíz, cada repetición irá aumentando uno hasta que "If" coincida con la fórmula de la raíz cuadrada. Esto es muy cómodo, ocupa mucho menos espacio y muestra los resultados más precisos, pero es más complicado.

FOR %%x in (x*) DO echo %%x

Esto mostrará todos los archivos que empiecen por X.

Hay dos modificadores más.

FOR /D %%x in (m*) DO echo %%x

Con /d mostrará solo los directorios que empiecen con M.

Y el más importante y complejo, el modificador /f.

El conjunto puede contener
Conjunto de archivos > sin comillas
Cadena de caracteres > con comillas dobles [ " " ]
Comando •> con comilla simple [ ' ' ]

OPCIONES

• Eol -> Todo lo que esté después de éste carácter (especificado con eol) será ignorado (para cada línea)

• Skip -> Es el número de líneas a saltarse al principio de un archivo o comando.

• Delims -> Delims nos sirve para separar cadenas, si no se coloca esta opción, se usarán como separadores "espacio" y "tab."

• Tokens -> Con tokens especificamos qué segmentos (palabras), delimitados por "delims", serán pasados a las variables... por ejemplo:

1, 2, 3
Solo pasará los primeros 3 segmentos.

1,2*
Pasa 2 segmentos, el primero y todo lo que este después (el * regresa todo el resto de la línea)

1,2,3-7.8.9-14,16*
Pasará los tres primeros segmentos, luego saltará al séptimo, seguirá has el noveno. Luego saltará al 14, salta al dieciséis hasta que se acaben los segmentos.

• Usebackq ->Cambia la forma de interpretar si es string o comando.

Pueden combinarse dos o más atributos para /f.

FOR /F "tokens=1,2-4,8,9,10*" %%a IN ("Con for f tokens podemos delimitar como palabra varias palabras y mostrarlas como variables consecutivas") DO echo %%a %%b %%d %%e %%f %%g %%h
Esta línea dará como resultado lo siguiente:

Con for tokens palabra varias palabras y mostrarlas como variables consecutivas

Podemos, por tanto, elegir qué palabras mostrar. Ahí va un ejercicio, utilizando FOR, haced un buscador de archivos  (El usuario ha de elegir la palabra o palabras que quiere buscar, utilizad set /p, y esa variable será lo que for tenga que buscar.)

Aquí os dejo algunos códigos parecidos.

::Saber las líneas de un archivo by PyXOLo
@echo off
:contador
set /p archivo=RUTA=
set cuenta=0
for /f %%x in (%archivo%) do set /a cuenta=1+cuenta
set funcion=%cuenta%
echo %funcion%
pause>nul




::Extraer la IP privada de tu ordenador en una variable por PyXOLo
@echo off
For /f "tokens=14 skip=5" %%x IN ('ipconfig') Do set ip=%%x
echo %ip%
pause>nul
goto EOF

::Sacar la ruta de un proceso (by RockoX)
@echo off
rem Sacando la ruta de un ejecutable activo.   
(cd %homedrive%\)
:Code
(cls)
(set /p proceso=Nombre de proceso : )
(if not defined proceso (goto:Code))
for /f "tokens=*" %%x in ('wmic process get executablepath ^| find /i "%proceso%"') do (set ruta=%%x)
(echo %ruta%)
(pause>nul)
(goto:eof)

También hay más tipos de for, como for /r, esto hará una lista de archivos de la ruta:
For /r C:windows %a in (Set) do Echo %a   .... Pero volvemos al for f tokens.
Esto nos viene muy bien, por ejemplo, si queremos tomar una pregunta de un txt.
:buscarnumero
set num=0
set /a num=%random% %% 100
if %num% geq 2 (if %num% leq 100 (goto :sig))
goto :buscarnumero
:sig
set /a nume=%num%-1
set a=0
for /f "skip=%nume% delims=" %%a in ('type "Preguntas.txt"') do (
if !a!==0 (
set preg=%%a
set a=1))
set b=0
for /f "skip=%nume% delims=" %%a in ('type "Respuestas.txt"') do (
if !b!==0 (
set rta=%%n
set b=1))
echo %preg%
If "%resp%"=="%rta%" (goto bien) else (goto mal)

Con esto tomará un número aleatorio entre 0 y 100, restamos uno para que se salte una línea menos, y de ahí tomamos el valor en el archivo preguntas.txt, haceos lo mismo con las respuestas, mostramos la pregunta, si la respuesta escrita por el usuario coincide con la tomada del archivo, irá a bien. Analizad este código.

Espero que te haya servido.