Alguien sabe como crear accesos directos en VB 6.0?

[Shadow]

Hola!!; mi duda es simple, sabe alguien como crear accesos directos desde VB?
y ponerlos en el escitorio...

encontre esto pero no funciona...

Option Explicit
Private Declare Function fCreateShellLink Lib "STKIT432.DLL" (ByVal lpstrFolderName As String, ByVal lpstrLinkName As String, _
ByVal lpstrLinkPath As String, ByVal lpstrLinkArgs As String) As Long

Private sub Command1_Click()
Dim lReturn As Long
lReturn = fCreateShellLink("..\..\Escritorio", "Nombre que quieras", "c:\xxxx\xxxx.exe", "")
End Sub

Y sobre la dll   STKIT432.DLL


esto:

Visual Basic Setup Toolkit Library DLL Este proceso todavía se está repasando. Si usted tiene cierta información sobre ella sensación libremente para enviarnos un email en pl[at]uniblue[dot]net
Procesos no pertenecientes al sistema como stkit432.dll originados por el software que ha instalado en su sistema. Puesto que la mayoría de aplicaciones almacenan datos en el registro del sistema, es probable que su registro haya sufrido una fragmentación y acumulado errores dañinos. Se recomienda que compruebe su registro para identificar errores ocultos.


Desde ya muchas gracias =)

[Shadow]

Encontre algo "nuevo" porque es vieja la documentacion. (Tengo que probarlo aun.... =) )


Dos formas de crear accesos directos
Usando DDE y el WSH
Publicado: 22/Ene/2000
Actualizado: 21/Jun/2000



Seguramente, (de hecho), hay más formas de hacerlo, pero estas dos que muestro aquí son las más accesibles, es decir, que no necesitas de llamadas al API ni crear referencias a funciones propias del Sistema Operativo para crear links o accesos directos, aunque es lamentable que el Visual Basic no disponga de una función u objeto con el cual poder crear, modificar o simplemente acceder a los accesos directos tan comunes en el Windows... talvez en la versión 7...

La primera forma que mostraré será la que se usaba cuando el Windows 3.x (sí, ese del que ya casi nadie sabe que existió, aunque aún hay gente que trabajan con él), para ello se usaba DDE o lo que es lo mismo la forma antigua de comunicarse entre aplicaciones... no voy a entrar en detalles sobre lo que es el DDE ni nada de eso, ya que hace tiempo que no lo uso y cuando lo usaba simplemente era con ejemplos prefabricados... o casi...

La segunda es usando el Windows Scripting Host (WSH). Seguramente esta forma será la preferida para aquellos que dispongáis del Windows 98/2000, (siempre que hayas seleccionado esa opción) o bien el Windows 95/NT con el WSH instalado, ya que también se puede instalar de forma separada desde el sitio de Microsoft:
http://msdn.microsoft.com/scripting/

Vamos a ver el código de ejemplo para ambos casos:

Usando DDE

He dejado los comentarios originales, aunque, lamentablemente ahora no recuerdo quién fue el autor de los mismos... lo siento.
El icono sólo se creará en la carpeta de Programas del menú de Inicio... con el otro sistema podrás crearlo en otros sitios diferentes...
Otra de las limitaciones de éste método es que no se pueden usar símbolos "raros" en el nombre del acceso directo, entre los cuales están los paréntesis.

Para usar este ejemplo, crea un nuevo proyecto, añádele un par de etiquetas y dos textboxes (en uno irá el nombre del acceso directo y en el otro el path del programa a ejecutar), y un botón para crear el acceso directo.

'
'------------------------------------------------------------------------------
' Crear accesos directos usando DDE                                 (14/Ene/00)
'
' Basado en un código para VB2/3 de 1994... por lo menos,
' que a su vez está basado en otro anterior con las rutinas para trabajar con DDE
' y algunas otras virguerías (al menos en aquellos tiempos)
'
' '------------------------------------------------------------------------------
Option Explicit

Private Sub cmdCrear_Click()
   ' Crear el acceso directo                                       (14/Ene/00)
   ' Se creará dentro de Programas del Menú de Inicio
   '
   CrearIconoEnProgMan Me, Text2.Text, Text1.Text
