Test Foro de elhacker.net SMF 2.1

disculpen las molestias de este post, xq se q ya se hablo del tema...
pero yo estuve buscando en google y hay bastantes cosas q no me salen ¬¬
queria ver si alguno me tiraba algun link de ejemplos concretos de como usar comandos de la MS-DOS ya q vi uno muy bueno y completo pero q muchas cosas me dicen q la sintaxis la hago mal.
la idea de esto es aplicarlo a VB x eso lo posteo aca
se q es algo con el piper pero nunca logre hacerlo :(

SALUDOS

bueno ,para ocupar comandos en la cmd podes hacer un shell i listo ej:
shell("cmd /c pause>>null")

algo asi estaba probando nada mas q ponia shell cmd solo

shell("cmd /c pause>>null")

el codigo q quiero ingresar donde iria?... y para ver la "pantalla" del cmd?

a ver la sintaxis seria shell(cmd /c codigo de la shell"). I va en el evento que la quieras ocupar.
s4lu2!

Si, por ejemplo renombrando...

Private Sub Form_Load()
    Shell "cmd.exe /c ren c:\prueba.txt prueba2.txt"
End Sub


Advertencia - mientras estabas leyendo, fueron publicadas 3 respuestas. Probablemente desees revisar tu mensaje.  :¬¬

jeje bueno... tambien puedes usar bat y ejecutarlos luego de crearlos.

Cita de: cΔssiΔnі en  2 Mayo 2008, 02:38 AM
Si, por ejemplo renombrando...

Código (vb) [Seleccionar] Expandir

Private Sub Form_Load()
    Shell "cmd.exe /c ren c:\prueba.txt prueba2.txt"
End Sub


Advertencia - mientras estabas leyendo, fueron publicadas 3 respuestas. Probablemente desees revisar tu mensaje.  :¬¬

jeje bueno... tambien puedes usar bat y ejecutarlos luego de crearlos.

para hacer el .bat podria ser open "c:\batch.bat" for binary as #1
put#1 , ," echo lol"
close#1
shell ("c:\batch.bat")

También puedes usar pipes, q es mas elegante :P Ejemplo de la api guide:

'Redirects output from console program to textbox.
'Requires two textboxes and one command button.
'Set MultiLine property of Text2 to true.
'
'Original bcx version of this program was made by
' dl <dl@tks.cjb.net>
'VB port was made by Jernej Simoncic <jernej@isg.si>
'Visit Jernejs site at http://www2.arnes.si/~sopjsimo/
'
'Note: don't run plain DOS programs with this example
'under Windows 95,98 and ME, as the program freezes when
'execution of program is finnished.

Option Explicit
Private Declare Function CreatePipe Lib "kernel32" (phReadPipe As Long, phWritePipe As Long, lpPipeAttributes As SECURITY_ATTRIBUTES, ByVal nSize As Long) As Long
Private Declare Sub GetStartupInfo Lib "kernel32" Alias "GetStartupInfoA" (lpStartupInfo As STARTUPINFO)
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As Any, lpThreadAttributes As Any, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function SetWindowText Lib "user32" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String) As Long
Private Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, lpOverlapped As Any) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Private Type SECURITY_ATTRIBUTES
  nLength As Long
  lpSecurityDescriptor As Long
  bInheritHandle As Long
End Type

Private Type PROCESS_INFORMATION
  hProcess As Long
  hThread As Long
  dwProcessId As Long
  dwThreadId As Long
End Type

Private Type STARTUPINFO
  cb As Long
  lpReserved As Long
  lpDesktop As Long
  lpTitle As Long
  dwX As Long
  dwY As Long
  dwXSize As Long
  dwYSize As Long
  dwXCountChars As Long
  dwYCountChars As Long
  dwFillAttribute As Long
  dwFlags As Long
  wShowWindow As Integer
  cbReserved2 As Integer
  lpReserved2 As Byte
  hStdInput As Long
  hStdOutput As Long
  hStdError As Long
End Type

Private Type OVERLAPPED
    ternal As Long
    ternalHigh As Long
    offset As Long
    OffsetHigh As Long
    hEvent As Long
End Type

Private Const STARTF_USESHOWWINDOW = &H1
Private Const STARTF_USESTDHANDLES = &H100
Private Const SW_HIDE = 0
Private Const EM_SETSEL = &HB1
Private Const EM_REPLACESEL = &HC2

Private Sub Command1_Click()
  Command1.Enabled = False
  Redirect Text1.Text, Text2
  Command1.Enabled = True
End Sub
Private Sub Form_Load()
    Text1.Text = "ping"
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  If Command1.Enabled = False Then Cancel = True
End Sub

Sub Redirect(cmdLine As String, objTarget As Object)
  Dim i%, t$
  Dim pa As SECURITY_ATTRIBUTES
  Dim pra As SECURITY_ATTRIBUTES
  Dim tra As SECURITY_ATTRIBUTES
  Dim pi As PROCESS_INFORMATION
  Dim sui As STARTUPINFO
  Dim hRead As Long
  Dim hWrite As Long
  Dim bRead As Long
  Dim lpBuffer(1024) As Byte
  pa.nLength = Len(pa)
  pa.lpSecurityDescriptor = 0
  pa.bInheritHandle = True
 
  pra.nLength = Len(pra)
  tra.nLength = Len(tra)

  If CreatePipe(hRead, hWrite, pa, 0) <> 0 Then
    sui.cb = Len(sui)
    GetStartupInfo sui
    sui.hStdOutput = hWrite
    sui.hStdError = hWrite
    sui.dwFlags = STARTF_USESHOWWINDOW Or STARTF_USESTDHANDLES
    sui.wShowWindow = SW_HIDE
    If CreateProcess(vbNullString, cmdLine, pra, tra, True, 0, Null, vbNullString, sui, pi) <> 0 Then
      SetWindowText objTarget.hwnd, ""
      Do
        Erase lpBuffer()
        If ReadFile(hRead, lpBuffer(0), 1023, bRead, ByVal 0&) Then
          SendMessage objTarget.hwnd, EM_SETSEL, -1, 0
          SendMessage objTarget.hwnd, EM_REPLACESEL, False, lpBuffer(0)
          DoEvents
        Else
          CloseHandle pi.hThread
          CloseHandle pi.hProcess
          Exit Do
        End If
        CloseHandle hWrite
      Loop
      CloseHandle hRead
    End If
  End If
End Sub

Miratelo, al principio pueden costar, pero son faciles de usar ;)

Salu2

esa! gracias a todos!

todo muy util ;)

SALUDOS

EON estuve haciendo varias cosas con ese code... mas o menos lo entiendo, pero x ejemplo para cambiar de directorio? cada vez q pongo la funcion "cd" se cuegla :S
no se xq  :huh:

si me podrias dar una mano (seria ocmo para hacer la funcion del filemnager:P)

SALUDOS

Pon en el text box cmd /c cd y si no recuerdo mal funcionaba. De todas formas ese código a mi no me gusta nada, mirate este y si eso te lo traduces a VB que es solo usar una par de apis:
http://foro.elhacker.net/programacion_cc/wsasocket_contra_socket-t210589.0.html;msg1000087#msg1000087

Salu2

Aca hay un ejemplo de como hacer un pipe
http://cobein27.googlepages.com/

jaja ok ahora los veo ;)

gracias de nuevo...