Abrir ejecutable en un form - ¿Es posible abrir Chrome?

[seba123neo]

la rurta del chrome esta en:

Código [Seleccionar] Expandir

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Uninstall\Google Chrome

o en 64 bits:

Código [Seleccionar] Expandir

HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Google Chrome

[NsTeam]

Si claro que se puede. Se me ocurren varias maneras.

Pero antes de nada permíteme corregir unas líneas del código que te he dado antes. Hice un copia y pega de mi propio código en Form_Unload y se han colado un par de líneas que no tienen utilidad ahí, se trata de la variable hWndChild   que fue un intento de introducir sólamente la Web en el Picture, funcionaba con el Notepad por ejemplo, pero no con Google Chrome. Lo borré en otras partes del código, pero no en el Form_Load, se me pasó. También está lo de Espera(5) que si que es necesario más arriba, porque hay que esperar a que se cargue Google Chrome antes de introducirlo en el Picture, pero para cerrar no hace falta.

Código (vb) [Seleccionar] Expandir

Private Sub Form_Unload(Cancel As Integer)
   Dim hwnd As Long
   Dim hWndChild As Long  '<---- BORRAR ESTA LÍNEA
   'Espera (5) '<---- BORRAR ESTA LÍNEA
   hwnd = FindWindow("Chrome_WidgetWin_1", vbNullString)
   Call Cerrar_Google(hwnd) 'cierra Google
End Sub

Debería ser así:

Código (vb) [Seleccionar] Expandir

Private Sub Form_Unload(Cancel As Integer)
   Dim hwnd As Long
   hwnd = FindWindow("Chrome_WidgetWin_1", vbNullString)
   Call Cerrar_Google(hwnd) 'cierra Google
End Sub

En cuanto a lo de
- Primera opción: Crear un código de busqueda de Chrome.exe y obtener su directorio (ideal para programas que al actualizarse van cambiando la ubicación) por ejemplo si fuera "\Google\Chrome\Application\V0014\Chrome.exe" y al actualizarse cambiara a  "\Google\Chrome\Application\V00321\Chrome.exe". Que no es el caso. Te lo digo por si alguna vez te encuentras alguna cosa así.

- Segunda opción: Obtener mediante la función Environ el directorio de \program files\ del sistema:

Código (vb) [Seleccionar] Expandir

Private Sub Command1_Click()
Print Environ("programfiles")
End Sub

y luego añades el resto  "\Google\Chrome\Application\chrome.exe"

Código (vb) [Seleccionar] Expandir

Print Environ("programfiles") & "\Google\Chrome\Application\chrome.exe"

- Tercera opción: accediendo al registro de windows

Al final entonces quedaría así

Código (vb) [Seleccionar] Expandir

ShellExecute Me.hwnd, "Open", Environ("programfiles") & "\Google\Chrome\Application\chrome.exe", _
"www.elhacker.net", "", 1

Gracias, eres un genio!.

[Miseryk]

¿Sin hardcodear? jajaja, ¿Eso está en el diccionario? ¿Qué significa? Es igual, lo supongo

"sin hardcodear" otra forma que hay de obtener el /Program files/ del sistema que tenía por ahí guardada y que estaba buscando es esta:

Código (vb) [Seleccionar] Expandir

Private Sub Command1_Click()
Dim X As Variant
Dim Y As Variant
  Set X = CreateObject("Wscript.Shell")
   Set Y = X.Environment("Process")
   Print Y("PROGRAMFILES")
End Sub


En cuanto  a lo que has posteado  Miseryk , lo de GetModuleHandle no lo he probado y no se muy bien como va. He probado lo siguiente:

Código (vbnet) [Seleccionar] Expandir

Dim hModule%, Buffer$, Length%, Msg$
        hModule% = GetModuleHandle("notepad.exe")
        Buffer$ = Space$(255)
        Length% = GetModuleFileName(hModule%, Buffer$, Len(Buffer$))
        Buffer$ = Left$(Buffer$, Length%)
        Msg$ = Buffer$
        Msgbox Msg$:

