[Batch] Ayuda con código

[shadowhunter]

Hola, alguien podria decirme donde me estoy equivocando?

Tengo este code:

Código [Seleccionar] Expandir

@Echo OFF & Color 70 & MODE con cols=75
Title Animefiles 1.3.2

CD Plugins
if not exist Activados.txt (
--------->Activados.txt
)

:ACTIVAR
cls
SETLOCAL EnableDelayedExpansion
Set "Directory=%CD%\plugins"

For %%# in (
"%Directory%\*.bat"
) Do (
Set /A "FileCount+=1"
Set "File!FileCount!=%%~nx#"
)
echo.
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ |MORE
For /L %%X in (1, 1, !FileCount!) Do (
Type "%Directory%\activados.txt" | Findstr /V /I "!File%%X!" do (set info=Activado)
if not defined info (set info=Desactivado)
Echo %%X. !File%%X! %info% | MORE
)
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ|MORE
echo Seleccione el plugin que desea activar:
echo.
Set /P "SelectFiles=
Set "SelectFiles=%SelectFiles: =%"
For %%# in (%SelectFiles%) Do (
Echo "!File%%#!" >> Activados.txt
)
pause
exit


El programa se encuentra en la ruta .\Programfiles\Animefiles y tanto los bat como el archivo Activados.txt en el subdirectorio Plugins. Lo que intento es que el for a la vez que imprime en pantalla los bat disponibles en la carpeta plugins, compare sus nombres con los almacenados en el archivo Activados y segun eso, la variable info imprima desactivado si no estan o activado si estan en la lista.

[Eleкtro]

Hola

Aquí se ve un fallo a simple vista, te comiste una comilla doble:

Código [Seleccionar] Expandir

Set /P "SelectFiles=

Luego aquí no estás redireccionando absolútamente nada:

Código [Seleccionar] Expandir

--------->Activados.txt

No ibas mal encaminado en esta parte, pero esto no es un For, el keyword "Do" solo pertenece a un For, en su lugar usa los operadores lógicos y de comparación "&" "|" "&&"  "||".

Código [Seleccionar] Expandir

Type "%Directory%\activados.txt" | Findstr /V /I "!File%%X!" do (set info=Activado)

Aquí no estás expandiendo la variable info, por lo tanto tus checkeos no iban a funcionar corréctamente.

Código [Seleccionar] Expandir

Echo %%X. !File%%X! %info% | MORE

Prueba así:

Código [Seleccionar] Expandir

@Echo OFF & Color 70 & MODE con cols=75
Title Animefiles 1.3.2

REM CD Plugins
if not exist ".\Plugins\Activados.txt" (
REM --------->Activados.txt
Echo. --------->".\Plugins\Activados.txt"
)

:ACTIVAR
cls
SETLOCAL EnableDelayedExpansion
Set "Directory=%CD%\plugins"

For %%# in (
"%Directory%\*.bat"
) Do (
Set /A "FileCount+=1"
Set "File!FileCount!=%%~nx#"
)
echo.
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ |MORE
For /L %%X in (1, 1, !FileCount!) Do (
REM Type "%Directory%\activados.txt" | Findstr /V /I "!File%%X!" do (set info=Activado)
Type "%Directory%\activados.txt" | Findstr /I "!File%%X!" 1>NUL 2>&1 && (
set "info=Activado"
) || (
set "info=Desactivado"
)
REM if not defined info (set info=Desactivado)
REM Echo %%X. !File%%X! %info% | MORE
Echo %%X. !File%%X! !info! | MORE
)
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ|MORE
echo Seleccione el plugin que desea activar:
echo.
Set /P "SelectFiles="
Set "SelectFiles=%SelectFiles: =%"
REM For %%# in (%SelectFiles%) Do (
REM Echo "!File%%#!" >> Activados.txt
REM )
(For %%# in (%SelectFiles%) Do (Echo "!File%%#!"))>> ".\Plugins\Activados.txt"
pause
exit

[shadowhunter]

gracias por la ayuda, ya consegui que funcione   , dejo el codigo por si alguien le sirve de ayuda para otra cosa:

Código [Seleccionar] Expandir

@Echo OFF & Color 70 & MODE con cols=75
Title Animefiles 1.3.2

REM CD Plugins
if not exist ".\Plugins\Activados.txt" (
--------->".\Plugins\Activados.txt"
)

:MAIN
cls
SETLOCAL EnableDelayedExpansion
Set "Directory=%CD%\plugins"

For %%# in (
"%Directory%\*.bat"
) Do (
Set /A "FileCount+=1"
Set "File!FileCount!=%%~nx#"
)
echo.
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ |MORE
For /L %%X in (1, 1, !FileCount!) Do (
REM Type "%Directory%\activados.txt" | Findstr /V /I "!File%%X!" do (set info=Activado)
Type "%Directory%\activados.txt" | Findstr /I "!File%%X!" 1>NUL 2>&1 && (
set "info=Activado"
) || (
set "info=Desactivado"
)
REM if not defined info (set info=Desactivado)
REM Echo %%X. !File%%X! %info% | MORE
Echo %%X. !File%%X! !info! | MORE
)
echo ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ|MORE
echo que quiere hacer? (Activar/desactivar)
echo.
set/p "menu=>"
if not defined menu (
ENDLOCAL
goto :MAIN
)
if %menu%==Activar goto ACTIVAR
if %menu%==ACTIVAR goto ACTIVAR
if %menu%==activar goto ACTIVAR
if %menu%==Desactivar goto DESACTIVAR
if %menu%==DESACTIVAR goto DESACTIVAR
if %menu%==desactivar goto DESACTIVAR
cls
echo.
echo Opcion no valida. |MORE
pause
ENDLOCAL
goto MAIN

