Ayuda con ya sea usando BATCH o VBS

[lendet]

Buenas, requiero ayuda para realizar un código que detecte cuando se ha agregado un nuevo archivo a una carpeta en especial. que capture el nombre y la hora de que fue guardado para llevar un registro en una archivo txt.  gracias

[Eleкtro]

Aqui tienes:

Código (dos) [Seleccionar] Expandir

@Echo OFF

REM By Elektro Hacker

REM La carpeta a monitorizar
Set Carpeta=C:\Users\Administrador\Desktop

Title Monitorizando "%Carpeta%"
mode con cols=71 lines=40

Echo+
Echo: "%Carpeta%" | MORE
Echo: Monitorizando la carpeta en tiempo real | MORE
Echo ÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜÜ | MORE


REM Listar
:Monitor
If NOT exist "%TEMP%\Old.txt" (Dir /B /A "%Carpeta%" > "%TEMP%\Old.txt")
Ping -n 3 localhost >NUL
Dir /B /A "%Carpeta%" > "%TEMP%\New.txt"


REM Comparar
For /F "Tokens=*" %%# in ('Type "%TEMP%\New.txt"') do (
Find "%%#"  "%TEMP%\Old.txt" >NUL
Call :Nuevos "%%#"
)
Goto :Clean


REM Mostrar los nuevos archivos
:Nuevos
If NOT %Errorlevel% EQU 0 (Echo+ "%~1" ^| %~t1)
Goto :EOF


REM Actualizar la lista
:Clean
Del /Q "%TEMP%\Old.txt"
Rename "%TEMP%\New.txt" "Old.txt"


REM Volver a empezar...
Goto :Monitor

[lendet]

Excelete!! Gracias por tu valiosa Ayuda