End Sub

Private Sub cmdSalir_Click()
   ' Salir del programa
   Unload Me
End Sub


'----------------------------------------------------------
' Procedure: CrearIconoEnProgMan
'
' Arguments: X           The form where Label1 exists
'
'            CmdLine$    A string that contains the command
'                        line for the item/icon.
'                        ie 'c:\myapp\setup.exe'
'
'            IconTitle$  A string that contains the item's
'                        caption
'----------------------------------------------------------
Private Sub CrearIconoEnProgMan(X As Form, CmdLine$, IconTitle$)
   
   Dim i As Integer, z As Integer
   
   Screen.MousePointer = 11
   ' Poner la primera letra en mayúsculas
   IconTitle$ = Left$(IconTitle$, 1) & LCase$(Mid$(IconTitle$, 2))
   
   '----------------------------------------------------------------------
   ' Windows requires DDE in order to create a program group and item.
   ' Here, a Visual Basic label control is used to generate the DDE messages
   '----------------------------------------------------------------------
   On Error Resume Next
   
   '---------------------------------
   ' Set LinkTopic to PROGRAM MANAGER
   '---------------------------------
   X.Label1.LinkTopic = "ProgMan|Progman"
   X.Label1.LinkMode = 2
   For i = 1 To 10         ' Loop to ensure that there is enough time to
     z = DoEvents()        ' process DDE Execute.  This is redundant but needed
   Next                    ' for debug windows.
   X.Label1.LinkTimeout = 100
   
   '------------------------------------------------
   ' Create Program Item, one of the icons to launch
   ' an application from Program Manager
   '------------------------------------------------
   X.Label1.LinkExecute "[AddItem(" & CmdLine$ & Chr$(44) & IconTitle$ & Chr$(44) & ",,)]"
   
   '-----------------
   ' Reset properties
   '-----------------
   X.Label1.LinkTimeout = 50
   X.Label1.LinkMode = 0
   
   Screen.MousePointer = 0
End Sub

Usando el WSH

Ahora vamos a ver el código de la otra forma de crear accesos directos en Windows.
Para crear el código que pondré a continuación, tendrás que crear un nuevo proyecto, añade tres etiquetas, tres textboxes, un listbox y un botón para crear el acceso directo.
La primera caja de textos servirá para introducir el nombre del acceso directo.
La segunda indicará el path del programa a ejecutar.
La tercera caja de textos indicará en que sitio queremos crear el acceso directo, el lugar de destino se seleccionará de las opciones mostradas en el Listbox.

Estos son algunos de los "destinos" de los accesos directos:
AllUsersDesktop
AllUsersStartMenu
AllUsersPrograms
AllUsersStartup

Desktop
Favorites
Fonts
MyDocuments
NetHood
PrintHood
Programs
Recent
SendTo
StartMenu
Startup
Templates


El destino "real" se puede averiguar mediante una llamada al método SpecialFolders del objeto Shell del WSH:
x = SpecialFolders("Desktop") ' Devolverá el path del Escritorio

Un, dos, tres...
Básicamente la forma de crear los accesos directos es:

Crear una referencia al objeto Shell del Scripting Host:
Set wshShell = CreateObject("WScript.Shell")
Llamar al método CreateShorcut:
Set vLnk = wshShell.CreateShortcut(sLnkPath)
Asignar el path de destino:
vLnk.Targetpath = sAppPath
y guardar los datos...
vLnk.Save
Las variables usadas son del tipo Variant, ya que pueden recibir objetos de cualquier tipo...

Si prefieres usar los tipos "reales", tendrás que crear una referencia al objeto Windows Scripting Host Object Model (WSHOM.OCX) y usar los siguientes tipos:

Para el objeto Shell:
Private m_wsShell As IWshShell_Class

Crear una referencia al objeto Shell:
Set m_wsShell = New IWshShell_Class

Una variable para crear accesos directos:
Dim vLnk As IWshShortcut_Class

