reiniciar EXE y a la vez no permitir otra instancia del mismo ¿como?

[yovaninu]

tengo la siguiente situacion:

en el LOAD de un form cualquiera tengo ete codigo para evitar que se ejecute 2 veces el programa:

Código [Seleccionar] Expandir


            If App.PrevInstance = True Then 'si ya se esta ejecutando
              End 'entonces finalizamos
            End If


ahora bien, el form tiene un boton para reiniciar la aplicacion es un simple boton "CMDREINICIAR" cuyo codigo es:

Código [Seleccionar] Expandir


Dim RET
RET = Shell(App.path & "\" & App.EXEName & ".exe", 1) 'la instruccion para reiniciar (pero no va a reiniciar)
End 'finaliza el exe


y como se daran cuenta el programa se cierra pero ya no reinicia pues en el load se esta condicionando.

¿Cual sera la forma de reiniciar un EXE pero a la vez cuidar de que este no se ejecute 2 veces?

[cobein]

Podrias hacer algo asi

Código (vb) [Seleccionar] Expandir


Option Explicit

Private Declare Function SetEnvironmentVariable Lib "kernel32" Alias "SetEnvironmentVariableA" (ByVal lpName As String, ByVal lpValue As String) As Long

Private Sub Command1_Click()
    Call SetEnvironmentVariable("RESTARTED", "1")
    Call Shell(App.Path & "\" & App.EXEName & ".exe", vbNormalFocus)
    Call Unload(Me)
End Sub

Private Sub Form_Load()
    If App.PrevInstance Then
        If Not Environ$("RESTARTED") = "1" Then
            Gosub Quit:
        End If
    End If

    '// Your Code Here

    Exit Sub

Quit:
    Call Unload(Me)
End Sub



[yovaninu]

Excelente COBEIN, entiendo lo de las variables de entorno, habia tenido la misma idea pero con un interruptor( tu lo llamaste "RESTARTED" ) guardado en un archivo y preguntar desde ahi pero veo que es mucho mas elegante tu solucion y mas rapida claro, hace tiempo vi que las instrucciones GOTO y GOSUB no eran recomendadas (asi como el abrupto END) asi que lo cambie por esto, y funciona:
¿por que END en vez de Unload? pues quiza se quede algun form abierto por ahi, en fin... gracias por tu ayuda

Código (vb) [Seleccionar] Expandir


Option Explicit
Private Declare Function SetEnvironmentVariable Lib "kernel32" Alias "SetEnvironmentVariableA" (ByVal lpName As String, ByVal lpValue As String) As Long

Private Sub Command1_Click()
    Call SetEnvironmentVariable("FLAG", "1")
    Call Shell(App.Path & "\" & App.EXEName & ".exe", vbNormalFocus)
    End
End Sub

Private Sub Form_Load()
    If App.PrevInstance = True Then
        If Not Environ$("FLAG") = "1" Then
          End
        End If
    End If

End Sub



PD.- que pasa con la variable creada? se borra? parece que si pues voy a la consola escribo SET y no existe tales variables. ¿o donde estan?

[cobein]

Se puede hacer asi sin necesidad de usar gosub, con respecto al end no es recomendado para nada, aparte se supone que esta es la primer funcion asi que no tendria que haber nada cargado exepto el form de inicio.

Con respecto a las variables de entorno, son locales no globales

Código (vb) [Seleccionar] Expandir

Private Sub Form_Load()
    If App.PrevInstance and _
         Not Environ$("RESTARTED") = "1" Then
            Call Unload(Me)
    Else
        '// Your Code Here
    End If

End Sub

[krackwar]

Se puede hacer asi sin necesidad de usar gosub, con respecto al end no es recomendado para nada, aparte se supone que esta es la primer funcion asi que no tendria que haber nada cargado exepto el form de inicio.

Con respecto a las variables de entorno, son locales no globales

Código (vb) [Seleccionar] Expandir

Private Sub Form_Load()
    If App.PrevInstance and _
         Not Environ$("RESTARTED") = "1" Then
            Call Unload(Me)
    Else
        '// Your Code Here
    End If

End Sub

Con mutex tambien se podria hacer.

[cobein]

Si, se puede hacer con mutex, archivo, memoria, registro, dde, linea de comandos o cualquier cosa que te permita crear un flag, tambien podrias ver que proceso lo ejecuto o usar CreateProcess y pasarle los flags o mil cosas mas,  gracias por el dato.