obtener el hwnd de un programa sin form

[x64core]

buenas pues esa duda tengo como puedo obtener el hwnd de un programa de VB sin form? estoy codeando un programa sin form ( modulo como main el principal ) y entonces llege a esa parte que necesito el hwnd normalmente se hace me.hwnd ( me = form ) pero ahora veo que el modulo no tiene hwnd al menos tiene esa propiedad como puedo hacer? gracias

[BlackZeroX]

.
Ponle entonces &H0 o 0, el hwnd es propio de ventanas y solo es asosiativos normalmente...

Dulces Lunas!¡.

[x64core]

gracias BlackZeroX eso funciona con hooks? la verdad por el momento lo quiero para la api Settimer para el primer parametro que me pide y luego creo que lo usare para aplicarlo a hooks...

PD: una duda  para eliminarlo con killtimer?
ya que si aplico 0 en killtimer entonces escribo 0 ??? 

[BlackZeroX]

.
La MSDN No muerde y si no sabes ingles hay tienes el traductor de google.

http://msdn.microsoft.com/en-us/library/ms644906%28v=vs.85%29.aspx

http://msdn.microsoft.com/en-us/library/ms644903%28v=vs.85%29.aspx

Dulces Lunas!¡.

[x64core]

  si lo lei tio por eso me entro la curiosidad ya que al escribirle 0 comprendi que el argumento idevent se ignora y por eso tenia duda de como si no lo ignorara el parametro lo usara para darle un numero para identificarlo pero lo ignora y comprobe y la funcion killtimer me devuelve 0 eso quiere decir que la funcion falla y no libera el timer

[x64core]

hice este ejemplo y comprobe que no funciona noce en que fallo

modulo bas

Código (vb) [Seleccionar] Expandir

Option Explicit
Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long

Dim A As Long
Dim B As Boolean

Sub main()
A = SetTimer(0, 0, 30000, AddressOf TimerProc)
Debug.Print A
Do While Not B
DoEvents
Loop
End Sub

Sub TimerProc(ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long)
Debug.Print "+1"
Debug.Print A
Debug.Print KillTimer(A, 0)
B = True
End Sub


el resultado del debug.print:

Código [Seleccionar] Expandir

26430
+1
26430
0       <--------- no lo libera :P (valor devuelto de la llamada a funcion killtimer )


luego lo termine de comprobar porq cuando termina sub main y vuelvo a vb en diseño el timer aun sigue marcando y en el debug.print me escribe

Código [Seleccionar] Expandir

+1
0
0

[x64core]

 
lo resolvi
bueno mi error era a la hora de liberarlo
el identificador q me devuelve settimer es el idevent no el hwnd del timer

Código [Seleccionar] Expandir

Debug.Print KillTimer(0, A)

debug.print:

Código [Seleccionar] Expandir

26196
+1
26196
1

[BlackZeroX]

.

Código (vb) [Seleccionar] Expandir



Option Explicit

Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long
Declare Function WaitMessage Lib "user32" () As Long

Dim iTmr            As Long

Sub main()
    iTmr = SetTimer(0, 0, 300, AddressOf TimerProc)
    Do While Not (iTmr = 0)
        DoEvents
        WaitMessage
    Loop
End Sub

Sub TimerProc(ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long)
    Debug.Print KillTimer(hwnd, iTmr)
    iTmr = 0
End Sub



Dulces Lunas!¡.

[Hasseds]

buenas pues esa duda tengo como puedo obtener el hwnd de un programa de VB sin form?

El tema ya quedó resuelto, pero si alguna vez tenés que obtener el hwnd de un Main podes usar FindWindow. (Acabo de enterarme de esto, ya que también pensaba que este tipo de hwnd era unicamente propio de ventanas).

Código [Seleccionar] Expandir





Option Explicit

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Sub Main()
 
 Dim lpClase As String
 
 If Not App.LogMode = 0 Then
   lpClase = "ThunderRT6Main" ' Exe Compilado
 Else
   lpClase = "ThunderMain" ' en el IDE
 End If
 
 MsgBox FindWindow(lpClase, App.Title)

End Sub





[BlackZeroX]

El tema ya quedó resuelto, pero si alguna vez tenés que obtener el hwnd de un Main podes usar FindWindow. (Acabo de enterarme de esto, ya que también pensaba que este tipo de hwnd era unicamente propio de ventanas).

En efecto solo son de ventanas, los procesos no tienen hwnd.
Por ello El PROCESO MAIN() al igual que los demas, NO tienen hwnd.

Todas las aplicaciones de Visual Basic tienen una ventana de nivel superior invisible que procesa los eventos y mensajes. En el modo de diseño, la ventana es ThunderMain, en el modo de ejecución, la ventana es ThunderRT6Main. El RT6 refleja el versión de Visual Basic que se utiliza. Las dos ventanas tienen el nombre del proyecto o el nombre del archivo ejecutable como el título de ventana. Esto es donde se establece el icono de aplicación.

Dulces Lunas!¡.