Duda sobre winsock y http

[Karcrack]

Wenas.
Me gustaria saber si se puede poner de alguna forma el winsock en escucha al puerto 80 y kuando winsock note algunja conexion que envie datos html.
Gracias. (no se si me he explicado bien)

Karcrack

[WarGhost]

claro que se puede mira este código que acabo de hacer, ya se que es básico que por lo menos... :

Código [Seleccionar] Expandir

Private Const Port As String = 80

Private Sub Form_Load()
Socket(0).LocalPort = Port
Socket(0).Listen
End Sub

Private Sub Socket_ConnectionRequest(Index As Integer, ByVal requestID As Long)
Socket(Index).Close
Socket(Index).Accept requestID
Load Socket(Socket.Count)
Socket(Socket.UBound).LocalPort = Port
Socket(Socket.UBound).Listen
End Sub

Private Sub Socket_DataArrival(Index As Integer, ByVal bytesTotal As Long)
Dim buffer As String
Dim Respuesta As String: Dim ruta As String: Dim data As String
Socket(Index).GetData buffer

ruta = App.Path & Replace(Mid(buffer, 5, InStr(1, buffer, "HTTP") - 6), "/", "\")

If ruta = App.Path & "\" Then ruta = ruta & "index.htm"

If Dir(ruta, vbArchive) <> "" Then
Respuesta = "HTTP/1.1 200 OK" & vbCrLf & _
"Server: WarGhost WebServer" & vbCrLf & vbCrLf

Open ruta For Binary As #1
data = Space(LOF(1))
Get #1, , data
Close #1
Respuesta = Respuesta & data
Socket(Index).SendData Respuesta
Else
Respuesta = "HTTP/1.1 404 Not Found" & vbCrLf & _
"Server: WarGhost WebServer" & vbCrLf & vbCrLf

Respuesta = Respuesta & "Error..."
Socket(Index).SendData Respuesta
End If

End Sub

Private Sub Socket_SendComplete(Index As Integer)
Socket(Index).Close
End Sub

Salu2

[ranslsad]

Hola, quisiera saber que hace esto exactamente?
y tambien si esto sirve por ejemplo para hacer un mini Server es decir que yo quiero hacer un exe y una carpeta para que la gente pueda ahcer su MiniWeb cada vez que quiera (El ejemplo del guru no me sirve porque cuando entro a la web se traba el programa, es decir y veo el log y recibe pero al enviar datos se pone (No Responde)

Bueno espero que sepas responderme

Salu2

Ranslsad

[WarGhost]

es un tipo server apache ,donde se aloja el fichero es como si fuera la carpeta www de apache.

Salu2