Personal Algorythm + Source

[illuminat3d]

Bueno este proyecto lo tenía parado, un dia se me ocurrió la idea de hacer un programa que cree un modulo para proyectos de VB6 (Visual Basic 6) con la función de cifrar y descifrar datos, lo que hice fue un programa con la opción de hacer un algoritmo personal, sustituyendo carácteres por otros.



Forma de uso :
Para llamar a la función de cifrar 'cifrado = Encrypt(Datos, Contraseña)'
Para llamar a la función de descifrar 'descifrado = Decrypt(Datos, Contraseña)'

Descargar Personal Algorythm (Binario)
Descargar Personal Algorythm (Source)

Contraseña de los ficheros : SCB Lab's

Saludos! 

[BlackZeroX]

Sin animos de ofender pero deberias ponerle "Encryptación Personal" por que de "Algoritmo personal" no tiene nada, con referencia a las definiciones.

Aquí un error logico

Código (vb) [Seleccionar] Expandir



For a = 0 To 75    'Error
  For x = 0 To 75   'Error
   If a <> x Then
    If txtChr(a).Text = txtChr(x).Text Then
     txtChr(a).BackColor = &H8080FF
     txtChr(x).BackColor = &H8080FF
    ElseIf Len(txtChr(a).Text) > 1 Then
     txtChr(a).BackColor = &H8080FF
    ElseIf Len(txtChr(x).Text) > 1 Then  ' Posible Error
     txtChr(x).BackColor = &H8080FF
    End If
   End If
  Next x
Next a



Código (vb) [Seleccionar] Expandir



For a = 1 To 75 ' Se empiesa desde 1
  For x = 0 To 74 ' se termina en total -1
   If a <> x Then
    If txtChr(a).Text = txtChr(x).Text Then
     txtChr(a).BackColor = &H8080FF
     txtChr(x).BackColor = &H8080FF
    ElseIf Len(txtChr(a).Text) > 1 Then
     txtChr(a).BackColor = &H8080FF
    end if
    If Len(txtChr(x).Text) > 1 Then
     txtChr(x).BackColor = &H8080FF
    End If
   End If
  Next x
Next a



Dulces Lunas

[illuminat3d]

Código (vb) [Seleccionar] Expandir



For a = 0 To 75    'Error
  For x = 0 To 75   'Error
   If a <> x Then
    If txtChr(a).Text = txtChr(x).Text Then
     txtChr(a).BackColor = &H8080FF
     txtChr(x).BackColor = &H8080FF
    ElseIf Len(txtChr(a).Text) > 1 Then
     txtChr(a).BackColor = &H8080FF
    ElseIf Len(txtChr(x).Text) > 1 Then  ' Posible Error
     txtChr(x).BackColor = &H8080FF
    End If
   End If
  Next x
Next a



Que podría pasar?, yo lo veo normal.
Gracias por tomarte el tiempo de ver el source 

[BlackZeroX]

es logico que el primer elemento es identico alprimer elemento y dentro de tus bucles hay una comparación para no hacer nada si el elemento a es igual a B es decir  1=1 no hacer nada y es lo mismo en lo ultimo

En si hay dos bucles Muertos

[cobein]

Primero que nada, esto no es para ofender ni nada por el estilo pero me parecio constructivo el hecho de mencionar o resaltar algunas cosas de este source.

Me tome la livertad de descargar esto para ver de que se trataba y el porque de los comentarios y decidi hacer este mini review porque hay muchas cosas que no tienen sentido.

Primero, para el que se pregunta que es esto? es simplemente un "Substitution cipher" o quiere serlo.

Vamos a destripar el source =D

Código [Seleccionar] Expandir

For x = 0 To 75
 If txtChr(x).Text = Chr(34) Then MsgBox "No se permite el carácter " & Chr(34), vbCritical, Me.Caption: txtChr(x).BackColor = &H8080FF: Exit Sub
Next x

En la funcion principal encontramos esto que es simplemente un check para ver si algun textbox tiene como texto comillas.

Esto no tiene absolutamente sentido por que se puede validar dinamicamente con el evento Validate del textbox.

Código [Seleccionar] Expandir