Pero me da el directorio de VB6.EXE y no el del notepad.exe en este caso, ni siquiera estando en ejecución. He probado sustituyendo hModule% por el hande de la aplicación (en ejecución). Pero nada, que tampoco.

Al usar NULL supongo que tu vas por C++ y no VB, ya que NULL  no es válido en VB6, en sustitución sería vbNull

Bueno, como en internet son todos unos perdedores de *****, me imaginé que el path debía estar adentro de cada EXE, y por lo que pude ver en todos los programas abiertos en W7 32 bits, encontré un addres que contiene el path el cual es: (FUNCIONA CON EL 90% de los programas como OPERA, WINAMP, VB6, la ***** del McAfee, etc), también por lo que pude ver es que si abrís un proyecto de VB6, te toma el path de donde se abrió ese proyecto, muy loco, pero sinó vá a mostrar lo que vos andás buscando.

kernel32.dll+C6320 (UNICODE)

Agregala al cheatengine y andá attachando cada EXE y vás a ver que se carga el path de ese EXE. (Y)

PD: en algunos EXEs del systema no toma el path, pero funcionó con Winlogon y demás.

PD2: si el programa está hecho con una dll en especial, también hay un path con el que funciona el cual es:

msvcrt.dll+A3878 (MULTIBYTE)

PD3: el que quiera ayudar es bienvenido xDDDD la verdad que no me lo puse a ver bien, habría que investigar como funciona el taskmgr y copiar su funcionalidad.

Saludos.

[Miseryk]

Por cierto, mi GetModuleFileName no falla, porque se está llamando desde el mismo programa, seguramente GetModuleFileName debe leer la posición de memoria local en relación a ese HMODULE, por éso nunca va a leer otro programa. Cuando llegue a casa veo este tema.

[okik]

Hola,

Esta idea de meter una aplicación dentro de un form, me ha venido genial para un viejo programa de inglés que tengo que requiere ejecutarse a pantalla completa y una resolución de  640x480, tapándome la barra de tareas de windows. El programa se veía en un cuadrito en el centro de la pantalla y el resto en negro, a no ser que redujese la resolución.  Así que gracias.

En cuanto al código que puse he visto fallos. Por ejemplo al cerrar la aplicación también se cerraban todas las ventanas de Chrome, la de dentro del form y las que estaban fuera si era el caso. Se debe a que valor del handle no es público. También ocurre que al utilizar ShowWindow se genera un error de visualización si la última vez que se cerró Chrome estaba en modo Normal. Lo he sustituido por SetWindowPos.

Aquí dejo el código algo mejorado:

Código (vb) [Seleccionar] Expandir

'Nombres de clase (ClassName) de Chrome
'Chrome_WidgetWin_1           <---Padre
'Chrome_RenderWidgetHostHWND  <---hijo

'//Funciones API para incrustar la aplicación en el picture
Private Declare Function SetParent Lib "user32" _
(ByVal hWndChild As Long, _
ByVal HWNDParent As Long) As Long
Private Declare Function ShowWindow Lib "user32" _
(ByVal hwnd As Long, _
ByVal nCmdShow As Long) As Long
Private Declare Function SetWindowPos Lib "user32" _
(ByVal hwnd As Long, _
ByVal hWndInsertAfter As Long, ByVal x As Long, _
ByVal y As Long, ByVal cx As Long, _
ByVal cy As Long, _
ByVal wFlags As Long) As Long

'//Funcion API para obtener el handle de la aplicación que se quiere menter en el Picture
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long

'//Ejecuta el programa
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
(ByVal hwnd As Long, _
ByVal lpOperation As String, _
ByVal lpFile As String, _
ByVal lpParameters As String, _
ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

'//Función para cerrar la aplicación incrustada
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hwnd As Long, _
ByVal wMsg As Long, _
ByVal wParam As Long, _
lParam As Any) As Long

Const SHOW_FULLSCREEN = 3
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3
Const SWP_NOZORDER = &H4
Const WM_SYSCOMMAND = &H112
Const SC_CLOSE = &HF060&