Obtener una de las carpetas especiales:
sLnkPath = m_wsShell.SpecialFolders.Item(Text3.Text)
(fíjate que hay que usar Item para poder acceder... curioso...)

Crear un acceso directo:
Set vLnk = m_wsShell.CreateShortcut(sLnkPath)



Veamos el código del formulario usando objetos del tipo Variant y creando una referencia en tiempo de ejecución (late binding):

'
'------------------------------------------------------------------------------
' Crear accesos directos usando WHS                                 (14/Ene/00)
'
'------------------------------------------------------------------------------
Option Explicit

Private m_wsShell As Variant

Private Sub cmdCrear_Click()
   ' Crear el acceso directo                                       (14/Ene/00)
   Dim sLnkPath As String
   Dim sLink As String
   Dim sAppPath As String
   Dim vLnk As Variant
   
   sAppPath = Text2
   sLink = Text1
   If InStr(sLink, ".lnk") = 0 Then
       sLink = sLink & ".lnk"
   End If
   ' Crearlo en el escritorio:
   'sLnkPath = m_wsShell.SpecialFolders("Desktop")
   '
   ' Crearlo en el indicado en el listbox
   ' Aunque siempre lo crea en el mismo sitio:
   ' C:\WINDOWS\All Users\Desktop
   ' es decir en el escritorio.
   '
   ' Pero eso era usando TEXT3 a secas,
   ' añadiendo el .Text ya si que sale lo que debe salir...
   '
   sLnkPath = m_wsShell.SpecialFolders(Text3.Text)
   sLnkPath = sLnkPath & "\" & sLink
   
   ' Crear el acceso directo
   Set vLnk = m_wsShell.CreateShortcut(sLnkPath)
   vLnk.Targetpath = sAppPath
   '
   '--------------------------------------------------------------------------
   ' Enviado el 20/Jun/00 por:
   ' paco diaz, frandivi@larural.es
   '
   ' definir directorio de trabajo
   vLnk.WorkingDirectory = "D:\gsCodigo" ' Escribe aquí el directorio
   '--------------------------------------------------------------------------
   '
   vLnk.Save
End Sub

Private Sub cmdSalir_Click()
   ' Salir del programa
   Unload Me
End Sub

Private Sub Form_Load()
   Set m_wsShell = CreateObject("WScript.Shell")
   
   List1.Clear
   
   ' Llenar el listbox con los "folders" de SpecialFolders
   '
   'Dim vName As Variant

   ' (Este método es preferible si quieres mostrar todos las carpetas especiales)

   'For Each vName In m_wsShell.SpecialFolders
   '    List1.AddItem vName
   'Next
   '
   '
   ' Estos no son válidos para el W95
   List1.AddItem "AllUsersDesktop= " & m_wsShell.SpecialFolders("AllUsersDesktop")
   'List1.AddItem "AllUsersStartMenu= " & m_wsShell.SpecialFolders("AllUsersStartMenu")
   'List1.AddItem "AllUsersPrograms= " & m_wsShell.SpecialFolders("AllUsersPrograms")
   'List1.AddItem "AllUsersStartup= " & m_wsShell.SpecialFolders("AllUsersStartup")
   '
   List1.AddItem "Desktop= " & m_wsShell.SpecialFolders("Desktop")
   List1.AddItem "Programs= " & m_wsShell.SpecialFolders("Programs")
   List1.AddItem "StartMenu= " & m_wsShell.SpecialFolders("StartMenu")
   List1.AddItem "Startup= " & m_wsShell.SpecialFolders("Startup")
   List1.AddItem "MyDocuments= " & m_wsShell.SpecialFolders("MyDocuments")
   List1.ListIndex = 0
   '
End Sub

Private Sub Form_Unload(Cancel As Integer)
   Set m_wsShell = Nothing
End Sub

Private Sub List1_Click()
   ' Mostrar el destino del acceso directo
   Dim sTmp As String
   Dim i As Long
   
   sTmp = List1.List(List1.ListIndex)
   i = InStr(sTmp, "= ")
   If i Then
       Text3 = Left$(sTmp, i - 1)
   Else
       Text3 = "Desktop"
   End If