Private Sub txtChr_Validate(Index As Integer, Cancel As Boolean)
   If txtChr(Index) = """" Then
       MsgBox "No se permite el carácter " & Chr(34), vbCritical, Me.Caption
       Cancel = True
   End If
End Sub

Código [Seleccionar] Expandir

For a = 0 To 75
 For x = 0 To 75
  If a <> x Then
   If txtChr(a).Text = txtChr(x).Text Then
    txtChr(a).BackColor = &H8080FF
    txtChr(x).BackColor = &H8080FF
   ElseIf Len(txtChr(a).Text) > 1 Then
    txtChr(a).BackColor = &H8080FF
   ElseIf Len(txtChr(x).Text) > 1 Then
    txtChr(x).BackColor = &H8080FF
   End If
  End If
 Next x
Next a


Aca esta el de la discoridia!!! Bien, este es uno de los que menos sentido tiene, son dos loops anidados que tienen como objetivo verificar si algun textbox tiene un texto con mas de un caracter y si hay dos textos repetidos.

Primero que nada, para que verificar si algun textbox tiene mas de un caracter? simplemente se pone la propiedad MaxLength = 1 y listo.

Una aclaracion aca para ░▒▓BlackZeroҖ▓▒░ en estos dos loops anidados se esta comparando una matriz con sigo misma por ende se van a producir tantas coliciones como objetos haya, en este caso 76.

Vamos con los elementos duplicados, mi pregunta es, vale la pena pasar por el proceso de "validacion" una y otra vez?  cuando todo esto se puede hacer on the fly?

Por ejemplo podriamos usar una coleccion para ver si el elemento existe y validarlo con el evento validate, algo asi.

Código [Seleccionar] Expandir



Dim cChars As New Collection

Private Sub txtChr_Validate(Index As Integer, Cancel As Boolean)
   
   If LenB(txtChr(Index)) = 0 Then Exit Sub
   
   If txtChr(Index) = """" Then
       MsgBox "No se permite el carácter " & Chr(34), vbCritical, Me.Caption
       Cancel = True
       Exit Sub
   End If
   
   If Exists(txtChr(Index)) Then
       MsgBox "El carácter esta en uso", vbCritical, Me.Caption
       Cancel = True
       Exit Sub
   End If
       
End Sub

Private Function Exists(ByVal sChar As String) As Boolean
   On Error GoTo Err_Exists
   cChars.Add sChar, sChar
   Exit Function
Err_Exists:
   Exists = True
End Function


Este es para verificar si se produjo un error durante la validacion.....

Código [Seleccionar] Expandir

For a = 0 To 75
 If txtChr(a).BackColor = &H8080FF Then Exit Sub
Next a

totalmente innecesario, se puede tener un flag en la validacion y evitar esto, no hay necesidad de utilizar un loop en lo absoluto.

Código [Seleccionar] Expandir

With CD
   .DialogTitle = "Guardar modulo .bas en..."
   .Filter = "Modulo bas (.bas) | *.bas"
   .ShowSave
End With

Este...bueno lo podriamos perdonar pero esta mal implementado tambien.

Al principio de la funcion se resetea el filename " CD.FileName = """ luego se abre el dialogo y se valida con esto "If CD.FileName <> "" Then" ... NO, el common dialog tiene una propiedad que se llama CancelError y esta ahi para poder determinar si se cancelo o no.

Bien estamos llegando al cuore de la funcion, el generador de algoritmos...

no lo pego completo poque no me entra ni en 3 paginas.

Código [Seleccionar] Expandir

 Open CD.FileName For Output As #File
  Print #File, "'Algoritmo de cifrado creado por [Personal Algorythm]"
  Print #File, ""
  Print #File, "Public Function Encrypt(Data As String, Pass As String) As String"
  Print #File, " Dim pPass As String"
  Print #File, "  pPass = " & Chr(34) & Text77.Text & Chr(34)
  Print #File, "  If Pass = pPass Then"
  Print #File, "   If InStr(Data," & Chr(34) & 0 & Chr(34) & ") Then Data = Replace(Data," & Chr(34) & 0 & Chr(34) & "," & Chr(34) & txtChr(0).Text & Chr(34) & ")"  ' Numeros
  Print #File, "   If InStr(Data," & Chr(34) & 1 & Chr(34) & ") Then Data = Replace(Data," & Chr(34) & 1 & Chr(34) & "," & Chr(34) & txtChr(61).Text & Chr(34) & ")"


Que demonios es esto? simplemente un template de la funcion principal que se parcha con los nuevos valores.

Mas alla de que todo esto se podria reducir a unas 5 lineas de codigo... vamos a lo interesante

Esto es simplemente substitucion de caracteres pero hay algo llamativo en como esta implementado. Vamos a sacar un pedazo del algoritmo generado y a ver que pasa.

  If InStr(Data, "0") Then Data = Replace(Data, "0", "1")
  If InStr(Data, "1") Then Data = Replace(Data, "1", "T")