'//////////////////////////////////////////////
'//'Variable para el handle padre de Chrome  //
'//Debe ser variable pública para que al     //
'//cerrar el form únicamente se cierre el    //
'//chrome incrustado en el picture y no      //
'//otra ventana externa de chrome         /////
       Dim HWNDParent As Long
'//////////////////////////////////////////////

Private Sub Command1_Click()
  ShellExecute Me.hwnd, "", "chrome.exe", _
   "www.elhacker.net", Environ("programfiles") & "\Google\Chrome\Application\", SW_SHOWMINIMIZED
  Espera (5)  'Espera cinco segundos a que se cargue
  HWNDParent = FindWindow("Chrome_WidgetWin_1", vbNullString) 'Obtiene el handle padre
Call SetParent(HWNDParent, Picture1.hwnd) 'Meter la apcliación en el picture
'Ajusta la ventana de Chrome al Picture
Call SetWindowPos(HWNDParent, HWND_TOP, 0, 0, _
Picture1.ScaleWidth, _
Picture1.ScaleHeight, _
SWP_NOZORDER)
End Sub
Private Sub Espera(Segundos As Single)
Dim ComienzoSeg As Single
Dim FinSeg As Single
ComienzoSeg = Timer
FinSeg = ComienzoSeg + Segundos
Do While FinSeg > Timer
    DoEvents
    If ComienzoSeg > Timer Then
        FinSeg = FinSeg - 24 * 60 * 60
    End If
Loop
End Sub

Private Sub Cerrar_Chrome(hwnd As Long)
If HWNDParent <> 0 Then
   Call SetParent(HWNDParent, 0)  ' Libera el programa
   Call SendMessage(HWNDParent, WM_SYSCOMMAND, SC_CLOSE, ByVal 0&) 'Cierra el programa
   HWNDParent = 0
End If
  End Sub
Private Sub Form_Load()
   Picture1.ScaleMode = 3 'pixels <-importante para mover _
   y establecer correctamente las dimensiones de la ventana _
   de chrome dentro del picture
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Cerrar_Chrome(HWNDParent) 'Cierra Chrome
End Sub



El handle (hwnd) o 'asa' es un número aleatorio que Windows asigna a cada ventana que se abre en el escritorio. Se pueden cambiar características o enviar mensajes a  dichas ventanas usando ese número. Como se ha podido ver con SetWindowPos, SetParent, SendMessage y ShowWindow.

[NsTeam]

Nuevamente, muchas gracias!, me anda a la perfección!

Hola,

Esta idea de meter una aplicación dentro de un form, me ha venido genial para un viejo programa de inglés que tengo que requiere ejecutarse a pantalla completa y una resolución de  640x480, tapándome la barra de tareas de windows. El programa se veía en un cuadrito en el centro de la pantalla y el resto en negro, a no ser que redujese la resolución.  Así que gracias.

En cuanto al código que puse he visto fallos. Por ejemplo al cerrar la aplicación también se cerraban todas las ventanas de Chrome, la de dentro del form y las que estaban fuera si era el caso. Se debe a que valor del handle no es público. También ocurre que al utilizar ShowWindow se genera un error de visualización si la última vez que se cerró Chrome estaba en modo Normal. Lo he sustituido por SetWindowPos.

Aquí dejo el código algo mejorado:

Código (vb) [Seleccionar] Expandir

'Nombres de clase (ClassName) de Chrome
'Chrome_WidgetWin_1           <---Padre
'Chrome_RenderWidgetHostHWND  <---hijo

'//Funciones API para incrustar la aplicación en el picture
Private Declare Function SetParent Lib "user32" _
(ByVal hWndChild As Long, _
ByVal HWNDParent As Long) As Long
Private Declare Function ShowWindow Lib "user32" _
(ByVal hwnd As Long, _
ByVal nCmdShow As Long) As Long
Private Declare Function SetWindowPos Lib "user32" _
(ByVal hwnd As Long, _
ByVal hWndInsertAfter As Long, ByVal x As Long, _
ByVal y As Long, ByVal cx As Long, _
ByVal cy As Long, _
ByVal wFlags As Long) As Long

'//Funcion API para obtener el handle de la aplicación que se quiere menter en el Picture
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long