:DESACTIVAR
echo.
echo Elija el plugin que quiere desactivar:
echo.
Set /P "SelectFiles=>"
Set SelectFiles2=%SelectFileS%.bat
Type "%Directory%\activados.txt" | Findstr /V /I "%SelectFiles2%">"%Directory%\activados.tmp"
Del /Q "%Directory%\activados.txt"
Rename "%Directory%\activados.tmp" "activados.txt"
cls
echo.
echo Plugin desactivado. |MORE
pause
goto END

:ACTIVAR
echo.
echo Elija el plugin que quiere activar:
echo.
Set /P "SelectFiles=>"
Set SelectFiles2=%SelectFileS%.bat
CD Plugins
if not exist %selectfiles2% (goto ERROR)
echo %selectfiles2%>>Activados.txt
cls
echo.
echo Plugin activado. |MORE
pause
goto END

:ERROR
cls
echo ÉÍÍÍÍÍÍÍÍÍÍÍ»
echo º   ERROR   º
echo ÈÍÍÍÍÍÍÍÍÍÍͼ |MORE
echo No existe un plugin con ese nombre. |MORE
Pause
goto END

:END
CD..
Start Animefiles
Exit



EleKtro H@cker la parte de:

Código [Seleccionar] Expandir

--------->Activados.txt

es solo para que el bat cree un archivo vacio llamado activados.txt, de la forma que tu lo pusiste el archivo contiene -----------

EDITO:Tengo una duda, esto funcionaria? o en caso de que no cual seria la forma correcta de escribirlo?

Código [Seleccionar] Expandir

FOR %%A IN ("activados.txt") DO (
               call %%A  & goto :AUTORUN
)

[Eleкtro]

EleKtro H@cker la parte de:

Código [Seleccionar] Expandir

--------->Activados.txt

es solo para que el bat cree un archivo vacio llamado activados.txt, de la forma que tu lo pusiste el archivo contiene -----------

Entonces haz esto:

Código (dos) [Seleccionar] Expandir

Echo.>"Activados.txt"

Aunque es preferible que para crear un archivo vacio hagas esto otro:

Código (dos) [Seleccionar] Expandir

fsutil file createnew "Activados.txt" 0

La cuestión es redireccionar/crear al archivo corréctamene, tal y como lo hacias daba error, aunque el archivo se crea, si, pero la orden que usas no tiene integridad, queda feo.

EDITO:Tengo una duda, esto funcionaria? o en caso de que no cual seria la forma correcta de escribirlo?

Código [Seleccionar] Expandir

FOR %%A IN ("activados.txt") DO (
               call %%A  & goto :AUTORUN
)

No funcionaría porque al usar "GOTO" etás saliendo del bloque del FOR, solo se procesaría corréctamente el primer plugin encontrado.

No has mostrado el código de la etiqueta Autorun así que no se muy bien que pretendes hacer, pero en lugar de usar "GOTO" usa "CALL", así llamas a ese bloque de la etiqueta "AUTORUN" y retornas al "FOR" para seguir procesando el resto de plugins. recuerda especificar un "GOTO:EOF" al final del bloque para poder retornar, dentro del bloque de ":AUTORUN".

Saludos

[shadowhunter]

Cierto culpa mia por no explicarme bien 

lo que pretendo es que el for carge el contenido del archivo activados.txt y use la funcion call para cada uno de esos archivos, pero que valla directamente a la etiqueta :AUTORUN que tendran los archivos.

ejemplo de los archivos a llamar:

Código [Seleccionar] Expandir

@echo off
@Echo OFF & Color 70 & MODE con cols=75
title ejemplo

:MAIN
echo.
echo Hola |MORE
pause
exit

:AUTORUN
echo.
echo adios |MORE
pause
exit