Este es mi texto original: 01
Vamos a "encriptarlo" ..
Primer paso reeemplazamos los 0s con 1s
nos queda algo asi 11
segundo paso reeemplazamos los 1s con Ts
Resultado: TT

Como tarea para el hogar les dejo intentar recobrar el texto original

  If InStr(Data, "1") Then Data = Replace(Data, "1", "0")
  If InStr(Data, "T") Then Data = Replace(Data, "T", "1")

PD: si alguno se esta preguntando que funcion cumple el password en todo esto... simplemente mera decoracion.

[BlackZeroX]

Una aclaracion aca para ░▒▓BlackZeroҖ▓▒░ en estos dos loops anidados se esta comparando una matriz con sigo misma por ende se van a producir tantas coliciones como objetos haya, en este caso 76.

lo que decia es que no tiene caso comparar el elemento de la matriz 0 con el elemento de la matrx misma es decir no tiene caso realmente y es lo mismo con el ultimo en si si hay un "if then" que hace muerto un bucle no hay caso de iniciar ambos en 0 yq que hay un "if then" que no dejara hacer nada en lo absoluto y es lo mismo al termino (75)

P.D.: Se que hay 76 elementos... se que cuentan desde LBound() hasta Ubound() es decir 0-75 = 76 elementos... ¬¬# y me da peresa ver ese codigo la verdad xP por tanto    Print #File, "

Dulces Lunas!¡.

[cobein]

lo que decia es que no tiene caso comparar el elemento de la matriz 0 con el elemento de la matrx misma es decir no tiene caso realmente y es lo mismo con el ultimo en si si hay un "if then" que hace muerto un bucle no hay caso de iniciar ambos en 0 yq que hay un "if then" que no dejara hacer nada en lo absoluto y es lo mismo al termino (75)

P.D.: Se que hay 76 elementos... se que cuentan desde LBound() hasta Ubound() es decir 0-75 = 76 elementos... ¬¬# y me da peresa ver ese codigo la verdad xP por tanto    Print #File, "

Dulces Lunas!¡.

No me exprese correctamente parece, lo que quiero decir es que no son 2 coliciones las que hay sino 76, cada elemento es comparado con sigo mismo una vez, asi como el primero y el ultimo que mencionas, todos los demas en el medio tambien.

[BlackZeroX]

solo para aclarar a lo que yo decia:

La lista de elementos no excluidos son si y solo si son Diferentes, tomando en considereción una misma matrix de de LBound = 0 a Ubound=2) donde Se excluyen los elementos de la misma indexación

Es decir:

 0 , 0  ' Excluido
 0 , 1
 0 , 2
 1 , 0
 1 , 1  ' Excluido
 1 , 2
 2 , 0
 2 , 1
 2 , 2  ' Excluido

por la razon anterior

Desde i = 0 to 2 - 1
  Desde a =  1 to 2
     Si a direfente de i entonces
        Imprimir a , i

Los resultados serían

'//-  0 , 0 ' Nunca se Analisa ya que aun que analisara se excluiria
 0 , 1
 0 , 2
//--  1 , 0 ' Ya fue analisado
//--  1 , 1  ' Se exluye
 1 , 2
//--  2 , 0 ' Ya fue analisado
//--  2 , 1 ' Ya fue analisado
//--  2 , 2 ' Nunca se Analisa ya que aun que analisara se excluiria

El resultado Neto seria (las indexaciones posibles en una comparación):

 0 , 1
 0 , 2
 1 , 2

Simples 3 Comparacióne

Como Nota curiosa para aquel lector la cantidad de resultados en una comparación sin repetir es dada por una ecuación matemática

Por ello defiendo mi punto de vista!¡.

Dulces Lunas!¡

[cobein]

Entiendo lo que planteas, pero la solucion no es correcta. Tendrias que hacer algo asi:

    For a = 0 To 4
        For x = a + 1 To 4

Ahi no hay no se excluyen ni repiten comparaciones.

[BlackZeroX]

Entiendo lo que planteas, pero la solucion no es correcta. Tendrias que hacer algo asi:

For a = 0 To 4
For x = a + 1 To 4

Ahi no hay no se excluyen ni repiten comparaciones.

de hecho se repite  4 , 4 xP

La forma Correcta es asi solo para evitar el ultimo bucle madre que no serviria de nada.

For a = 0 To 4 - 1
For x = a + 1 To 4

Pero igual ya se entendio.

Dulces Lunas!¡.