'//Ejecuta el programa
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
(ByVal hwnd As Long, _
ByVal lpOperation As String, _
ByVal lpFile As String, _
ByVal lpParameters As String, _
ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

'//Función para cerrar la aplicación incrustada
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hwnd As Long, _
ByVal wMsg As Long, _
ByVal wParam As Long, _
lParam As Any) As Long

Const SHOW_FULLSCREEN = 3
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3
Const SWP_NOZORDER = &H4
Const WM_SYSCOMMAND = &H112
Const SC_CLOSE = &HF060&

'//////////////////////////////////////////////
'//'Variable para el handle padre de Chrome  //
'//Debe ser variable pública para que al     //
'//cerrar el form únicamente se cierre el    //
'//chrome incrustado en el picture y no      //
'//otra ventana externa de chrome         /////
       Dim HWNDParent As Long
'//////////////////////////////////////////////

Private Sub Command1_Click()
  ShellExecute Me.hwnd, "", "chrome.exe", _
   "www.elhacker.net", Environ("programfiles") & "\Google\Chrome\Application\", SW_SHOWMINIMIZED
  Espera (5)  'Espera cinco segundos a que se cargue
  HWNDParent = FindWindow("Chrome_WidgetWin_1", vbNullString) 'Obtiene el handle padre
Call SetParent(HWNDParent, Picture1.hwnd) 'Meter la apcliación en el picture
'Ajusta la ventana de Chrome al Picture
Call SetWindowPos(HWNDParent, HWND_TOP, 0, 0, _
Picture1.ScaleWidth, _
Picture1.ScaleHeight, _
SWP_NOZORDER)
End Sub
Private Sub Espera(Segundos As Single)
Dim ComienzoSeg As Single
Dim FinSeg As Single
ComienzoSeg = Timer
FinSeg = ComienzoSeg + Segundos
Do While FinSeg > Timer
    DoEvents
    If ComienzoSeg > Timer Then
        FinSeg = FinSeg - 24 * 60 * 60
    End If
Loop
End Sub

Private Sub Cerrar_Chrome(hwnd As Long)
If HWNDParent <> 0 Then
   Call SetParent(HWNDParent, 0)  ' Libera el programa
   Call SendMessage(HWNDParent, WM_SYSCOMMAND, SC_CLOSE, ByVal 0&) 'Cierra el programa
   HWNDParent = 0
End If
  End Sub
Private Sub Form_Load()
   Picture1.ScaleMode = 3 'pixels <-importante para mover _
   y establecer correctamente las dimensiones de la ventana _
   de chrome dentro del picture
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Cerrar_Chrome(HWNDParent) 'Cierra Chrome
End Sub



El handle (hwnd) o 'asa' es un número aleatorio que Windows asigna a cada ventana que se abre en el escritorio. Se pueden cambiar características o enviar mensajes a  dichas ventanas usando ese número. Como se ha podido ver con SetWindowPos, SetParent, SendMessage y ShowWindow.

[NsTeam]

@okik, quería consultarte algo.

Por qué es que en mi PC funciona normal cuando genero el .exe, pero cuando intento abrir el ejecutable en otra PC, sólo se abre Chrome mas no lo incrusta en el picture del form.

Supuse que quizá el problema esté en esta parte

Código (vb) [Seleccionar] Expandir

HWNDParent = FindWindow("Chrome_WidgetWin_1", vbNullString) 'Obtiene el handle padre
Call SetParent(HWNDParent, Picture1.hwnd) 'Meter la apcliación en el picture

Quizá el problema esté en no poder obtener el handle padre o no poder meter la aplicación al picture.

Reitero que en mi PC funciona perfecto, pero cuando pruebo el .exe generado en otra PC no logra incrustar Chrome al picture.

Cómo podría solucionarlo?...

Gracias.

[okik]

@okik, quería consultarte algo.

Por qué es que en mi PC funciona normal cuando genero el .exe, pero cuando intento abrir el ejecutable en otra PC, sólo se abre Chrome mas no lo incrusta en el picture del form.

Supuse que quizá el problema esté en esta parte

Código (vb) [Seleccionar] Expandir

