AnonFilesUpload Función

Iniciado por Danyfirex, 14 Mayo 2013, 20:22 PM

0 Miembros y 1 Visitante están viendo este tema.

Danyfirex

Una funcion para subir archivos a Anonfiles  :rolleyes:

Código (vb) [Seleccionar]
' =================================================================
' =================================================================
' => Autor: Danyfirex
' => Upload file to AnonFiles.com
' => Gracias AnonFiles.com
' => Fecha : 14|05|2013
' => Uso: AnonFilesUpload("c:\hola.rar")
' => Retorno: Texto de Respuesta (hotlink)
' =================================================================
' =================================================================


Option Explicit

Function AnonFilesUpload(filepath As String) As String
Dim boundary As String
Dim Post As String
Dim bytesfinal()  As Byte
Dim bytes() As Byte
Dim url As String
Dim Http As Object
Dim filedata As String

url = "https://anonfiles.com/api/hotlink"
boundary = "--------Boundary"


Open filepath For Binary As #1
ReDim bytes(LOF(1) - 1)
Get #1, , bytes()
Close #1
filedata = StrConv(bytes(), vbUnicode)

Post = "--" & boundary & vbCrLf & _
"Content-Disposition: form-data; name=" & Chr(34) & "file" & Chr(34) & "; filename=" & Chr(34) & filename(filepath) & Chr(34) & vbCrLf & _
"Content-Type: application/octet-stream" & vbCrLf & vbCrLf & _
filedata & vbCrLf & _
"--" & boundary & "--" & vbCrLf

bytesfinal() = StrConv(Post, vbFromUnicode)

Set Http = CreateObject("winhttp.winhttprequest.5.1")
Http.Open "POST", url, False
Http.SetRequestHeader "Content-Type", "multipart/form-data; " & "boundary=" & boundary
Http.Send (bytesfinal())
AnonFilesUpload = Http.ResponseText
Set Http = Nothing
End Function

Function filename(cadena As String) As String
Dim cadenas() As String
cadenas() = Split(cadena, "\")
filename = cadenas(UBound(cadenas))
End Function

XresH

Excelente, lo probe y me funciono correctamente, para los nuevos si me permitis dejo un comentario y un detalle !

Para usar esta funcion realizada por Danyfirex pueden "llamarla" de esta manera


txtUrl.Text = AnonFilesUpload("c:\mibat.rar")


Donde txtUrl es en donde obtendremos el string que tiene la url para la
descarga de nuestro archivo, lo que esta entre parentesis es el archivo
que queremos subir.
Tengan en cuenta que cuanto mas grande sea el archivo, mas tiempo lleva.

Buen aporte, Saludos.

[ - Si eres programador y quieres que tus proyectos esten en mi blog(con o sin source), consúltame! - ]
Entra A Mi Blog De Programación | | Dudas en este post :| | >>Clic para ir al Post<<