End Sub



lo saque de la pagina del guille.

[79137913]

HOLA!!!

Me parece que te respondiste solo... Al menos usaste google, ojala la mitad de los que preguntan lo usaran!

No me agrada tu nick Shadow.

Todo bien siempre y cuando no agregues Scout.

GRACIAS POR LEER!!!

[Shadow]

Si lo se, a veces no doy con las busquedas correctas colega, pero de todas formas sigue sin funcionar... y aun asi no volvi a postear... a ver si lo saco.
Has probado algo similar a esto?
un saludo 79137913 (es un buen numero

[79137913]

HOLA!!!

Mira, aca tenes en RecVB un ejemplo que genera accesos directos re facil.

GRACIAS POR LEER!!!

[Shadow]

Hola numerooo!!!! Impecable... salio funcionando al toque.
Muchas gracias!!!
=)

[Shadow]

Hola de nuevo, un pequeño problemita con unas variables string... mira...

Cargo de un texto (que uso como .ini en la carpeta del programa) todo en un list, son nombres de programas y el acceso directo.

en el list aparecen ya cargados asi:


Programa1; "C:\Programas\programa1.exe"

Programita2; "C:\Programas\Programita2.exe"

Programon3; "C:\Programas\Programon3.exe"


Ahora bien, tengo en cada "linea" de este list dos datos que me interesan:
El nombre del programa y la direccion.

si la en la lista el programa esta seleccionado...

For i = 0 To List2.ListCount
   
If List2.Selected(i) Then
        Dim NombreLink() As String
        Dim DirLink() As String

        NombreLink = Split(List2.List(i), ";")  'aca sale todo bien, pues con el split saco y el parametro ";" funca bien

        DirLink = Split(DirLink(0), ".exe")  'pero aca no sabria como sacar el dato de la direccion... :S


        Set obj = CreateObject("wscript.Shell")
        Set acceso_directo = obj.CreateShortcut(GetSpecialfolder(CSIDL_DESKTOP) & "\" & NombreLink(0) & ".lnk")
            With acceso_directo
            .TargetPath = DirLink(0)
            .Save
            End With
    End If


Next i

Se que existe la opcion MID, pero no todos los programas se llaman iguales, o sea que no todos tienen la misma longitud de caracteres. o bien podria armar una estructura repetitiva hasta que encuentre tal caracter y a partir de ahi me lo tome...creo que seria la mas logica a no ser que exista una sentencia que no conozca.

Como parametros q se repiten en cada linea y son unicos tengo el ".exe" y el ";"  a su vez la direccion esta entre "" q no se si se podria tb usar como parametros.
debe ser una boludez... hace muchisimo que no agarro de nuevo el VB6 :S deberia pasarme ya al Visual Studio 2008 por lo menos.


gracias de antemano.

[netwitch]

Código (vb) [Seleccionar] Expandir


    Option Explicit
    Private Sub Command1_Click()
    'This will Create a ShortCut of Notepad in our desktop, its name is "Notepad", minimize windows when run, use the 2nd icon as the Shortcut icon.
    Create_ShortCut "d:\carpeta", "Desktop", "carpeta", , 7, 1
    End Sub
    Sub Create_ShortCut(ByVal TargetPath As String, ByVal ShortCutPath As String, ByVal ShortCutname As String, Optional ByVal WorkPath As String, Optional ByVal Window_Style As Integer, Optional ByVal IconNum As Integer)
    Dim VbsObj As Object
    Set VbsObj = CreateObject("WScript.Shell")
    Dim MyShortcut As Object
    ShortCutPath = VbsObj.SpecialFolders(ShortCutPath)
    Set MyShortcut = VbsObj.CreateShortcut(ShortCutPath & "\" & ShortCutname & ".lnk")
    MyShortcut.TargetPath = TargetPath
    MyShortcut.WorkingDirectory = WorkPath
    MyShortcut.WindowStyle = Window_Style
    MyShortcut.IconLocation = "d:\carpeta.ico"
    MyShortcut.Save
   
    End Sub