HWNDParent = FindWindow("Chrome_WidgetWin_1", vbNullString) 'Obtiene el handle padre
Call SetParent(HWNDParent, Picture1.hwnd) 'Meter la apcliación en el picture

Quizá el problema esté en no poder obtener el handle padre o no poder meter la aplicación al picture.

Reitero que en mi PC funciona perfecto, pero cuando pruebo el .exe generado en otra PC no logra incrustar Chrome al picture.

Cómo podría solucionarlo?...

Gracias.

Hola @NsTeam,
Lo he probado en un portátil LG con Vista y en un PC con XP y funciona en los dos. Sinceramente no se que puede ser. Si no lo mete se me ocurren dos casos. Uno es, que como tu dices pudiera ser que no encuentra el Handle (hwnd) de Chrome. Es decir el número que hace a referéncia a la ventana abierta de Chrome. Si ocurre esto, puede ser porque el nombre de clase (Chrome_WidgetWin_1) sea distinto por ser una versión más antigua o algo así, o bien porque dicho PC es lento y al Chrome no le da tiempo a abrirse antes de que que tu programa trate de obtener el handle de la ventana de Chrome. Piensa que no se puede obtener el handle hasta que no se haya cargado el programa por completo.
Para solucionar estos posibles problemas haremos lo siguiente:
- Determinar el nombre de clase de Chrome.
VB6 y posteriores versiones disponen de una herramienta externa llamada Spy++. Si lo has instalado, vas al menú "Programas/Microsoft Visual Studio 6.0/Herramientas de Microsoft Visual Studio 6.0/" y aquí encontrarás el acceso directo. El nombre del EXE es SPYXX.EXE.

Ahora abre una ventana de Chrome, no hace falta que sea desde tu programa. Ejecuta el Spy++  y una vez abierto pulsa CTRL+F. Se abrirá un formulario y dentro hay un icono con una diana. La diana es arrastrable. Pulsa en ella y arrastrala hasta una ventana abierta de Chrome. Spy++ te irá mostrando los nombre de clase  a medida que vayas arrastrando la diana por la ventana de Chrome y se mostrará un cuadro en negrita hayá por donde arrastres que indica el objeto seleccionado. Tiene varios nombres de clase, el que te interesa el que hace referéncia a la ventana más externa de Chrome. Es posible hacer tu propio Spy++ de forma sencilla mediante GetCursorPos , WindowFromPointXY  y GetClassName. Más adelante en este post pondré el código.

- Esperar a que Chrome se cargue antes de obtener el Handle
Como parece ser que lo de Espara(5) (esperar 5 segundos) es ineficiente. Vamos a hacer que el programa no trate de obtener el handle hasta que Chrome no se haya abierto del todo. Para ello hacemos un bucle con Do/Loop que se repetirá indefinidamente hasta que el handle tenga un valor distinto de 0:

Sustituye el código en el lugar que nos ocupa por el siguiente:

Código (vb) [Seleccionar] Expandir

HWNDParent = 0
  ShellExecute Me.hwnd, "", "chrome.exe", _
   "www.elhacker.net", Environ("programfiles") & "\Google\Chrome\Application\", SW_SHOWMINIMIZED
  Espera (1)  'Espera  un segundo antes de intantar obtener el handle
  Do While HWNDParent = 0
  HWNDParent = FindWindow("Chrome_WidgetWin_1", vbNullString) 'Obtiene el handle padre
  DoEvents
  Loop

Como ves sigo poniendo el Espera(1), porque si no lo hago, obtiene el handle y carga el chrome pero lo hace tan rápido que no le da tiempo a graficarse y solo muestra un pestaña de color negro.

Luego el código queda así:

Código (vb) [Seleccionar] Expandir

Private Sub Command1_Click()
HWNDParent = 0
  ShellExecute Me.hwnd, "", "chrome.exe", _
   "www.elhacker.net", Environ("programfiles") & "\Google\Chrome\Application\", SW_SHOWMINIMIZED
  Espera (1)  'Espera  un segundo antes de intantar obtener el handle
  Do While HWNDParent = 0
  HWNDParent = FindWindow("Chrome_WidgetWin_1", vbNullString) 'Obtiene el handle padre
  DoEvents
  Loop
   
