[APORTE] [Inno Setup] Plantilla para usarla como script por defecto.

[Eleкtro]

A petición de un usuario aquí tienen la plantilla por defecto que uso para mis instaladores...


Setup.iss

Código (inno) [Seleccionar] Expandir

; = = = = = = = = = = = = = = = = = = =
; Default Template (by Elektro H@cker) |
;                                      |
;            InnoSetup 5.5.3           |
; = = = = = = = = = = = = = = = = = = =

[Setup]

; Info
; ----
#define Name "Application"
#define Version "1.0"
#define EXE "Application.exe"
AppName={#Name}
AppVersion={#Version}
AppVerName={#Name} {#Version}
AppCopyright=Elektro H@cker
AppPublisher=Elektro H@cker

; Paths
; -----
DefaultDirName={pf}\{#Name}
DefaultGroupName={#Name}
OutputDir=.\Output\
OutputBaseFilename={#Name}
UninstallDisplayIcon={app}\{#EXE}

; Resources
; ---------
;SetupIconFile=Icon.ico
;WizardImageFile=Icon.bmp
;WizardSmallImageFile=Icon.bmp
;InfoBeforeFile=Info.txt

; Compression
; -----------
Compression=lzma/ultra
InternalCompressLevel=Ultra
SolidCompression=True

; Appearance
; ----------
AlwaysShowComponentsList=False
DisableDirPage=True
DisableProgramGroupPage=True
DisableReadyPage=True
DisableStartupPrompt=True
FlatComponentsList=False
LanguageDetectionMethod=None
PrivilegesRequired=PowerUser
RestartIfNeededByRun=False
ShowLanguageDialog=NO
ShowTasksTreeLines=True
Uninstallable=True
ArchitecturesAllowed=x86 x64
;ArchitecturesInstallIn64BitMode=x64

[Languages]
Name: spanish; MessagesFile: compiler:Languages\Spanish.isl

[Dirs]
;{sd}                  = C:\
;{commonappdata}       = C:\ProgramData
;{sd}\Users\{username} = C:\Users\UserName
;{userdesktop}         = C:\Users\UserName\Desktop
;{localappdata}        = C:\Users\UserName\AppData\Local
;{userappdata}         = C:\Users\UserName\AppData\Roaming
;{userstartmenu}       = C:\Users\UserName\AppData\Roaming\Microsoft\Windows\Start Menu

[Files]
;Source: {app}\*.*; DestDir: {app}; DestName:; Attribs:; Flags:;
;Attribs: ReadOnly Hidden System
;DestName: Example.exe
;Flags: 32bit 64bit Deleteafterinstall IgnoreVersion NoCompression Onlyifdoesntexist recursesubdirs uninsneveruninstall

[Registry]
;Root: HKCR; Subkey: SystemFileAssociations\.ext\Shell\OPTION; ValueName: Icon; ValueType: String; ValueData: {app}\{#Exe}; Flags: ;
;Root: HKCR; Subkey: SystemFileAssociations\.ext\Shell\OPTION\Command; ValueType: String; ValueData: """{app}\{#Exe}"" ""%1"""; Flags: ;
;Flags: uninsdeletevalue uninsdeletekey

[Tasks]
;Name: Identifier; Description: Title; GroupDescription: Group; Flags:;
;Flags: Unchecked

[Run]
;Filename: "{cmd}"; Parameters: "/C command"; StatusMsg: "Installing..."; Flags: RunHidden WaitUntilTerminated
;Filename: {app}\{#Exe}; Description: {cm:LaunchProgram,{#Nombre}}; Flags: NoWait PostInstall SkipIfSilent ShellExec Unchecked
;Flags: 32bit 64bit RunHidden WaitUntilTerminated NoWait PostInstall SkipIfSilent ShellExec Unchecked

[Icons]
Name: {userstartmenu}\Programs\{#Name}; Filename: {app}\{#Exe}; Iconfilename: {app}\{#Exe}; WorkingDir: {app}

[Code]

const
 Custom_Height = 440;
 Custom_ProgressBar_Height = 20;
 Page_Color = clwhite;
 Page_Color_Alternative1 = clblack;
 Page_Color_Alternative2 = clwhite;
 Font_Color = clblack;


var
 DefaultTop,
 DefaultLeft,
 DefaultHeight,
 DefaultBackTop,
 DefaultNextTop,
 DefaultCancelTop,
 DefaultBevelTop,
 DefaultOuterHeight: Integer;


procedure InitializeWizard();
begin

 DefaultTop := WizardForm.Top;
 DefaultLeft := WizardForm.Left;
 DefaultHeight := WizardForm.Height;
 DefaultBackTop := WizardForm.BackButton.Top;
 DefaultNextTop := WizardForm.NextButton.Top;
 DefaultCancelTop := WizardForm.CancelButton.Top;
 DefaultBevelTop := WizardForm.Bevel.Top;
 DefaultOuterHeight := WizardForm.OuterNotebook.Height;


 // Pages (Size)
 WizardForm.Height := Custom_Height;
 WizardForm.InnerPage.Height := WizardForm.InnerPage.Height + (Custom_Height - DefaultHeight);
 WizardForm.LicensePage.Height := WizardForm.LicensePage.Height + (Custom_Height - DefaultHeight);


 // Pages (Color)
 WizardForm.color := Page_Color_Alternative1;
 WizardForm.FinishedPage.Color  := Page_Color;
 WizardForm.InfoAfterPage.Color := Page_Color;
 WizardForm.InfoBeforePage.Color := Page_Color;
 WizardForm.InnerPage.Color := Page_Color;
 WizardForm.InstallingPage.color := Page_Color;
 WizardForm.LicensePage.Color := Page_Color;
 WizardForm.PasswordPage.color := Page_Color;
 WizardForm.PreparingPage.color := Page_Color;
 WizardForm.ReadyPage.Color := Page_Color;
 WizardForm.SelectComponentsPage.Color  := Page_Color;
 WizardForm.SelectDirPage.Color  := Page_Color;
 WizardForm.SelectProgramGroupPage.color := Page_Color;
 WizardForm.SelectTasksPage.color := Page_Color;
 WizardForm.UserInfoPage.color := Page_Color;
 WizardForm.WelcomePage.color := Page_Color;


 // Controls (Size)
 WizardForm.InfoAfterMemo.Height := (Custom_Height - (DefaultHeight / 2));
 WizardForm.InfoBeforeMemo.Height := (Custom_Height - (DefaultHeight / 2));
 WizardForm.InnerNotebook.Height :=  WizardForm.InnerNotebook.Height + (Custom_Height - DefaultHeight);
 WizardForm.LicenseMemo.Height := WizardForm.LicenseMemo.Height + (Custom_Height - DefaultHeight);
 WizardForm.OuterNotebook.Height := WizardForm.OuterNotebook.Height + (Custom_Height - DefaultHeight);
 WizardForm.ProgressGauge.Height := Custom_ProgressBar_Height
 WizardForm.ReadyMemo.Height := (Custom_Height - (DefaultHeight / 2));
 WizardForm.Taskslist.Height := (Custom_Height - (DefaultHeight / 2));
 WizardForm.WizardBitmapImage.Height := (Custom_Height - (DefaultHeight - DefaultBevelTop));
 WizardForm.WizardBitmapImage2.Height  := (Custom_Height - (DefaultHeight - DefaultBevelTop));


 // Controls (Location)
 WizardForm.BackButton.Top := DefaultBackTop + (Custom_Height - DefaultHeight);
 WizardForm.Bevel.Top := DefaultBevelTop + (Custom_Height - DefaultHeight);
 WizardForm.CancelButton.Top := DefaultCancelTop + (Custom_Height - DefaultHeight);
 WizardForm.LicenseAcceptedRadio.Top := WizardForm.LicenseAcceptedRadio.Top + (Custom_Height - DefaultHeight);
 WizardForm.LicenseNotAcceptedRadio.Top := WizardForm.LicenseNotAcceptedRadio.Top + (Custom_Height - DefaultHeight);
 WizardForm.NextButton.Top := DefaultNextTop + (Custom_Height - DefaultHeight);
 WizardForm.Top := DefaultTop - (Custom_Height - DefaultHeight) div 2;
 //WizardForm.ProgressGauge.Top := (DefaultHeight / 2)


 // Controls (Back Color)
 WizardForm.DirEdit.Color  := Page_Color_Alternative2;
 WizardForm.GroupEdit.Color  := Page_Color_Alternative2;
 WizardForm.InfoAfterMemo.Color := Page_Color_Alternative2;
 WizardForm.InfoBeforeMemo.Color := Page_Color_Alternative2;
 WizardForm.LicenseMemo.Color := Page_Color_Alternative2;
 WizardForm.MainPanel.Color := Page_Color;
 WizardForm.PasswordEdit.Color  := Page_Color_Alternative2;
 WizardForm.ReadyMemo.Color := Page_Color_Alternative2;
 WizardForm.Taskslist.Color := Page_Color;
 WizardForm.UserInfoNameEdit.Color  := Page_Color_Alternative2;
 WizardForm.UserInfoOrgEdit.Color  := Page_Color_Alternative2;
 WizardForm.UserInfoSerialEdit.Color  := Page_Color_Alternative2;


 // Controls (Font Color)
 WizardForm.FinishedHeadingLabel.font.color  := Font_Color;
 WizardForm.InfoafterMemo.font.Color  := Font_Color;
 WizardForm.FinishedLabel.font.color  := Font_Color;
 WizardForm.DirEdit.font.Color  := Page_Color_Alternative1;
 WizardForm.Font.color := Font_Color;
 WizardForm.GroupEdit.font.Color  := Page_Color_Alternative1;
 WizardForm.InfoBeforeMemo.font.Color  := Page_Color_Alternative1;
 WizardForm.LicenseMemo.font.Color  := Page_Color_Alternative1;
 WizardForm.MainPanel.font.Color := Font_Color;
 WizardForm.PageDescriptionLabel.font.color  := Font_Color;
 WizardForm.PageNameLabel.font.color  := Font_Color;
 WizardForm.PasswordEdit.font.Color  := Page_Color_Alternative1;
 WizardForm.Taskslist.font.Color  := Font_Color;
 WizardForm.UserInfoNameEdit.font.Color  := Page_Color_Alternative1;
 WizardForm.UserInfoOrgEdit.font.Color  := Page_Color_Alternative1;
 WizardForm.UserInfoSerialEdit.font.Color  := Page_Color_Alternative1;
 WizardForm.WelcomeLabel1.font.color  := Font_Color;
 WizardForm.WelcomeLabel2.font.color  := Font_Color;
 WizardForm.ReadyMemo.font.Color := Page_Color_Alternative1;

end;


Este es el aspecto por defecto:




Y se puede customizar un poco el aspecto para conseguir algo parecido a esto, sólamente cambiando las variables de la plantilla...

[/code]