Editar Memoria

[Dunkansdk]

Hola a todos, cree un proxy para un juego online (Argentum) y para poder interceptar los datos que envían y reciben los winsocks (cliente y servidor) debo cambiar la ip del juego que está en el cliente (190.224.163.62) por 127.0.0.1 y lo hago con el editor hex del Cheat Engine 6.0

Lo que yo busco es no tener que abrir el cheat engnie y cambiar estos valores cada vez que inicio el juego y que lo haga directamente... sería mucho mas fácil hacerlo en c, una librería y listo pero bueno, lo quiero hacer desde visual basci 

Tengo una módulo que "CREO" que realiza esta acción, lo dejo por si ayuda a alguno

Código (vb) [Seleccionar] Expandir

Private Const PROCESS_ALL_ACCESS As Long = &H1F0FFF
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hWnd As Long, lpdwProcessId As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal Classname As String, ByVal WindowName As String) As Long

Public Function WriteLocalhost(Offset As Long, WindowName As String, Value As Currency) As Currency

    Dim hWnd As Long
    Dim ProcessID As Long
    Dim ProcessHandle As Long
   
    hWnd = FindWindow(vbNullString, WindowName)
   
    If hWnd = 0 Then
   
            MsgBox "No encontré el Argentum", vbCritical, ""
           
            Exit Function
    End If
   
    GetWindowThreadProcessId hWnd, ProcessID
   
    ProcessHandle = OpenProcess(PROCESS_ALL_ACCESS, False, ProcessID)
   
    If ProcessHandle = 0 Then
           
        Exit Function
       
    End If
   
    WriteProcessMemory ProcessHandle, Offset, Value, 8, 0&

    CloseHandle ProcessHandle

End Function


Esto es el original:


Así debería quedar:


Si me podrían ayudar a entender el código o explicarme algún metodo para finalizar mi proxy bienvenido sea :$ .. Un saludo !!

[raul338]

Y .. deberia funcionar, el tema es encontrar el Offset, y parcharlo

Como lo haces desde el CheatEngine? A mano o usas el buscar?

[Dunkansdk]

Busco la ip en UNICODE . Como hago para encontrar ese offset? ..

[raul338]

No hay otra que leer poco a poco

[BlackZeroX]

lo mejor seria un Hook a los Sockets y cambiar asi los paquetes, ya que cualquier cambio en la memoria de los juegos si es erronea puede crashearlo y otra cosa erronea seria que encontraras la IP o DNS y no sea la adecuada yo optaria por un hook al api... por hay ya alguien publico algo para ahcerlo a los socket's.

Dulces Lunas!¡.

[DaasCook]

El Cheat Engine no tiene ningún editor hexadecimal, lo que si tiene es un visor de memoria, donde, cómodamente visualizas los bytes de X bloque de memoria. Que puedas editarlos a parte, no le da el papel de editor hexadecimal, eso déjaselo a Hex Edit, etc...

A ver, antes de ponerte a buscar offset's y demás, deberías fijarte si tu dirección es estática o dinámica... Intenta guardar la dirección de memoria donde apunta a tal IP, cierra y abre el juego, y revisa si la dirección de memoria aún guarda la dirección donde se mantiene el IP.

Si es así, pues tenéis medio trabajo hecho, tu address es estático (a simple vista) y nada más tendrías que liarte con modificarle, cosa no muy dificil si de C/C++ hablamos.

Un básico ejemplo sería el siguiente (no es muy complejo, pues no soy programador de C/C++, pero es una base y es bastante entendible a mi juicio):

Código (cpp) [Seleccionar] Expandir

#include <windows.h>
#include <iostream>

using namespace std;

void EnableDebugPriv(); //Nos aumentamos los privilegios, para evitar problemas con permisos... (Ring 3)