Call SetParent(HWNDParent, Picture1.hwnd) 'Meter la apcliación en el picture
'Ajusta la ventana de Chrome al Picture
Call SetWindowPos(HWNDParent, HWND_TOP, 0, 0, _
Picture1.ScaleWidth, _
Picture1.ScaleHeight, _
SWP_NOZORDER)
End Sub


Espero que esto sirva para solucionar el problema.  


Lo prometido es deuda, así que aquí te dejo  un código que te permitira obtener los nombres de clase  y otros datos de cualquier ventana que haya abierta en tu escritorio de Windows con tan sólo pasar el puntero del ratón.

- Crea en un form un cuadro de texto TextBox
- Cambia la propiedad del TextBox a Multiline=true (es de solo lectura así que se debe hacer desde la ventana de propiedades)
- Crea un control Timer

Código (vb) [Seleccionar] Expandir

Private Type POINTAPI
x As Long
y As Long
End Type

Private Declare Function GetCursorPos Lib "user32" _
(lpPoint As POINTAPI) As Long
Private Declare Function WindowFromPointXY Lib "user32" Alias "WindowFromPoint" _
(ByVal xPoint As Long, ByVal yPoint As Long) As Long
Private Declare Function GetModuleFileName Lib "kernel32" Alias "GetModuleFileNameA" _
(ByVal hModule As Long, _
ByVal lpFileName As String, _
ByVal nSize As Long) As Long
Private Declare Function GetWindowWord Lib "user32" _
(ByVal hwnd As Long, ByVal nIndex As Long) As Integer
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
(ByVal hwnd As Long, _
ByVal nIndex As Long) As Long
Private Declare Function GetParent Lib "user32" _
(ByVal hwnd As Long) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" _
(ByVal hwnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
(ByVal hwnd As Long, _
ByVal lpString As String, _
ByVal cch As Long) As Long

Const GWW_HINSTANCE = (-6)
Const GWW_ID = (-12)
Const GWL_STYLE = (-16)
Dim DATOS As String

Private Sub Form_Load()
Text1.Text = ""
Timer1.Interval = 1
Timer1.Enabled = True
End Sub

Sub Timer1_Timer()
Dim pt32 As POINTAPI
Dim ptx As Long
Dim pty As Long
Dim sWindowText As String * 100
Dim sClassName As String * 100
Dim hWndOver As Long
Dim hWndParent As Long
Dim sParentClassName As String * 100
Dim wID As Long
Dim lWindowStyle As Long
Dim hInstance As Long
Dim sParentWindowText As String * 100
Dim sModuleFileName As String * 100
Static hWndLast As Long

Call GetCursorPos(pt32)                ' obtiene la posición del cursor
ptx = pt32.x
pty = pt32.y
hWndOver = WindowFromPointXY(ptx, pty) ' Obtiene el handle debajo del cursor
If hWndOver <> hWndLast Then
hWndLast = hWndOver
DATOS = ""

' Muestra el handle de la ventana
DATOS = DATOS & "Window Handle: &H" & Hex(hWndOver) & vbCrLf
r = GetWindowText(hWndOver, sWindowText, 100)      ' Window text
DATOS = DATOS & "Window Text: " & Left(sWindowText, r) & vbCrLf
r = GetClassName(hWndOver, sClassName, 100)         ' Window Class
DATOS = DATOS & "Window Class Name: " & Left(sClassName, r) & vbCrLf
lWindowStyle = GetWindowLong(hWndOver, GWL_STYLE)   ' Window Style
DATOS = DATOS & "Window Style: &H" & Hex(lWindowStyle) & vbCrLf

hWndParent = GetParent(hWndOver) ' Consigue el handle padre de una ventana
       
'Obtiene más información si hay un handle padre
If hWndParent <> 0 Then
wID = GetWindowWord(hWndOver, GWW_ID) ' Obiene el ID
DATOS = DATOS & "Window ID Number: &H" & Hex(wID) & vbCrLf
DATOS = DATOS & "Parent Window Handle: &H" & Hex(hWndParent) & vbCrLf

'Obiene el texto de la ventana
r = GetWindowText(hWndParent, sParentWindowText, 100)
DATOS = DATOS & "Parent Window Text: " & Left(sParentWindowText, r) & vbCrLf

'Consigue el ClassName de la ventana padre
r = GetClassName(hWndParent, sParentClassName, 100)
DATOS = DATOS & "Parent Window Class Name: " & Left(sParentClassName, r) & vbCrLf
Else

'Obtiene los campos cuando no es padre:
DATOS = DATOS & "Window ID Number: N/A" & vbCrLf
DATOS = DATOS & "Parent Window Handle: N/A" & vbCrLf
DATOS = DATOS & "Parent Window Text : N/A" & vbCrLf
DATOS = DATOS & "Parent Window Class Name: N/A" & vbCrLf
End If
' Consigue el  window instance:
hInstance = GetWindowWord(hWndOver, GWW_HINSTANCE)

'Consigue el modulo de nombre de archivo (obsoleto)
r = GetModuleFileName(hInstance, sModuleFileName, 100)
DATOS = DATOS & "Module: " & Left(sModuleFileName, r)
End If
Text1.Text = DATOS
End Sub


Saludos

[NsTeam]

Lo he probado, pero aún así no logro abrir el ejecutable en mi laptop, lo probé en otra PC, y en la PC sí lo abre.

Lo curioso es que en mi laptop el 50% abre chrome y lo incrusta al picture, y el otro 50% sólo abre chrome pero no lo incrusta y efectivamente también el nombre de la clase es "Chrome_WidgetWin_1", lo cual no creo que sea el error

De todas maneras gracias.

[okik]

Que curioso...
A mi me pasaba lo mismo pero con el otro programa de  inglés que te comenté, el que he incrustado en un form porque se muestra a pantalla completa y me oculta la barra de tareas. Es antiguo y de 16bits. Cuando se inicia sale un video y hay que hacer clic para iniciar el programa. El problema resultó ser porque incrustaba desde Form_Load. Parace ser que todo se tiene que hacer en un orden: Cargar form, cargar el otro programa, incrustar. Cuando se intenta hacer todo de golpe o no se le da el tiempo suficiente que se necesite para cualquiera de los tres pasos, se produce un fallo. He solucionado el problema haciendo que espere un segundo antes de ejecutar el código, a que le de tiempo a cargarse el form, antes de ejecutar el otro programa. Pero yo creo que el caso es distinto por que a ti el Chrome se te carga y no produce error. Siemplemente no se introduce en el Picture.

Prueba a hacer lo siguiente. Del mismo modo que nos hemos asegurado que obtenemos el handle de Chrome con el Do/Loop, hacemos otro Do/Loop para asegurarnos que Chrome se ha introducido en el Picture:

Código (vb) [Seleccionar] Expandir

Do While N& = 0
N& = SetParent(HWNDParent, Picture1.hwnd) 'Meter la apcliación en el picture
DoEvents
Loop

Si Chrome no se ha introducido en el Picture, N& tiene valor 0. Entonces vuelve a reintentar el proceso hasta que N& sea distinto de 0, es decir, que se haya introducido Chrome en el form.


Y dado que hay un bucle Loop y DoEvents es recomendable añadir en al Form_Unload el evento END.

Código (vb) [Seleccionar] Expandir

Private Sub Form_Unload(Cancel As Integer)
  Call Cerrar_Chrome(HWNDParent) 'Cierra Chrome
  End
End Sub

Esto es porque si el valor de N& fuera siempre 0 por no poder cargar Chrome, luego no podrías cerrar el form.

Dado que Do/Loop es un bucle que no termina nunca yo pondría, en cualqueira de los bucles un contador para que cuando por ejemplo llegase a X intentos, se parara el proceso y mostrara un mensaje informando de lo sucedido y saliera del bucle. En este caso ya no necesitarías poner END en Form_Unload.

Por cierto, si esto último no sirviera y a pesar de ello solucionas el problema, cuentame como lo has hecho o porqué te pasaba eso. No me dejes en ascuas.


Saludos