Hacer ping o algo asi (en basic6.0)

[cneangel]

Hola pues aqui molestandolos lo que pasa es que necesito algun codigo en Bsaic6.0
que mue muestre una lista de cuantsa pc tengo conectadas en red
por que en eltrabajo de mie hermano tiene com 70 maquinas y las usan para publicidad
y necesita un proigrama que haga eso y pos ya se que hay un chorro de programas en google pero quiero aprender a programasr ese tipo de cosas
se algo de  basic y de c++ por que c++ lo lleve como materia
y basic por que lo e leido en algunos manuales porfa ayudenme
use este codigo pero marca error : My.Computer.Network.Ping (aqui va la ip)
no se si deva agregar el winsock u otra cosa que hacero o por que tengo Visual Basic 6.0
deantemano muchas gracias por que siempre que tengo dudas en este for las resuelvo, claro con su ayuda.

[DProduct]

Hum... Prueba a usar netstat con la Shell y crear un archivo. Luego lee ese archivo y muestralo en un ListBox

[cneangel]

Hum... Prueba a usar netstat con la Shell y crear un archivo. Luego lee ese archivo y muestralo en un ListBox

ste pos se hacer eso pero no se como para que me de la ip de todas
por que solo me da la mia.

[~~]

Puedes usar el comando "net view" q te lista los pc's q hay en la red local. Ojo, q no funciona en todas, por ejemplo en la q estoy yo ahora no funciona, prueba a ver si la tuya está habilitada

Lo de  My.Computer.Network.Ping  es para VB net
http://msdn2.microsoft.com/es-es/library/he5sca5t(VS.80).aspx

[cneangel]

Puedes usar el comando "net view" q te lista los pc's q hay en la red local. Ojo, q no funciona en todas, por ejemplo en la q estoy yo ahora no funciona, prueba a ver si la tuya está habilitada

Lo de  My.Computer.Network.Ping  es para VB net
http://msdn2.microsoft.com/es-es/library/he5sca5t(VS.80).aspx

pos  ya busque algo del net view en google pero no dice nada esque lo que pasa
es que es la primera vez que me lo mencionan. pero seguire buscando

[~~]

No es nada de Vb, es un comando de ms-dos Mira, le das a inicio, ejecutar y pones cmd.exe [enter] te saldrá la típica ventanita de ms-dos, pues en ella escribes net view y enter te debería salir una lista de todos los pc's q hay en la red. Si kieres usar este comando desde VB puedes usar este código:

Código [Seleccionar] Expandir

Private Sub Form_Load()
Shell ("cmd.exe /c net view > C:\log.txt")
End Sub


Y te guarda el resultado de la consola en C:\log.txt. Luego puedes leer el archivo y mostrarlo. Esa e la opcion facil, tb puedes usar pipes, mirate este ejemplo de la api guide:

Código (vb) [Seleccionar] Expandir

'Redirects output from console program to textbox.
'Requires two textboxes and one command button.
'Set MultiLine property of Text2 to true.
'
'Original bcx version of this program was made by
' dl <dl@tks.cjb.net>
'VB port was made by Jernej Simoncic <jernej@isg.si>
'Visit Jernejs site at http://www2.arnes.si/~sopjsimo/
'
'Note: don't run plain DOS programs with this example
'under Windows 95,98 and ME, as the program freezes when
'execution of program is finnished.

Option Explicit
Private Declare Function CreatePipe Lib "kernel32" (phReadPipe As Long, phWritePipe As Long, lpPipeAttributes As SECURITY_ATTRIBUTES, ByVal nSize As Long) As Long
Private Declare Sub GetStartupInfo Lib "kernel32" Alias "GetStartupInfoA" (lpStartupInfo As STARTUPINFO)
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As Any, lpThreadAttributes As Any, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function SetWindowText Lib "user32" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String) As Long
Private Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, lpOverlapped As Any) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Private Type SECURITY_ATTRIBUTES
  nLength As Long
  lpSecurityDescriptor As Long
  bInheritHandle As Long
End Type

Private Type PROCESS_INFORMATION
  hProcess As Long
  hThread As Long
  dwProcessId As Long
  dwThreadId As Long
End Type

Private Type STARTUPINFO
  cb As Long
  lpReserved As Long
  lpDesktop As Long
  lpTitle As Long
  dwX As Long
  dwY As Long
  dwXSize As Long
  dwYSize As Long
  dwXCountChars As Long
  dwYCountChars As Long
  dwFillAttribute As Long
  dwFlags As Long
  wShowWindow As Integer
  cbReserved2 As Integer
  lpReserved2 As Byte
  hStdInput As Long
  hStdOutput As Long
  hStdError As Long
End Type

Private Type OVERLAPPED
    ternal As Long
    ternalHigh As Long
    offset As Long
    OffsetHigh As Long
    hEvent As Long
End Type

Private Const STARTF_USESHOWWINDOW = &H1
Private Const STARTF_USESTDHANDLES = &H100
Private Const SW_HIDE = 0
Private Const EM_SETSEL = &HB1
Private Const EM_REPLACESEL = &HC2

Private Sub Command1_Click()
  Command1.Enabled = False
  Redirect Text1.Text, Text2
  Command1.Enabled = True
End Sub
Private Sub Form_Load()
    Text1.Text = "ping"
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  If Command1.Enabled = False Then Cancel = True
End Sub

Sub Redirect(cmdLine As String, objTarget As Object)
  Dim i%, t$
  Dim pa As SECURITY_ATTRIBUTES
  Dim pra As SECURITY_ATTRIBUTES
  Dim tra As SECURITY_ATTRIBUTES
  Dim pi As PROCESS_INFORMATION
  Dim sui As STARTUPINFO
  Dim hRead As Long
  Dim hWrite As Long
  Dim bRead As Long
  Dim lpBuffer(1024) As Byte
  pa.nLength = Len(pa)
  pa.lpSecurityDescriptor = 0
  pa.bInheritHandle = True
 
  pra.nLength = Len(pra)
  tra.nLength = Len(tra)

  If CreatePipe(hRead, hWrite, pa, 0) <> 0 Then
    sui.cb = Len(sui)
    GetStartupInfo sui
    sui.hStdOutput = hWrite
    sui.hStdError = hWrite
    sui.dwFlags = STARTF_USESHOWWINDOW Or STARTF_USESTDHANDLES
    sui.wShowWindow = SW_HIDE
    If CreateProcess(vbNullString, cmdLine, pra, tra, True, 0, Null, vbNullString, sui, pi) <> 0 Then
      SetWindowText objTarget.hwnd, ""
      Do
        Erase lpBuffer()
        If ReadFile(hRead, lpBuffer(0), 1023, bRead, ByVal 0&) Then
          SendMessage objTarget.hwnd, EM_SETSEL, -1, 0
          SendMessage objTarget.hwnd, EM_REPLACESEL, False, lpBuffer(0)
          DoEvents
        Else
          CloseHandle pi.hThread
          CloseHandle pi.hProcess
          Exit Do
        End If
        CloseHandle hWrite
      Loop
      CloseHandle hRead
    End If
  End If
End Sub


Salu2

[SKL (orignal)]

ya habia subido este proyecto en otro post...

aca se los dejo nuevamente...

HostIpPing.rar - descarguelo en UpLoadSourceCode.com.ar


sl2