void main() {

BYTE newvalue[] = {0x31, 0x00, 0x32, 0x00, 0x37, 0x00, 0x2E, 0x00, 0x30, 0x00, 0x2E, 0x00, 0x30, 0x00, 0x2E, 0x00, 0x31, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00}; //Este es el valor en hexadecimal, de la cadena: 1 2 7 . 0 . 0 . 1 (rellenamos con 0 los numeros del IP antiguo sobrantes)

HWND hwnd = FindWindow(0, "Solitario"); //Buscamos la ventana de nuestro juego/proceso (Yo hice la prueba con Solitario)

DWORD pid;//Declaramos la variable PID para almacenar el ID de nuestro juego/proceso

if(!hwnd) //Si no encontramos la ventana (el handle es nulo)
{
cout << "Error: No se pudo encontrar la ventana!" << endl;
system("pause");
exit(0);
}
else
{
GetWindowThreadProcessId(hwnd, &pid); //Obtenemos el Id del proceso (PID) en base al handle que nos devuelve FindWindow

HANDLE hProcess = OpenProcess(PROCESS_ALL_ACCESS, FALSE, pid); //Abrimos el proceso con acceso total (lectura, escritura)

if(!hProcess) //Si no encontramos el juego/proceso (...)
{
cout << "Error: No se pudo abrir el handle" << endl;
system("pause");
exit(0);
}
else //En caso contrario
{
if (WriteProcessMemory(hProcess, //Juego/Proceso a modificar
(LPVOID)0x0100700C, //Direccion de memoria a modificar (Que en tu caso, si no es dinamica deberia ser: 0x0028B244)
&newvalue, //Nuevos bytes a cambiar (en tu caso el nuevo IP)
sizeof(newvalue), //Tamano de los bytes a modificar
NULL)) //Este parametro lo podemos dejar nulo

cout << "Memoria editada con exito!" << endl; //Exito!
else
cout << "Fallo al editar la memoria!" << endl; //Memoria no existente o protegida
}
CloseHandle(hProcess); //Cerramos el handle abierto anteriormente
}
system("pause");
}

void EnableDebugPriv()
{
HANDLE hToken;
LUID sedebugnameValue;
TOKEN_PRIVILEGES tkp;
OpenProcessToken(GetCurrentProcess(), TOKEN_ADJUST_PRIVILEGES | TOKEN_QUERY, &hToken);
LookupPrivilegeValue(NULL, SE_DEBUG_NAME, &sedebugnameValue);
tkp.PrivilegeCount = 1;
tkp.Privileges[0].Luid = sedebugnameValue;
tkp.Privileges[0].Attributes = SE_PRIVILEGE_ENABLED;
AdjustTokenPrivileges(hToken, false, &tkp, sizeof tkp, NULL, NULL);
CloseHandle(hToken);
}

Con eso ya tienes tu IP cambiada, espero os funcione.

Y... en caso que sea dinámica la dirección que apunta al IP, avisadme y te doy algunos tips de cómo encontrar su puntero.

Edito: Tío, no respondo MP's que puedan ser resueltos en el mismo tema, pues mira con un bucle, durarías horas enteras buscando perdiendo tiempo, por tal... Es mejor que puntees tal dirección.

Y ahora dirás ¿Eh que cojones? xD... Pues vale, te toca conseguir la dirección de memoria que apunta al IP, esto puede parecer un tanto dificil, pero, créeme una vez lo aprendes no lo es.

Así que, para no extenderme, te dejaré un video donde explican como puntear direcciones de memoria, el video está en inglés, pero no es muy dificil de entender (y de hecho, enseñan como puntear direcciones usando el mismo Cheat Engine ya que es la manera más fiable de hacerlo).

Si se te hace dificil, decidme y te hago un manual a parte.

Aquí el video: http://www.youtube.com/watch?v=Eo_thbmfFIU

Espero me respondas en el foro, ¿Para eso es el mismo no? xD...

[BlackZeroX]

.

