Una mano, me quede trabado.

[TheJucas21]

Buenas, estuve haciando un cambia caption.
Cambiar la caption de una ventana poniendo yo los datos que quiero etc.

El cambia caption lo hice asi:

Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function SetWindowText Lib "user32.dll" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String) As Long

Private Sub Command1_Click()
    Dim Ret As Long
    Ret = FindWindow(vbNullString, Text1.Text)
    SetWindowText Ret, Text2.Text
End Sub

(Generen el codigo en su vb para entender mejor)

Y me funciono bien, pero lo que quiero hacer ahora es mejorarlo, de manera que pueda ver los caption es un listbox y cambiandolo dandole click a la caption en la lista y poniendo en un textbox el nombre y dandole al commandbutton bueno, para que ejecute la acción de cambiar la caption.

Lo mas que pude acercarme a eso fue este codigo:
(generenlo en vb para entenderlo mejor)

Private Declare Function CreateToolhelpSnapshot Lib "kernel32" Alias "CreateToolhelp32Snapshot" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long

Private Declare Function ProcessFirst Lib "kernel32" Alias "Process32First" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function ProcessNext Lib "kernel32" Alias "Process32Next" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Sub CloseHandle Lib "kernel32" (ByVal hPass As Long)

Private Type PROCESSENTRY32
dwSize As Long
cntUsage As Long
th32ProcessID As Long
th32DefaultHeapID As Long
th32ModuleID As Long
cntThreads As Long
th32ParentProcessID As Long
pcPriClassBase As Long
dwFlags As Long
szExeFile As String * 260
End Type

'Para llenar el listbox con los procesos
Sub RellenaLista()
On Error Resume Next
Dim hSnapShot As Long
Dim uProceso As PROCESSENTRY32
Dim res As Long
List1.Clear
hSnapShot = CreateToolhelpSnapshot(2&, 0&)
If hSnapShot <> 0 Then
uProceso.dwSize = Len(uProceso)
res = ProcessFirst(hSnapShot, uProceso)
Do While res
List1.AddItem Left$(uProceso.szExeFile, InStr(uProceso.szExeFile, Chr$(0)) - 1)
List1.ItemData(List1.NewIndex) = uProceso.th32ProcessID
res = ProcessNext(hSnapShot, uProceso)
Loop
Call CloseHandle(hSnapShot)
End If

End Sub

Private Sub Form_Load()
RellenaLista
End Sub

Pero me muestra los procesos, no las caption de los .exe abiertos. Y ahi me quede.

Espero que ustedes me puedan ayudar a terminar el proyecto, por que me quede estancado.

Saludos!

[Miseryk]

Buenas, estuve haciando un cambia caption.
Cambiar la caption de una ventana poniendo yo los datos que quiero etc.

El cambia caption lo hice asi:
(Generen el codigo en su vb para entender mejor)

Y me funciono bien, pero lo que quiero hacer ahora es mejorarlo, de manera que pueda ver los caption es un listbox y cambiandolo dandole click a la caption en la lista y poniendo en un textbox el nombre y dandole al commandbutton bueno, para que ejecute la acción de cambiar la caption.

Lo mas que pude acercarme a eso fue este codigo:
(generenlo en vb para entenderlo mejor)

Pero me muestra los procesos, no las caption de los .exe abiertos. Y ahi me quede.

Espero que ustedes me puedan ayudar a terminar el proyecto, por que me quede estancado.

Saludos!

Código (vb) [Seleccionar] Expandir


Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function GetWindow Lib "user32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long
Private Declare Function GetWindowText Lib "user32.dll" Alias "GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Private Declare Function IsWindowVisible Lib "user32" (ByVal hWnd As Long) As Long



Código (vb) [Seleccionar] Expandir


Private Sub Command1_Click()
List1.Clear

'This code submitted by Sarun101.
Dim DeskTophWnd As Long, WindowhWnd As Long
Dim Buff As String * 255, WindowsCaption() As String
Dim WindowsHandle() As Long
ReDim WindowsCaption(0)
ReDim WindowsHandle(0)
DeskTophWnd = GetDesktopWindow
WindowhWnd = GetWindow(DeskTophWnd, 5)
Do While (WindowhWnd <> 0)
    GetWindowText WindowhWnd, Buff, 255
    If (Trim(Buff) <> "") And (IsWindowVisible(WindowhWnd) > False) Then
        'ShowWindowAsync WindowhWnd, 0
        ReDim Preserve WindowsCaption(UBound(WindowsCaption) + 1)
        ReDim Preserve WindowsHandle(UBound(WindowsHandle) + 1)
        WindowsCaption(UBound(WindowsCaption)) = Buff
        WindowsHandle(UBound(WindowsHandle)) = WindowhWnd
       
        List1.AddItem Buff
    End If
    WindowhWnd = GetWindow(WindowhWnd, 2)
    'Debug.Print WindowhWnd
Loop
'The caption of window is in WindowsCaption()
'The handle of window is in WindowsHandle()
End Sub


Ahí estás listando todos los Captions de los programas (aunque muchos no aparecen, pero supongo que son todos)