Añadir a Favoritos del panel de navegación del explorer

[Car0nte]

Buenas,

Estoy acabando una pequeña aplicación y como remate me gustaría poder añadirla a los favoritos del panel de navegación del explorer, no a la carpeta de favoritos de Windows sino a los favoritos que aparecen normalmente a la izquierda del explorador de Windows.

Es para una aplicación en NET, pero como supongo que se haga a través del registro o de donde sea y no encuentro absolutamente nada que no sea hacerlos desaparecer del explorador, posteo aquí porque imagino que pueda ser una solución común.

Saludos y gracias

[Eleкtro]

Hola

Las preguntas sobre .NET van en el subforo .NET.

Supongo que te refieres a las ubicaciones favoritas?:



No se hace mediante el registro, símplemente son accesos directos que se guardan en el directorio del perfil del usuario actual, en C:\Users\USUARIO\Links

Solo necesitas crear un acceso directo.

Te hice este ejemplo (en VB.NET) para crear un acceso directo de la aplicación actual en el directorio de los favoritos del panel de navegación:

Código (vbnet) [Seleccionar] Expandir

Imports System.IO

Public Class Form1

   ''' <summary>
   ''' La ruta del directorio del acceso directo que quieres crear.
   ''' </summary>
   ReadOnly ShortcutDir As String =
       Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.UserProfile), "Links")

   ''' <summary>
   ''' El nombre del archivo de acceso directo.
   ''' </summary>
   ReadOnly ShortcutName As String =
       "MyProgram.lnk"

   ReadOnly FileInfo As FileInfo =
       New FileInfo(Path.Combine(My.Application.Info.DirectoryPath(),
                                 Process.GetCurrentProcess().MainModule.ModuleName))

   Private Shadows Sub Load() Handles MyBase.Load

       Dim Shortcut As New ShortcutManager.ShortcutInfo

       With Shortcut

           .ShortcutFile = Path.Combine(ShortcutDir, ShortcutName)
           .Target = FileInfo.FullName
           .Arguments = Nothing
           .WorkingDir = FileInfo.DirectoryName
           .Description = "MyProgram"
           .Icon = FileInfo.FullName
           .IconIndex = 0
           .WindowState = ShortcutManager.ShortcutWindowState.Normal

       End With

       ShortcutManager.CreateShortcut(Shortcut)

   End Sub

End Class

...Usando el ayudante que escribí:

Código (vbnet) [Seleccionar] Expandir

' ***********************************************************************
' Author   : Elektro
' Modified : 02-16-2014
' ***********************************************************************
' <copyright file="ShortcutManager.vb" company="Elektro Studios">
'     Copyright (c) Elektro Studios. All rights reserved.
' </copyright>
' ***********************************************************************

#Region " Imports "

Imports System.Runtime.InteropServices
Imports System.Text
Imports System.IO

#End Region

#Region " ShortcutManager "