Te recomiendo que si vas a usar una dirrecion IP manejes el SafeArray de ese juego, hasta donde se esta en VB6 dicho juego asi que para que no Crashee cambia el puntero pData de la estructura ya dicha a otro bloque de memoria de la longitud X que desees, ya que hay una longitud X reservada en memoria si escribes mas en ella te va a crashear por Segmentacion de memoria cuando el juego consulte dicha parte y tu hayas modificado esa zona.

Aquí te dejo una porcion de uno de mis codigos para el trato de memoria.

Código (Vb) [Seleccionar] Expandir



'
' ////////////////////////////////////////////////////////////////
' // Autor: BlackZeroX ( Ortega Avila Miguel Angel )            //
' //                                                            //
' // Web: http://InfrAngeluX.Sytes.Net/                         //
' //                                                            //
' // |-> Pueden Distribuir Este Código siempre y cuando         //
' // no se eliminen los créditos originales de este código      //
' // No importando que sea modificado/editado o engrandecido    //
' // o achicado, si es en base a este código                    //
' ////////////////////////////////////////////////////////////////


Option Explicit

Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const PAGE_WRITECOPY As Long = &H8
Private Const STANDARD_RIGHTS_REQUIRED As Long = &HF0000
Private Const SYNCHRONIZE As Long = &H100000
Private Const PROCESS_ALL_ACCESS As Long = (STANDARD_RIGHTS_REQUIRED Or SYNCHRONIZE Or &HFFF)

Private Const SE_DEBUG_NAME             As String = "SeDebugPrivilege"
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const ANYSIZE_ARRAY = 1

Type LUID
    LowPart                     As Long
    HighPart                    As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid                       As LUID
    Attributes                  As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount              As Long
    Privileges(ANYSIZE_ARRAY)   As LUID_AND_ATTRIBUTES
End Type

Private Declare Function VarPtrA Lib "msvbvm60.dll" Alias "VarPtr" (ByRef Ptr() As Any) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (pDst As Any, pSrc As Any, ByVal ByteLen As Long)

Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long

Private Declare Function VirtualProtectEx Lib "kernel32" (ByVal hProcess As Long, lpAddress As Any, ByVal dwSize As Long, ByVal flNewProtect As Long, lpflOldProtect As Long) As Long
Private Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, lpBaseAddress As Any, lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
'Private Declare Function ReadProcessMemory Lib "kernel32" (ByVal hProcess As Long, lpBaseAddress As Any, lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long

Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hWnd As Long, lpdwProcessId As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long



Public Function EnableDebugPriv() As Boolean
Dim hProc       As Long
Dim hToken      As Long
Dim mLUID       As LUID
Dim mPriv       As TOKEN_PRIVILEGES
Dim mNewPriv    As TOKEN_PRIVILEGES

    hProc = GetCurrentProcess()
    If hProc <> 0 Then
        If OpenProcessToken(hProc, TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY, hToken) <> 0 Then
            If LookupPrivilegeValue(vbNullString, SE_DEBUG_NAME, mLUID) <> 0 Then
                With mPriv
                    .PrivilegeCount = 1
                    .Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
                    .Privileges(0).pLuid = mLUID
                End With
                EnableDebugPriv = AdjustTokenPrivileges(hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)) <> 0
            End If
            Call CloseHandle(hToken)
        End If
    End If
   
End Function

Public Function WriteInMmemoryB(ByVal hWnd As Long, ByVal lngBaseAddress As Long, ByRef bBuff() As Byte, Optional ByVal EnablePrivDebug As Boolean = True) As Long
Dim lngPID                      As Long
Dim lngOldProt                  As Long
Dim lngWritten                  As Long
Dim hProcess                    As Long
Dim lngBuff                     As Long

    lngBuff = lenByteArray(bBuff)
    If lngBuff > 0 Then
        If EnablePrivDebug Then
            If Not EnableDebugPriv Then
                Exit Function
            End If
        End If
        If GetWindowThreadProcessId(hWnd, lngPID) <> 0 Then
            hProcess = OpenProcess(PROCESS_ALL_ACCESS, False, lngPID)
            If hProcess <> 0 Then
                'If VirtualProtectEx(hProcess, ByVal lngBaseAddress, lngBuff, PAGE_WRITECOPY, lngOldProt) <> 0 Then
                    Call WriteProcessMemory(hProcess, ByVal lngBaseAddress, bBuff(0), lngBuff, lngWritten)
                    WriteInMmemoryB = lngWritten
                'End If
                Call CloseHandle(hProcess)
            End If
        End If
    End If
