guardar datos cuando el programa esta ejecutado

[malkavianvam]

holassss, que tal, tenia una gran duda, bueno estoy haciendo un programatita bien trucho que agrega menues cuando el programa esta activo. este es el codigo:

Option Explicit
Dim indice As Integer

Private Sub cmd_Click()
Dim a
a = cmb.ListIndex
indice = indice + 1

If cmb.List(a) = "menu1" Then
       
        Load mnua(indice)
        mnua(indice).Caption = txt.Text
       
ElseIf cmb.List(a) = "menu2" Then
       
        Load mnub(indice)
        mnub(indice).Caption = txt.Text

ElseIf cmb.List(a) = "menu3" Then

        Load mnuc(indice)
        mnuc(indice).Caption = txt.Text

End If

End Sub

y mi duda seria como le puedo agregar codigo a esos munu que e agregado, pense en guardar el codigo en un archivo aparte o algo por el estilo, pero la verdad no tengo idea, bueno espero me puedan ayudar, y desde ya les estoy agradecido. saludos

[CeLaYa]

pues depende de que quieres que hagan esos menus, si los agregas para generar una especie de "Documentos abiertos recientemente" pues puedes ponerle en el nombre del menu el path del archivo y asi abrir los archivos

[malkavianvam]

bueno mira, lo que yo quiero hacer es parecido como el menu favoritos, cosa que agregas el menu (con el nombre que vos queras) y colocarle en el codigo que abra en una ventana aparte cierto sitio web, seguro hay muchas maneras de hacerlo muchisimo mas fasil, pero yo siempre me la complico, aparte ya que estoy en eso me gustaria aprender este tema de codificar cuando el programa esta activo, bueno es eso, te agradezco q me hayas respondido y espero que me puedas ayudar , bueno chauuu

[CeLaYa]

pues podrias crear un archivo un txt donde guardes el nombre que le das al menu y la direccion http, luego cuando en el codigo solo le pones que cuando se seleccione un nombre abra el txt y te abra una ventanita con la dirección relacionada

[malkavianvam]

buenisimo, gracias , saludosss

[Nymphetaminito]

Crea un formulario con un submenú de nombre mnuFavorite e índice 0, y un archivo de texto en el directorio del proyecto que se llame favoritos.txt

En favoritos.txt escribir lo siguiente:

Algoritmica:http://www.algoritmica.com.ar/
el Guille:http://www.elguille.info/default.aspx
VBPrincipiantes:http://www.vbprincipiantes.com/

Los datos se guardan por lineas, y de a par: Descripción:Url

Código [Seleccionar] Expandir


Option Explicit

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, Optional ByVal lpParameters As String, Optional ByVal lpDirectory As String, Optional ByVal nShowCmd As Long) As Long

Property Get AppPath() As String
  AppPath = App.Path
 
  If (Right$(AppPath, 1) <> "\") Then AppPath = AppPath & "\"

End Property

Sub LoadMenus()
  On Error GoTo Errors
 
      Dim hFile%, iCnt%
      Dim sLine$, iPos%

  hFile = FreeFile
 
  Open AppPath & "favoritos.txt" For Input As #hFile
 
  iCnt = -1
 
  Do
    iCnt = iCnt + 1
   
    If iCnt > 0 Then
      Call Load(mnuFavorite(iCnt))
    End If
   
    Line Input #hFile, sLine
   
    iPos = InStr(1, sLine, ":")
   
    mnuFavorite(iCnt).Caption = Left$(sLine, iPos - 1)
    mnuFavorite(iCnt).Tag = Mid$(sLine, iPos + 1)
    mnuFavorite(iCnt).Visible = True
   
  Loop While (Not EOF(hFile))
 
Errors:
  Close #hFile
End Sub

Private Sub Form_Load()
  Call LoadMenus
End Sub

Private Sub mnuFavorite_Click(Index As Integer)
  Call ShellExecute(0&, vbNullString, mnuFavorite(Index).Tag)
End Sub


Prueba el code y haz click en uno de los menús, voilà.

[malkavianvam]

joya gracias, me ayudo mucho  ,  suerte a todos, saludosss