''' <summary>
''' Performs Shortcut related operations.
''' </summary>
Public Class ShortcutManager

#Region " Variables "

   Private Shared lnk As New ShellLink()
   Private Shared lnk_data As New WIN32_FIND_DATAW()

   Private Shared lnk_arguments As New StringBuilder(260)
   Private Shared lnk_description As New StringBuilder(260)
   Private Shared lnk_target As New StringBuilder(260)
   Private Shared lnk_workingdir As New StringBuilder(260)
   Private Shared lnk_iconpath As New StringBuilder(260)
   Private Shared lnk_iconindex As Integer = -1
   Private Shared lnk_hotkey As Short = -1
   Private Shared lnk_windowstate As ShortcutWindowState = ShortcutWindowState.Normal

#End Region

#Region " P/Invoke "

   <DllImport("shfolder.dll", CharSet:=CharSet.Auto)>
   Private Shared Function SHGetFolderPath(
          ByVal hwndOwner As IntPtr,
          ByVal nFolder As Integer,
          ByVal hToken As IntPtr,
          ByVal dwFlags As Integer,
          ByVal lpszPath As StringBuilder
   ) As Integer
   End Function

   <Flags()>
   Private Enum SLGP_FLAGS

       ''' <summary>
       ''' Retrieves the standard short (8.3 format) file name.
       ''' </summary>
       SLGP_SHORTPATH = &H1

       ''' <summary>
       ''' Retrieves the Universal Naming Convention (UNC) path name of the file.
       ''' </summary>
       SLGP_UNCPRIORITY = &H2

       ''' <summary>
       ''' Retrieves the raw path name.
       ''' A raw path is something that might not exist and may include environment variables that need to be expanded.
       ''' </summary>
       SLGP_RAWPATH = &H4

   End Enum

   <Flags()>
   Private Enum SLR_FLAGS

       ''' <summary>
       ''' Do not display a dialog box if the link cannot be resolved. When SLR_NO_UI is set,
       ''' the high-order word of fFlags can be set to a time-out value that specifies the
       ''' maximum amount of time to be spent resolving the link. The function returns if the
       ''' link cannot be resolved within the time-out duration. If the high-order word is set
       ''' to zero, the time-out duration will be set to the default value of 3,000 milliseconds
       ''' (3 seconds). To specify a value, set the high word of fFlags to the desired time-out
       ''' duration, in milliseconds.
       ''' </summary>
       SLR_NO_UI = &H1

       ''' <summary>
       ''' If the link object has changed, update its path and list of identifiers.
       ''' If SLR_UPDATE is set, you do not need to call IPersistFile::IsDirty to determine,
       ''' whether or not the link object has changed.
       ''' </summary>
       SLR_UPDATE = &H4

       ''' <summary>
       ''' Do not update the link information
       ''' </summary>
       SLR_NOUPDATE = &H8

       ''' <summary>
       ''' Do not execute the search heuristics
       ''' </summary>
       SLR_NOSEARCH = &H10

       ''' <summary>
       ''' Do not use distributed link tracking
       ''' </summary>
       SLR_NOTRACK = &H20

       ''' <summary>
       ''' Disable distributed link tracking.
       ''' By default, distributed link tracking tracks removable media,
       ''' across multiple devices based on the volume name.
       ''' It also uses the Universal Naming Convention (UNC) path to track remote file systems,
       ''' whose drive letter has changed.
       ''' Setting SLR_NOLINKINFO disables both types of tracking.
       ''' </summary>
       SLR_NOLINKINFO = &H40

       ''' <summary>
       ''' Call the Microsoft Windows Installer
       ''' </summary>
       SLR_INVOKE_MSI = &H80

   End Enum

   ''' <summary>
   ''' Stores information about a shortcut file.
   ''' </summary>
   Public Class ShortcutInfo

       ''' <summary>
       ''' Shortcut file full path.
       ''' </summary>
       Public Property ShortcutFile As String

       ''' <summary>
       ''' Shortcut Comment/Description.
       ''' </summary>
       Public Property Description As String

       ''' <summary>
       ''' Shortcut Target Arguments.
       ''' </summary>
       Public Property Arguments As String

       ''' <summary>
       ''' Shortcut Target.
       ''' </summary>
       Public Property Target As String

       ''' <summary>
       ''' Shortcut Working Directory.
       ''' </summary>
       Public Property WorkingDir As String

       ''' <summary>
       ''' Shortcut Icon Location.
       ''' </summary>
       Public Property Icon As String

       ''' <summary>
       ''' Shortcut Icon Index.
       ''' </summary>
       Public Property IconIndex As Integer

       ''' <summary>
       ''' Shortcut Hotkey combination.
       ''' Is represented as Hexadecimal.
       ''' </summary>
       Public Property Hotkey As Short

       ''' <summary>
       ''' Shortcut Hotkey modifiers.
       ''' </summary>
       Public Property Hotkey_Modifier As HotkeyModifiers

       ''' <summary>
       ''' Shortcut Hotkey Combination.
       ''' </summary>
       Public Property Hotkey_Key As Keys

       ''' <summary>
       ''' Shortcut Window State.
       ''' </summary>
       Public Property WindowState As ShortcutWindowState

       ''' <summary>
       ''' Indicates if the target is a file.
       ''' </summary>
       Public Property IsFile As Boolean

       ''' <summary>
       ''' Indicates if the target is a directory.
       ''' </summary>
       Public Property IsDirectory As Boolean

       ''' <summary>
       ''' Shortcut target drive letter.
       ''' </summary>
       Public Property DriveLetter As String

       ''' <summary>
       ''' Shortcut target directory name.
       ''' </summary>
       Public Property DirectoryName As String

       ''' <summary>
       ''' Shortcut target filename.
       ''' (File extension is not included in name)
       ''' </summary>
       Public Property FileName As String

       ''' <summary>
       ''' Shortcut target file extension.
       ''' </summary>
       Public Property FileExtension As String

   End Class

   ''' <summary>
   ''' Hotkey modifiers for a shortcut file.
   ''' </summary>
   <Flags()>
   Public Enum HotkeyModifiers As Short

       ''' <summary>
       ''' The SHIFT key.
       ''' </summary>
       SHIFT = 1

       ''' <summary>
       ''' The CTRL key.
       ''' </summary>
       CONTROL = 2

       ''' <summary>
       ''' The ALT key.
       ''' </summary>
       ALT = 4

       ''' <summary>
       ''' None.
       ''' Specifies any hotkey modificator.
       ''' </summary>
       NONE = 0

   End Enum

   ''' <summary>
   ''' The Window States for a shortcut file.
   ''' </summary>
   Public Enum ShortcutWindowState As Integer

       ''' <summary>
       ''' Shortcut Window is at normal state.
       ''' </summary>
       Normal = 1

       ''' <summary>
       ''' Shortcut Window is Maximized.
       ''' </summary>
       Maximized = 3

       ''' <summary>
       ''' Shortcut Window is Minimized.
       ''' </summary>
       Minimized = 7

   End Enum

   <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)>
   Private Structure WIN32_FIND_DATAW
       Public dwFileAttributes As UInteger
       Public ftCreationTime As Long
       Public ftLastAccessTime As Long
       Public ftLastWriteTime As Long
       Public nFileSizeHigh As UInteger
       Public nFileSizeLow As UInteger
       Public dwReserved0 As UInteger
       Public dwReserved1 As UInteger
       <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=260)>
       Public cFileName As String
       <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=14)>
       Public cAlternateFileName As String
   End Structure

   ''' <summary>
   ''' The IShellLink interface allows Shell links to be created, modified, and resolved
   ''' </summary>
   <ComImport(),
   InterfaceType(ComInterfaceType.InterfaceIsIUnknown),
   Guid("000214F9-0000-0000-C000-000000000046")>
   Private Interface IShellLinkW

       ''' <summary>
       ''' Retrieves the path and file name of a Shell link object.
       ''' </summary>
       Sub GetPath(<Out(), MarshalAs(UnmanagedType.LPWStr)>
                   ByVal pszFile As StringBuilder,
                   ByVal cchMaxPath As Integer,
                   ByRef pfd As WIN32_FIND_DATAW,
                   ByVal fFlags As SLGP_FLAGS)

       ''' <summary>
       ''' Retrieves the list of item identifiers for a Shell link object.
       ''' </summary>
       Sub GetIDList(ByRef ppidl As IntPtr)

       ''' <summary>
       ''' Sets the pointer to an item identifier list (PIDL) for a Shell link object.
       ''' </summary>
       Sub SetIDList(ByVal pidl As IntPtr)

       ''' <summary>
       ''' Retrieves the description string for a Shell link object.
       ''' </summary>
       Sub GetDescription(<Out(), MarshalAs(UnmanagedType.LPWStr)>
                          ByVal pszName As StringBuilder,
                          ByVal cchMaxName As Integer)

       ''' <summary>
       ''' Sets the description for a Shell link object.
       ''' The description can be any application-defined string.
       ''' </summary>
       Sub SetDescription(<MarshalAs(UnmanagedType.LPWStr)>
                          ByVal pszName As String)

       ''' <summary>
       ''' Retrieves the name of the working directory for a Shell link object.
       ''' </summary>
       Sub GetWorkingDirectory(<Out(), MarshalAs(UnmanagedType.LPWStr)>
                               ByVal pszDir As StringBuilder,
                               ByVal cchMaxPath As Integer)

       ''' <summary>
       ''' Sets the name of the working directory for a Shell link object.
       ''' </summary>
       Sub SetWorkingDirectory(<MarshalAs(UnmanagedType.LPWStr)>
                               ByVal pszDir As String)

       ''' <summary>
       ''' Retrieves the command-line arguments associated with a Shell link object.
       ''' </summary>
       Sub GetArguments(<Out(), MarshalAs(UnmanagedType.LPWStr)>
                        ByVal pszArgs As StringBuilder,
                        ByVal cchMaxPath As Integer)

       ''' <summary>
       ''' Sets the command-line arguments for a Shell link object.
       ''' </summary>
       Sub SetArguments(<MarshalAs(UnmanagedType.LPWStr)>
                        ByVal pszArgs As String)

       ''' <summary>
       ''' Retrieves the hot key for a Shell link object.
       ''' </summary>
       Sub GetHotkey(ByRef pwHotkey As Short)

       ''' <summary>
       ''' Sets a hot key for a Shell link object.
       ''' </summary>
       Sub SetHotkey(ByVal wHotkey As Short)

       ''' <summary>
       ''' Retrieves the show command for a Shell link object.
       ''' </summary>
       Sub GetShowCmd(ByRef piShowCmd As Integer)

       ''' <summary>
       ''' Sets the show command for a Shell link object.
       ''' The show command sets the initial show state of the window.
       ''' </summary>
       Sub SetShowCmd(ByVal iShowCmd As ShortcutWindowState)

       ''' <summary>
       ''' Retrieves the location (path and index) of the icon for a Shell link object.
       ''' </summary>
       Sub GetIconLocation(<Out(), MarshalAs(UnmanagedType.LPWStr)>
                           ByVal pszIconPath As StringBuilder,
                           ByVal cchIconPath As Integer,
                           ByRef piIcon As Integer)

       ''' <summary>
       ''' Sets the location (path and index) of the icon for a Shell link object.
       ''' </summary>
       Sub SetIconLocation(<MarshalAs(UnmanagedType.LPWStr)>
                           ByVal pszIconPath As String,
                           ByVal iIcon As Integer)

       ''' <summary>
       ''' Sets the relative path to the Shell link object.
       ''' </summary>
       Sub SetRelativePath(<MarshalAs(UnmanagedType.LPWStr)>
                           ByVal pszPathRel As String,
                           ByVal dwReserved As Integer)

       ''' <summary>
       ''' Attempts to find the target of a Shell link,
       ''' even if it has been moved or renamed.
       ''' </summary>
       Sub Resolve(ByVal hwnd As IntPtr,
                   ByVal fFlags As SLR_FLAGS)

       ''' <summary>
       ''' Sets the path and file name of a Shell link object
       ''' </summary>
       Sub SetPath(ByVal pszFile As String)

   End Interface

   <ComImport(), Guid("0000010c-0000-0000-c000-000000000046"),
   InterfaceType(ComInterfaceType.InterfaceIsIUnknown)>
   Private Interface IPersist

       <PreserveSig()>
       Sub GetClassID(ByRef pClassID As Guid)

   End Interface

   <ComImport(), Guid("0000010b-0000-0000-C000-000000000046"),
   InterfaceType(ComInterfaceType.InterfaceIsIUnknown)>
   Private Interface IPersistFile
       Inherits IPersist

       Shadows Sub GetClassID(ByRef pClassID As Guid)

       <PreserveSig()>
       Function IsDirty() As Integer

       <PreserveSig()>
       Sub Load(<[In](), MarshalAs(UnmanagedType.LPWStr)>
                pszFileName As String,
                dwMode As UInteger)

       <PreserveSig()>
       Sub Save(<[In](), MarshalAs(UnmanagedType.LPWStr)>
                pszFileName As String,
                <[In](), MarshalAs(UnmanagedType.Bool)>
                fRemember As Boolean)

       <PreserveSig()>
       Sub SaveCompleted(<[In](), MarshalAs(UnmanagedType.LPWStr)>
                         pszFileName As String)

       <PreserveSig()>
       Sub GetCurFile(<[In](), MarshalAs(UnmanagedType.LPWStr)>
                      ppszFileName As String)

   End Interface

   ' "CLSID_ShellLink" from "ShlGuid.h"
   <ComImport(),
   Guid("00021401-0000-0000-C000-000000000046")>
   Private Class ShellLink
   End Class

#End Region

#Region " Public Methods "

   ''' <summary>
   ''' Resolves the target of a shortcut.
   ''' If shortcut can't be resolved, an error message would be displayed.
   ''' This is usefull when the target path of a shortcut file is changed from a driveletter for example,
   ''' then the shortcut file need to be resolved before trying to retrieve the target path.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to resolve.
   ''' </param>
   ''' <param name="hwnd">
   ''' The new handle pointer that would be generated
   ''' for the window which should display the error message (if any).
   ''' </param>
   Public Shared Sub ResolveUi(ShortcutFile As String, hwnd As IntPtr)
       LoadShortcut(ShortcutFile)
       DirectCast(lnk, IShellLinkW).Resolve(hwnd, SLR_FLAGS.SLR_UPDATE)
   End Sub

   ''' <summary>
   ''' Resolves the target of a shortcut.
   ''' If shortcut can't be resolved, any error message would be displayed.
   ''' This is usefull when the target path of a shortcut file is changed from a driveletter for example,
   ''' then the shortcut file need to be resolved before trying to retrieve the target path.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to resolve.
   ''' </param>
   Public Shared Sub ResolveNoUi(ByVal ShortcutFile As String)
       LoadShortcut(ShortcutFile)
       DirectCast(lnk, IShellLinkW).Resolve(IntPtr.Zero, SLR_FLAGS.SLR_UPDATE Or SLR_FLAGS.SLR_NO_UI)
   End Sub

   ''' <summary>
   ''' Returns the description of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetDescription(ByVal ShortcutFile As String) As String
       LoadShortcut(ShortcutFile)
       lnk_description.Clear()
       DirectCast(lnk, IShellLinkW).GetDescription(lnk_description, lnk_description.Capacity)
       Return lnk_description.ToString()
   End Function

   ''' <summary>
   ''' Returns the Arguments of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetArguments(ByVal ShortcutFile As String) As String
       LoadShortcut(ShortcutFile)
       lnk_arguments.Clear()
       DirectCast(lnk, IShellLinkW).GetArguments(lnk_arguments, lnk_arguments.Capacity)
       Return lnk_arguments.ToString()
   End Function

   ''' <summary>
   ''' Returns the path and filename of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetFullPath(ByVal ShortcutFile As String) As String
       LoadShortcut(ShortcutFile)
       lnk_target.Clear()
       DirectCast(lnk, IShellLinkW).GetPath(lnk_target, lnk_target.Capacity, lnk_data, SLGP_FLAGS.SLGP_UNCPRIORITY)
       Return lnk_target.ToString()
   End Function

   ''' <summary>
   ''' Returns the working directory of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetWorkingDir(ByVal ShortcutFile As String) As String
       LoadShortcut(ShortcutFile)
       lnk_workingdir.Clear()
       DirectCast(lnk, IShellLinkW).GetWorkingDirectory(lnk_workingdir, lnk_workingdir.Capacity)
       Return lnk_workingdir.ToString()
   End Function

   ''' <summary>
   ''' Returns the Hotkey of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetHotkey(ByVal ShortcutFile As String) As Short
       LoadShortcut(ShortcutFile)
       lnk_hotkey = -1
       DirectCast(lnk, IShellLinkW).GetHotkey(lnk_hotkey)
       Return lnk_hotkey
   End Function

   ''' <summary>
   ''' Returns the Window State of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetWindowStyle(ByVal ShortcutFile As String) As ShortcutWindowState
       LoadShortcut(ShortcutFile)
       DirectCast(lnk, IShellLinkW).GetShowCmd(lnk_windowstate)
       Return lnk_windowstate
   End Function

   ''' <summary>
   ''' Returns the Icon location of a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   ''' <param name="IconIndex">
   ''' Optional Integer type variable to store the IconIndex.
   ''' </param>
   Public Shared Function GetIconLocation(ByVal ShortcutFile As String,
                                           Optional ByRef IconIndex As Integer = 0) As String
       LoadShortcut(ShortcutFile)
       lnk_iconpath.Clear()
       DirectCast(lnk, IShellLinkW).GetIconLocation(lnk_iconpath, lnk_iconpath.Capacity, IconIndex)
       Return lnk_iconpath.ToString()
   End Function

   ''' <summary>
   ''' Retrieves all the information about a shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Public Shared Function GetInfo(ByVal ShortcutFile As String) As ShortcutInfo

       ' Load Shortcut
       LoadShortcut(ShortcutFile)

       ' Clean objects
       Clean()

       ' Retrieve Shortcut Info
       DirectCast(lnk, IShellLinkW).GetDescription(lnk_description, lnk_description.Capacity)
       DirectCast(lnk, IShellLinkW).GetArguments(lnk_arguments, lnk_arguments.Capacity)
       DirectCast(lnk, IShellLinkW).GetPath(lnk_target, lnk_target.Capacity, lnk_data, SLGP_FLAGS.SLGP_UNCPRIORITY)
       DirectCast(lnk, IShellLinkW).GetWorkingDirectory(lnk_workingdir, lnk_workingdir.Capacity)
       DirectCast(lnk, IShellLinkW).GetIconLocation(lnk_iconpath, lnk_iconpath.Capacity, lnk_iconindex)
       DirectCast(lnk, IShellLinkW).GetHotkey(lnk_hotkey)
       DirectCast(lnk, IShellLinkW).GetShowCmd(lnk_windowstate)

       ' Return Shortcut Info
       Return New ShortcutInfo With {
           .ShortcutFile = ShortcutFile,
           .Description = lnk_description.ToString,
           .Arguments = lnk_arguments.ToString,
           .Target = lnk_target.ToString,
           .Icon = lnk_iconpath.ToString,
           .IconIndex = lnk_iconindex,
           .WorkingDir = lnk_workingdir.ToString,
           .Hotkey = Hex(lnk_hotkey),
           .Hotkey_Modifier = [Enum].Parse(GetType(HotkeyModifiers), GetHiByte(lnk_hotkey)),
           .Hotkey_Key = [Enum].Parse(GetType(Keys), GetLoByte(lnk_hotkey)),
           .WindowState = lnk_windowstate,
           .IsFile = File.Exists(lnk_target.ToString),
           .IsDirectory = Directory.Exists(lnk_target.ToString),
           .DriveLetter = lnk_target.ToString.Substring(0, 1),
           .DirectoryName = lnk_target.ToString.Substring(0, lnk_target.ToString.LastIndexOf("\")),
           .FileName = lnk_target.ToString.Split("\").LastOrDefault.Split(".").FirstOrDefault,
           .FileExtension = lnk_target.ToString.Split(".").LastOrDefault
       }

   End Function

   ''' <summary>
   ''' Creates a shortcut file.
   ''' </summary>
   ''' <param name="FilePath">
   ''' The filepath to create the shortcut.
   ''' </param>
   ''' <param name="Target">
   ''' The target file or directory.
   ''' </param>
   ''' <param name="WorkingDirectory">
   ''' The working directory os the shortcut.
   ''' </param>
   ''' <param name="Description">
   ''' The shortcut description.
   ''' </param>
   ''' <param name="Arguments">
   ''' The target file arguments.
   ''' This value only should be set when target is an executable file.
   ''' </param>
   ''' <param name="Icon">
   ''' The icon location of the shortcut.
   ''' </param>
   ''' <param name="IconIndex">
   ''' The icon index of the icon file.
   ''' </param>
   ''' <param name="HotKey_Modifier">
   ''' The hotkey modifier(s) which should be used for the hotkey combination.
   ''' <paramref name="HotkeyModifiers"/> can be one or more modifiers.
   ''' </param>
   ''' <param name="HotKey_Key">
   ''' The key used in combination with the <paramref name="HotkeyModifiers"/> for hotkey combination.
   ''' </param>
   ''' <param name="WindowState">
   ''' The Window state for the target.
   ''' </param>
   Public Shared Sub CreateShortcut(ByVal FilePath As String,
                                    ByVal Target As String,
                                    Optional ByVal WorkingDirectory As String = Nothing,
                                    Optional ByVal Description As String = Nothing,
                                    Optional ByVal Arguments As String = Nothing,
                                    Optional ByVal Icon As String = Nothing,
                                    Optional ByVal IconIndex As Integer = Nothing,
                                    Optional ByVal HotKey_Modifier As HotkeyModifiers = Nothing,
                                    Optional ByVal HotKey_Key As Keys = Nothing,
                                    Optional ByVal WindowState As ShortcutWindowState = ShortcutWindowState.Normal)

       ' Load Shortcut
       LoadShortcut(FilePath)

       ' Clean objects
       Clean()

       ' Set Shortcut Info
       DirectCast(lnk, IShellLinkW).SetPath(Target)

       DirectCast(lnk, IShellLinkW).SetWorkingDirectory(If(WorkingDirectory IsNot Nothing,
                                                           WorkingDirectory,
                                                           Path.GetDirectoryName(Target)))

       DirectCast(lnk, IShellLinkW).SetDescription(Description)
       DirectCast(lnk, IShellLinkW).SetArguments(Arguments)
       DirectCast(lnk, IShellLinkW).SetIconLocation(Icon, IconIndex)

       DirectCast(lnk, IShellLinkW).SetHotkey(If(HotKey_Modifier + HotKey_Key <> 0,
                                                 Convert.ToInt16(CInt(HotKey_Modifier & Hex(HotKey_Key)), 16),
                                                 Nothing))

       DirectCast(lnk, IShellLinkW).SetShowCmd(WindowState)

       DirectCast(lnk, IPersistFile).Save(FilePath, True)
       DirectCast(lnk, IPersistFile).SaveCompleted(FilePath)

   End Sub

   ''' <summary>
   ''' Creates a shortcut file.
   ''' </summary>
   ''' <param name="Shortcut">Indicates a ShortcutInfo object.</param>
   Public Shared Sub CreateShortcut(ByVal Shortcut As ShortcutInfo)

       CreateShortcut(Shortcut.ShortcutFile,
                      Shortcut.Target,
                      Shortcut.WorkingDir,
                      Shortcut.Description,
                      Shortcut.Arguments,
                      Shortcut.Icon,
                      Shortcut.IconIndex,
                      Shortcut.Hotkey_Modifier,
                      Shortcut.Hotkey_Key,
                      Shortcut.WindowState)

   End Sub

   ''' <summary>
   ''' Modifies the atributes of an existing shortcut file.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The existing .lnk file to modify.
   ''' </param>
   ''' <param name="Target">
   ''' The target file or directory.
   ''' </param>
   ''' <param name="WorkingDirectory">
   ''' The working directory os the shortcut.
   ''' </param>
   ''' <param name="Description">
   ''' The shortcut description.
   ''' </param>
   ''' <param name="Arguments">
   ''' The target file arguments.
   ''' This value only should be set when target is an executable file.
   ''' </param>
   ''' <param name="Icon">
   ''' The icon location of the shortcut.
   ''' </param>
   ''' <param name="IconIndex">
   ''' The icon index of the icon file.
   ''' </param>
   ''' <param name="HotKey_Modifier">
   ''' The hotkey modifier(s) which should be used for the hotkey combination.
   ''' <paramref name="HotkeyModifiers"/> can be one or more modifiers.
   ''' </param>
   ''' <param name="HotKey_Key">
   ''' The key used in combination with the <paramref name="HotkeyModifiers"/> for hotkey combination.
   ''' </param>
   ''' <param name="WindowState">
   ''' The Window state for the target.
   ''' </param>
   Public Shared Sub ModifyShortcut(ByVal ShortcutFile As String,
                                    Optional ByVal Target As String = Nothing,
                                    Optional ByVal WorkingDirectory As String = Nothing,
                                    Optional ByVal Description As String = Nothing,
                                    Optional ByVal Arguments As String = Nothing,
                                    Optional ByVal Icon As String = Nothing,
                                    Optional ByVal IconIndex As Integer = -1,
                                    Optional ByVal HotKey_Modifier As HotkeyModifiers = -1,
                                    Optional ByVal HotKey_Key As Keys = -1,
                                    Optional ByVal WindowState As ShortcutWindowState = -1)

       ' Load Shortcut
       LoadShortcut(ShortcutFile)

       ' Clean objects
       Clean()

       ' Retrieve Shortcut Info
       DirectCast(lnk, IShellLinkW).GetDescription(lnk_description, lnk_description.Capacity)
       DirectCast(lnk, IShellLinkW).GetArguments(lnk_arguments, lnk_arguments.Capacity)
       DirectCast(lnk, IShellLinkW).GetPath(lnk_target, lnk_target.Capacity, lnk_data, SLGP_FLAGS.SLGP_UNCPRIORITY)
       DirectCast(lnk, IShellLinkW).GetWorkingDirectory(lnk_workingdir, lnk_workingdir.Capacity)
       DirectCast(lnk, IShellLinkW).GetIconLocation(lnk_iconpath, lnk_iconpath.Capacity, lnk_iconindex)
       DirectCast(lnk, IShellLinkW).GetHotkey(lnk_hotkey)
       DirectCast(lnk, IShellLinkW).GetShowCmd(lnk_windowstate)

       ' Set Shortcut Info
       DirectCast(lnk, IShellLinkW).SetPath(If(Target IsNot Nothing,
                                               Target,
                                               lnk_target.ToString))

       DirectCast(lnk, IShellLinkW).SetWorkingDirectory(If(WorkingDirectory IsNot Nothing,
                                                           WorkingDirectory,
                                                           lnk_workingdir.ToString))

       DirectCast(lnk, IShellLinkW).SetDescription(If(Description IsNot Nothing,
                                                      Description,
                                                      lnk_description.ToString))

       DirectCast(lnk, IShellLinkW).SetArguments(If(Arguments IsNot Nothing,
                                                    Arguments,
                                                    lnk_arguments.ToString))

       DirectCast(lnk, IShellLinkW).SetIconLocation(If(Icon IsNot Nothing, Icon, lnk_iconpath.ToString),
                                                    If(IconIndex <> -1, IconIndex, lnk_iconindex))

       DirectCast(lnk, IShellLinkW).SetHotkey(If(HotKey_Modifier + HotKey_Key > 0,
                                                 Convert.ToInt16(CInt(HotKey_Modifier & Hex(HotKey_Key)), 16),
                                                 lnk_hotkey))

       DirectCast(lnk, IShellLinkW).SetShowCmd(If(WindowState <> -1,
                                                  WindowState,
                                                  lnk_windowstate))

       DirectCast(lnk, IPersistFile).Save(ShortcutFile, True)
       DirectCast(lnk, IPersistFile).SaveCompleted(ShortcutFile)


   End Sub

#End Region

#Region " Private Methods "

   ''' <summary>
   ''' Loads the shortcut object to retrieve information.
   ''' </summary>
   ''' <param name="ShortcutFile">
   ''' The shortcut file to retrieve the info.
   ''' </param>
   Private Shared Sub LoadShortcut(ByVal ShortcutFile As String)
       DirectCast(lnk, IPersistFile).Load(ShortcutFile, 0)
   End Sub

   ''' <summary>
   ''' Clean the shortcut info objects.
   ''' </summary>
   Private Shared Sub Clean()
       lnk_description.Clear()
       lnk_arguments.Clear()
       lnk_target.Clear()
       lnk_workingdir.Clear()
       lnk_iconpath.Clear()
       lnk_hotkey = -1
       lnk_iconindex = -1
   End Sub

   ''' <summary>
   ''' Gets the low order byte of a number.
   ''' </summary>
   Private Shared Function GetLoByte(ByVal Intg As Integer) As Integer
       Return Intg And &HFF&
   End Function

   ''' <summary>
   ''' Gets the high order byte of a number.
   ''' </summary>
   Private Shared Function GetHiByte(ByVal Intg As Integer) As Integer
       Return (Intg And &HFF00&) / 256
   End Function

#End Region

End Class

#End Region

[Car0nte]

JodX"#!@!!! xDDD

No se hace mediante el registro, símplemente son accesos directos que se guardan en el directorio del perfil del usuario actual, en C:\Users\USUARIO\Links

GRACIAS, de verdad... ERA EXACTAMENTE ESO LO QUE BUSCABA me estaba volviendo loco. Ayer me tire dos horas buscando en el registro, carpetas especiales, etc y no caí en los Links

Por eso postee en este foro en vez del de net o el específico de VB. Imagianaba que la solución estaba en el registro o en alguna carpeta, aunque siendo sincero ya había tirado la toalla con las carpetas especiales... se me pasó!

Gracias por el pedazo de código que te has marcado, No conocía esa forma de crear Shorcuts (lo copio con tu permiso) Yo tiraba de la shell de WS

Pego la función que cree por si a alguien le sirve:

Código (vbnet) [Seleccionar] Expandir

   Function CreadorAD(ByVal Directorio As String)

       Dim ScriptShell, DirectorioShell, EnlaceShell As Object

       Try

           ScriptShell = CreateObject("WScript.Shell")

           If Directorio = "Escritorio" Then

               Dim DirEscritorio As String = Environment.GetFolderPath(Environment.SpecialFolder.Desktop)

               DirectorioShell = DirEscritorio

           ElseIf Directorio = "Inicio" Then

               Dim DirInicio As String = Environment.GetFolderPath(Environment.SpecialFolder.StartMenu)

               DirectorioShell = DirInicio

           ElseIf Directorio = "Favoritos" Then

               Dim DirFavoritos As String = Environment.GetFolderPath(Environment.SpecialFolder.Favorites)

               DirectorioShell = DirFavoritos

           ElseIf Directorio = "FavoritosPanel" Then

               Dim DirUsuario As String = Environment.GetFolderPath(Environment.SpecialFolder.UserProfile)
               Dim DirLink1 As String = "\Links"

               If CompruebaDir(DirUsuario & DirLink1) = True Then

                   DirectorioShell = DirUsuario & DirLink1

               Else

                   DirLink1 = "\Vínculos"
                   DirectorioShell = DirUsuario & DirLink1

               End If

           ElseIf Directorio = "InicioWin" Then

               Dim DirInicioWin As String = Environment.GetFolderPath(Environment.SpecialFolder.UserProfile)

               DirectorioShell = DirInicioWin

           Else : DirectorioShell = Directorio

           End If

           If CompruebaArchivo(DirectorioShell & "\" & My.Application.Info.ProductName & ".lnk") = True Then

               MsgBox("El acceso directo que se pretende crear ya existe en " & DirectorioShell, _
                      MsgBoxStyle.Information)

               Return False
               Exit Function

           Else

               Dim Respuesta As MsgBoxResult

               Respuesta = MsgBox("A continuación se creará un acceso directo en " & DirectorioShell & _
                                  vbCrLf & vbCrLf & "¿Desea activar la ejecución mediante un a" & _
                                  "tajo?" & vbCrLf & "Esto significa que podrá llamar al Progr" & _
                                  "amador pulsando " & Chr(34) & "ALT + P" & Chr(34), _
                                  MsgBoxStyle.Question + MsgBoxStyle.YesNoCancel)

               If Not Respuesta = MsgBoxResult.Cancel Then


                   EnlaceShell = ScriptShell.CreateShortcut(DirectorioShell & "\" & My.Application.Info.ProductName & ".lnk")

                   EnlaceShell.TargetPath = Application.ExecutablePath
                   EnlaceShell.Description = My.Application.Info.ProductName
                   EnlaceShell.WindowStyle = 1

                   If Respuesta = MsgBoxResult.Yes Then EnlaceShell.Hotkey = "Alt+p"

                   EnlaceShell.Save()

                   If CompruebaArchivo(DirectorioShell & "\" & My.Application.Info.ProductName & ".lnk") = True Then

                       MsgBox("El acceso directo ha sido creado con éxito en " & DirectorioShell, _
                              MsgBoxStyle.Information, "Creación de acceso directo")

                   Else : MsgBox("Ocurrió un error durante el proceso" & vbCrLf & vbCrLf & _
                                 "El acceso directo no ha sido creado", MsgBoxStyle.Critical, _
                                 "Error")
                   End If
               Else

                   MsgBox("Se ha cancelado la creación del acceso directo en " & DirectorioShell, _
                          MsgBoxStyle.Information, "Operación cancelada")
                   Return False
                   Exit Function

               End If

           End If

       Catch ex As Exception

           MsgBox(ex.Message & vbCrLf & vbCrLf & "En caso de que requiera pemisos administrati" & _
                  "vos, consulte con el administrador del sistema", MsgBoxStyle.Critical, "Error")

       End Try

       Return True

   End Function


Las otras dos funciones citadas son:

Código (vbnet) [Seleccionar] Expandir

   Function CompruebaDir(ByVal Directorio As String, Optional ByVal Explicación As Boolean = False)

       If IO.Directory.Exists(Directorio) Then

           Return True

       Else

           Return False
           If Explicación = True Then MsgBox("El directorio especificado no existe", _
               MsgBoxStyle.Exclamation, "Comprobación directorio")

       End If

   End Function

   Function CompruebaArchivo(ByVal Archivo As String, Optional ByVal Explicación As Boolean = False)

           If IO.File.Exists(Archivo) Then

               Return True

           Else

               Return False
               If Explicación = True Then MsgBox("El archivo especificado no existe", _
                   MsgBoxStyle.Exclamation, "Comprobación Archivo")

           End If

   End Function

Saludos y GRACIAS

PD: Elektro, estoy probando tu código y me da problemas con ShortcutManager.ShortcutInfo Será cosa mía... echaré un vistazo en msdn. Has propocionado material para un buen rato

EDITADO:

Añadido "Links" a la función

EDITADO (2):

Añadidas correcciones

[Eleкtro]

La verdad es que si la intención es sólamente crear un shortcut pues no vale la pena añadir a tu proyecto una Class de 1.000 lineas de código y taladrarse la cabeza investigando en MSDN sobre esas interfaces y demás, lo típico es hacerlo como has mostrado tú, aunque prácticamente es lo mismo, pero el código lo escribí hace ya tiempo para manejar más que la creación de shortcuts, en realidad la idea fue resolver shortcuts y lo de la creación/modificación de shortcuts lo añadí como algo secundario y para evitar dependencias innecesarias de WScript.

PD: Elektro, estoy probando tu código y me da problemas con ShortcutManager.ShortcutInfo Será cosa mía... echaré un vistazo en msdn.

Me resulta extraño porque el miembro 'ShortcutInfo' sólamente es una Class con propiedades públicas,
en cada propiedad debes especificar los valores del shortcut que quieres crear (aunque algunas de las propiedades como 'IsFile' o 'IsFolder' no importa lo que pongas porque las uso para otros métodos) que luego toma el método 'CreateShortcut', al que le añadí un 'Overload' para poder pasarle un objeto 'ShortcutInfo', pero si te da problemas, en lugar de pasarle un 'ShortcutInfo' puedes pasarle todos los parámetros del shortcut de forma manual: Shortcutmanager.createshortcut("C:\Nuevo link.lnk", etc...)

No me imagino que tipo de problema te puede causar la Class 'ShortcutInfo' porque como ya digo son propiedades y nada más,
si quieres mostrar el código para ver de que forma lo estás utilizando y detallar la excepción/error de compilación o en tiempo de ejecución (si es que hubiera alguna excepción)...

un saludo!

[Car0nte]

Me resulta extraño porque el miembro 'ShortcutInfo' sólamente es una Class con propiedades públicas,
en cada propiedad debes especificar los valores del shortcut que quieres crear (aunque algunas de las propiedades como 'IsFile' o 'IsFolder' no importa lo que pongas porque las uso para otros métodos) que luego toma el método 'CreateShortcut', al que le añadí un 'Overload' para poder pasarle un objeto 'ShortcutInfo', pero si te da problemas, en lugar de pasarle un 'ShortcutInfo' puedes pasarle todos los parámetros del shortcut de forma manual: Shortcutmanager.createshortcut("C:\Nuevo link.lnk", etc...)

No me imagino que tipo de problema te puede causar la Class 'ShortcutInfo' porque como ya digo son propiedades y nada más,
si quieres mostrar el código para ver de que forma lo estás utilizando y detallar la excepción/error de compilación o en tiempo de ejecución (si es que hubiera alguna excepción)...

un saludo!

Probablemente el error sea mio. El equipo que uso habitualmente está en en el servicio tecnico. Éste tiene muchos Km y un montón de modificaciones y funciones capadas (por necesidad, experimentos y/o estupidez xD). En cuanto me traigan el otro probaré.

La verdad es que tu método promete .. no había leído nada sobre el tema. En buena parte es mejor mires por donde lo mires porque es algo nativo integrado por completo en NET.

Saludos