[BATCH] [APORTE] TextFont Installer (Instalador automático de fuentes de texto)

[Eleкtro]

Un pequeño code que me he hecho para automatizar la instalación de muchas fuentes de texto TTF u OTF EN WINDOWS 7...
Viene bien para ciertos casos así que aquí lo dejo por si alguien anda buscando algo parecido.

(Versión 0.2)

Código (dos) [Seleccionar] Expandir

@ECHO OFF
Mode con COLS=60 LINES=3
TITLE Text Font Installer (By Elektro H@cker^) v0.2
Nircmd win center ititle "Fuentes TrueType" 2>NUL
COLOR 07

:: Modo de instalación normal
REM Instalador.bat
:: Modo de instalación recursiva
REM Instalador.bat -R

Takeown /F "%SystemRoot%\Fonts" >NUL
Icacls "%SystemRoot%\Fonts" /Grant "%USERNAME%":(F) >NUL
Attrib -R -S "%SystemRoot%\Fonts" >NUL

IF /I "%~1" EQU "-R" (Set "DIR_RECURSIVE=/S" & Set "FOR_RECURSIVE=/R")

For /F %%X in ('Dir /B %DIR_RECURSIVE% "*.OTF"; "*.TTF" ^| FIND /V /C ""') Do (SET "Total=%%X")

For %FOR_RECURSIVE% %%# in (*.otf; *.ttf) DO (
Set /A "Counter+=1"
IF /I "%%~x#" EQU ".OTF" (Call SET "Font_Type=OpenType") ELSE (Call SET "Font_Type=TrueType")
CALL Echo: Instalando fuentes de texto...  ( %%COUNTER%% de %%TOTAL%% ^)
Echo: [+] %%~nx#
CALL REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts" /V "%%~n# (%%Font_Type%%)" /D "%%~nx#" /F >NUL
CALL REG ADD "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\Fonts" /V "%%~n# (%%Font_Type%%)" /D "%%~nx#" /F >NUL
COPY /Y "%%#" "%SystemRoot%\Fonts\" >NUL
)

Echo+
Echo: Las fuentes de texto se han instalado!
Timeout /T 3
Exit



Versión alternativa del script (Se reduce el molesto efecto del borrado de pantalla, pero la ventana queda más pequeña, menos bonita xD)

Código (dos) [Seleccionar] Expandir

@ECHO OFF
Mode con COLS=60 LINES=5
TITLE Text Font Installer (By Elektro H@cker^) v0.2
Nircmd win center ititle "Fuentes TrueType" 2>NUL
COLOR 07

:: Modo de instalación normal
REM Instalador.bat
:: Modo de instalación recursiva
REM Instalador.bat -R

Takeown /F "%SystemRoot%\Fonts" >NUL
Icacls "%SystemRoot%\Fonts" /Grant "%USERNAME%":(F) >NUL
Attrib -R -S "%SystemRoot%\Fonts" >NUL

IF /I "%~1" EQU "-R" (Set "DIR_RECURSIVE=/S" & Set "FOR_RECURSIVE=/R")

For /F %%X in ('Dir /B %DIR_RECURSIVE% "*.OTF"; "*.TTF" ^| FIND /V /C ""') Do (SET "Total=%%X")

For %FOR_RECURSIVE% %%# in (*.otf; *.ttf) DO (
Set /A "Counter+=1"
IF /I "%%~x#" EQU ".OTF" (Call SET "Font_Type=OpenType") ELSE (Call SET "Font_Type=TrueType")
Echo+
CALL Echo: Instalando fuentes de texto...  ( %%COUNTER%% de %%TOTAL%% ^) | MORE
Echo: [+] %%~nx#
CALL REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts" /V "%%~n# (%%Font_Type%%)" /D "%%~nx#" /F >NUL
CALL REG ADD "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\Fonts" /V "%%~n# (%%Font_Type%%)" /D "%%~nx#" /F >NUL
COPY /Y "%%#" "%SystemRoot%\Fonts\" >NUL
CLS
)

Echo+
Echo: Las fuentes de texto se han instalado!
Timeout /T 3
Exit

Saludos

[lahero85]

Gracias me sirvio tu BATCH saludos.