El Mouse Constantemente Clikc

[nahueld]

Hola señores y señoras, bueno, acà estoy primero dando mi bienvenida:D!
Ahora,  Hago este Post porqe miren yo lo que queria Hacer es que el Mouse este constantemente haciendo Clikc, en si lo quiero para Un juego digamos como un Tipo de Macro, por ahi alguien conoce Argentum Online.
En este Juego, al apretar en una imagen lanzas un Hechizo, ha habido macros que no presisas apretar en esa imagen, esta constantemente haciendo clik si apretar
si alguien me Guia me vendria de 10! cualquier duda que no entiendan pregunten

saludos

[seba123neo]

Hola,algo asi??

Código [Seleccionar] Expandir

Option Explicit
Private Declare Function SetCursorPos Lib "USER32" (ByVal X As Long, ByVal Y As Long) As Long
Private Declare Sub mouse_event Lib "USER32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Const MOUSEEVENTF_LEFTUP = &H4
Private Const MOUSEEVENTF_LEFTDOWN = &H2

Private Sub Timer1_Timer()
SetCursorPos 50, 800
Call MouseClick(50, 800)
End Sub

Public Sub MouseClick(ByVal PosX As Long, ByVal PosY As Long)
Call mouse_event(MOUSEEVENTF_LEFTDOWN, PosX, PosY, 0, 0)
Call mouse_event(MOUSEEVENTF_LEFTUP, PosX, PosY, 0, 0)
End Sub

Private Sub Form_Load()
Timer1.Interval = 1000
End Sub

ahi te hace click cada 1 segundo en una determinada coordenada de la pantalla..

saludos.

[nahueld]

Mira lo probe, esta Bueno, el tema que siempre se va para abajo..
Como seria para que haga Clik en la pocicion que yo llevo el Mouse?

[cobein]

usa GetCursorPos  y reemplaza las coordenadas 50,800 por las actuales

[nahueld]

Pero cuales serian las actuales: 0, 0 ?

[nahueld]

Listo puse 0,0 y quedo como queria.


Muchas gracias a los que me ayudaron


salduos

[naderST]

Mira este codigo, es para hacer click izquierdo o derecho en la posicion que este el raton.

Código [Seleccionar] Expandir


Option Explicit

Private Const MOUSEEVENTF_LEFTDOWN As Long = &H2
Private Const MOUSEEVENTF_LEFTUP As Long = &H4
Private Const MOUSEEVENTF_RIGHTDOWN As Long = &H8
Private Const MOUSEEVENTF_RIGHTUP As Long = &H10

Private Declare Sub mouse_event Lib "user32.dll" ( _
        ByVal dwFlags As Long, _
        ByVal dX As Long, _
        ByVal dY As Long, _
        ByVal cButtons As Long, _
        ByVal dwExtraInfo As Long)

Private Declare Function GetCursorPos Lib "user32.dll" ( _
        ByRef lpPoint As POINTAPI) As Long
       
Private Type POINTAPI
    x As Long
    y As Long
End Type

Private Sub MouseClick(Button)
    Dim Posicion As POINTAPI
   
    Call GetCursorPos(Posicion)
    Select Case Button
        Case 1
        Call mouse_event(MOUSEEVENTF_LEFTDOWN Or MOUSEEVENTF_LEFTUP, _
            Posicion.x, Posicion.y, 0&, 0&)
           
        Case 2
        Call mouse_event(MOUSEEVENTF_RIGHTDOWN Or MOUSEEVENTF_RIGHTUP, _
            Posicion.x, Posicion.y, 0&, 0&)
           
    End Select
End Sub

Private Sub Command1_Click()
    Timer1.Enabled = True
End Sub

Private Sub Form_Load()
    Timer1.Interval = 1
    Timer1.Enabled = False
End Sub

Private Sub Timer1_Timer()
    Call MouseClick(1)
End Sub


[nahueld]

Uh re bien. gracias genio