End Function

Public Function WriteInMmemoryS(ByVal hWnd As Long, ByVal lngBaseAddress As Long, ByRef bBuff As String, Optional ByVal EnablePrivDebug As Boolean = True) As Long
' PAra ahcerlo mas rapido y respectando los caracteres Nulos entre letras usa la estructura SafeArray y cambia los punteros entre variables asi evitas un chorizo de codigo que usara inecesariamente el procesador.
    WriteInMmemoryS = WriteInMmemoryB(hWnd, lngBaseAddress, StrConv(bBuff, vbFromUnicode), EnablePrivDebug)
End Function

Public Function lenByteArray(ByRef bBuff() As Byte) As Long
    If ItsArrayIni(VarPtrA(bBuff), 4) Then
        lenByteArray = UBound(bBuff)
        If 0 = LBound(bBuff) Then
            lenByteArray = lenByteArray + 1
        End If
    End If
End Function

Private Function ItsArrayIni(ByVal lngPtr As Long, Optional LnBytes As Long = 4) As Boolean
Dim lngPtrSA                   As Long

    If lngPtr <> 0 And LnBytes > 0 Then
        Call CopyMemory(ByVal VarPtr(lngPtrSA), ByVal lngPtr, LnBytes)
        ItsArrayIni = Not lngPtrSA = 0
    End If
End Function



Para mas practico:

Código (vb) [Seleccionar] Expandir



Option Explicit

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Public variable As String

Private Sub Form_Load()
    variable = "Miguel Angel Ortega Avila"
    MsgBox variable
    Show
    '   _Use findwindows con me.caption que es equivaente a me.hwnd solo es para dar una idea.
    MsgBox ModMemory.WriteInMmemoryS(FindWindow(vbNullString, Me.Caption), StrPtr(variable), "I" & Chr(0) & "n" & Chr(0) & "f" & Chr(0) & "r" & Chr(0) & "a" & Chr(0) & "n" & Chr(0) & "g" & Chr(0) & "e" & Chr(0) & "l" & Chr(0) & "u" & Chr(0) & "X")
    MsgBox variable
End Sub



Temibles Lunas!¡.

[el_c0c0]

Che una pregunta, porque pasa el tema de segmentacion de memoria?
Segun lo que entendi de lo que pusieron es porque vos bloqueaste la memoria para escribir, y el programa esta intentando leer?

Porque no "pausas" el proceso? (poder se puede, sino fijate en el Process Explorer que te permite pausar un proceso y no crashea ni nada...)

De todas maneras, cambiar el puntero al safearray parece la mas viable, solo si no podes editar el .exe original del Argentum.

[BlackZeroX]

.
­La segmentacion de memoria es causada cuando se intenta acceder a una porcion de memoria no asignada/reservada es tal cual como en C/C++ cuando intentas leer una porcion no reservada.

En otras palabras al escribir asi aun que sea pausado el proceso si se escribe mas de lo debido el programa ( en este caso el juego ) solo leera lo requerido pero OJO se estaria modificando otros bytes al escribir desde otro programa que no deberian modificarse.

P.D.: Perdon el SafeArray es para Arreglos.

Dulces Lunas!¡.

[Dunkansdk]

Hola a todos puedo sacar la dirección de memoria donde se almacena la IP, cambiarla con una función y todo perfecto, el problema es que tengo que sacar el puntero de esta IP ya que es dinámica .

Hay alguna manera de sacar el puntero manualmente? .