Mensajes

Busco automatizar el proceso, es decir, crearme una aplicación que agregue recursos a un EXE .NET

Voy a averiguar sobre ILMerge, si tienes algun info?.

Puedes recurrir a la ayuda integrada en la aplicación (por linea de comandos), o googlear la documentación de los parámetros de la aplicación en MSDN o Technet.
http://research.microsoft.com/en-us/people/mbarnett/ilmerge.aspx
(fíjate en el hyperlink del .doc que contiene la documentación)

Pero hay un detalle importante, se me olvidó que solo podrás "unir" ensamblados .Net, esa es su limitación, es decir, no podrás interactuar con otro tipo de archivos como un binario de C/C++ que tnega código nativo, o un archivo de texto plano, etc, o al menos eso tengo entendido por lo que especifica Microsoft, pero lo cierto es que nunca lo intenté.

Saludos

Buenas

Hola, quisiera ser moderador del foro, cuales son los requisitos??  

Si realmente quieres tener una mínima posibilidad de que alguien (cualquier persona) se tome en serio tu pregunta, entonces podrías empezar por reemplazar esa imagen gigantesca, desagradable e irrelevante, para expresar y dar a conocer algo sobre tí, empezando por las motivaciones que te hayan llevado a formular esa pregunta, así cómo tu temática favorita del foro (a la que aspires a moderar), tus conocimientos, etc, etc, etc. Lo que sea menos imágenes de South-Park .

PD: Lo digo para ayudar...

Saludos!

[ILMerge]

Si tienes el source del proyecto entonces puedes embedir directamente cualquier archivo a la compilación del exe desde la IDE:



Si no tienes el source, entonces puedes utilizar la herramienta command-line ILMerge de Microsoft, o la GUI ILMerge-GUI, o herramientas de pago cómo .Net Shrink.

Saludos

He desarrollado este snippet para administrar las capacidades de arrastrar (dragging) en tiempo de ejecución, de uno o varios Forms, extendiendo el control y la eficiencia de los típicos códigos "copy&paste" que se pueden encontrar por internet para llevar a cabo dicha tarea.

Ejemplos de uso:

Código (vbnet) [Seleccionar] Expandir

Public Class Form1

   ''' <summary>
   ''' The <see cref="FormDragger"/> instance that manages the form(s) dragging.
   ''' </summary>
   Private formDragger As FormDragger = FormDragger.Empty

   Private Sub Test() Handles MyBase.Shown
       Me.InitializeDrag()
   End Sub

   Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) _
   Handles Button1.Click

       Me.AlternateDragEnabled(Me)

   End Sub

   Private Sub InitializeDrag()

       ' 1st way, using the single-Form constructor:
       Me.formDragger = New FormDragger(Me, enabled:=True, cursor:=Cursors.SizeAll)

       ' 2nd way, using the multiple-Forms constructor:
       ' Me.formDragger = New FormDragger({Me, Form2, form3})

       ' 3rd way, using the default constructor then adding a Form into the collection:
       ' Me.formDragger = New FormDragger
       ' Me.formDragger.AddForm(Me, enabled:=True, cursor:=Cursors.SizeAll)

   End Sub

   ''' <summary>
   ''' Alternates the dragging of the specified form.
   ''' </summary>
   ''' <param name="form">The form.</param>
   Private Sub AlternateDragEnabled(ByVal form As Form)

       Dim formInfo As FormDragger.FormDragInfo = Me.formDragger.FindFormDragInfo(form)
       formInfo.Enabled = Not formInfo.Enabled

   End Sub

End Class

Source:

Código (vbnet) [Seleccionar] Expandir

' ***********************************************************************
' Author   : Elektro
' Modified : 15-March-2015
' ***********************************************************************
' <copyright file="FormDragger.vb" company="Elektro Studios">
'     Copyright (c) Elektro Studios. All rights reserved.
' </copyright>
' ***********************************************************************

#Region " Option Statements "

Option Explicit On
Option Strict On
Option Infer Off

#End Region

#Region " Usage Examples "

'Public Class Form1

'    ''' <summary>
'    ''' The <see cref="FormDragger"/> instance that manages the form(s) dragging.
'    ''' </summary>
'    Private formDragger As FormDragger = FormDragger.Empty

'    Private Sub Test() Handles MyBase.Shown
'        Me.InitializeDrag()
'    End Sub

'    Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) _
'    Handles Button1.Click

'        Me.AlternateDragEnabled(Me)

'    End Sub

'    Private Sub InitializeDrag()

'        ' 1st way, using the single-Form constructor:
'        Me.formDragger = New FormDragger(Me, enabled:=True, cursor:=Cursors.SizeAll)

'        ' 2nd way, using the multiple-Forms constructor:
'        ' Me.formDragger = New FormDragger({Me, Form2, form3})

'        ' 3rd way, using the default constructor then adding a Form into the collection:
'        ' Me.formDragger = New FormDragger
'        ' Me.formDragger.AddForm(Me, enabled:=True, cursor:=Cursors.SizeAll)

'    End Sub

'    ''' <summary>
'    ''' Alternates the dragging of the specified form.
'    ''' </summary>
'    ''' <param name="form">The form.</param>
'    Private Sub AlternateDragEnabled(ByVal form As Form)

'        Dim formInfo As FormDragger.FormDragInfo = Me.formDragger.FindFormDragInfo(form)
'        formInfo.Enabled = Not formInfo.Enabled

'    End Sub

'End Class

#End Region

#Region " Imports "

Imports System.ComponentModel

#End Region

#Region " Form Dragger "

''' <summary>
''' Enable or disable drag at runtime on a <see cref="Form"/>.
''' </summary>
Public NotInheritable Class FormDragger : Implements IDisposable

#Region " Properties "

   ''' <summary>
   ''' Gets an <see cref="IEnumerable(Of Form)"/> collection that contains the Forms capables to perform draggable operations.
   ''' </summary>
   ''' <value>The <see cref="IEnumerable(Of Form)"/>.</value>
   <EditorBrowsable(EditorBrowsableState.Always)>
   Public ReadOnly Property Forms As IEnumerable(Of FormDragInfo)
       Get
           Return Me.forms1
       End Get
   End Property
   ''' <summary>
   ''' An <see cref="IEnumerable(Of Form)"/> collection that contains the Forms capables to perform draggable operations.
   ''' </summary>
   Private forms1 As IEnumerable(Of FormDragInfo) = {}

   ''' <summary>
   ''' Represents a <see cref="FormDragger"/> instance that is <c>Nothing</c>.
   ''' </summary>
   ''' <value><c>Nothing</c></value>
   <EditorBrowsable(EditorBrowsableState.Always)>
   Public Shared ReadOnly Property Empty As FormDragger
       Get
           Return Nothing
       End Get
   End Property

#End Region

#Region " Types "

   ''' <summary>
   ''' Defines the draggable info of a <see cref="Form"/>.
   ''' </summary>
   <Serializable>
   Public NotInheritable Class FormDragInfo

#Region " Properties "

       ''' <summary>
       ''' Gets the associated <see cref="Form"/> used to perform draggable operations.
       ''' </summary>
       ''' <value>The associated <see cref="Form"/>.</value>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public ReadOnly Property Form As Form
           Get
               Return form1
           End Get
       End Property
       ''' <summary>
       ''' The associated <see cref="Form"/>
       ''' </summary>
       <NonSerialized>
       Private ReadOnly form1 As Form

       ''' <summary>
       ''' Gets the name of the associated <see cref="Form"/>.
       ''' </summary>
       ''' <value>The Form.</value>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public ReadOnly Property Name As String
           Get
               If Me.Form IsNot Nothing Then
                   Return Form.Name
               Else
                   Return String.Empty
               End If
           End Get
       End Property

       ''' <summary>
       ''' Gets or sets a value indicating whether drag is enabled on the associated <see cref="Form"/>.
       ''' </summary>
       ''' <value><c>true</c> if drag is enabled; otherwise, <c>false</c>.</value>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public Property Enabled As Boolean

       ''' <summary>
       ''' A <see cref="FormDragger"/> instance instance containing the draggable information of the associated <see cref="Form"/>.
       ''' </summary>
       ''' <value>The draggable information.</value>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Property DragInfo As FormDragger = FormDragger.Empty

       ''' <summary>
       ''' Gets or sets the <see cref="Cursor"/> used to drag the associated <see cref="Form"/>.
       ''' </summary>
       ''' <value>The <see cref="Cursor"/>.</value>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public Property Cursor As Cursor = Cursors.SizeAll

       ''' <summary>
       ''' Gets or sets the old form's cursor to restore it after dragging.
       ''' </summary>
       ''' <value>The old form's cursor.</value>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Property OldCursor As Cursor = Nothing

       ''' <summary>
       ''' Gets or sets the initial mouse coordinates, normally <see cref="Form.MousePosition"/>.
       ''' </summary>
       ''' <value>The initial mouse coordinates.</value>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Property InitialMouseCoords As Point = Point.Empty

       ''' <summary>
       ''' Gets or sets the initial <see cref="Form"/> location, normally <see cref="Form.Location"/>.
       ''' </summary>
       ''' <value>The initial location.</value>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Property InitialLocation As Point = Point.Empty

#End Region

#Region " Constructors "

       ''' <summary>
       ''' Initializes a new instance of the <see cref="FormDragInfo"/> class.
       ''' </summary>
       ''' <param name="form">The form.</param>
       Public Sub New(ByVal form As Form)
           Me.form1 = form
           Me.Cursor = form.Cursor
       End Sub

       ''' <summary>
       ''' Prevents a default instance of the <see cref="FormDragInfo"/> class from being created.
       ''' </summary>
       Private Sub New()
       End Sub

#End Region

#Region " Hidden Methods "

       ''' <summary>
       ''' Serves as a hash function for a particular type.
       ''' </summary>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Shadows Function GetHashCode() As Integer
           Return MyBase.GetHashCode
       End Function

       ''' <summary>
       ''' Gets the System.Type of the current instance.
       ''' </summary>
       ''' <returns>The exact runtime type of the current instance.</returns>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Shadows Function [GetType]() As Type
           Return MyBase.GetType
       End Function

       ''' <summary>
       ''' Determines whether the specified System.Object instances are considered equal.
       ''' </summary>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Shadows Function Equals(ByVal obj As Object) As Boolean
           Return MyBase.Equals(obj)
       End Function

       ''' <summary>
       ''' Determines whether the specified System.Object instances are the same instance.
       ''' </summary>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Private Shadows Sub ReferenceEquals()
       End Sub

       ''' <summary>
       ''' Returns a String that represents the current object.
       ''' </summary>
       <EditorBrowsable(EditorBrowsableState.Never)>
       Public Shadows Function ToString() As String
           Return MyBase.ToString
       End Function

#End Region

   End Class

#End Region

#Region " Constructors "

   ''' <summary>
   ''' Initializes a new instance of the <see cref="FormDragger"/> class.
   ''' </summary>
   Public Sub New()
       Me.forms1={}
   End Sub

   ''' <summary>
   ''' Initializes a new instance of the <see cref="FormDragger"/> class.
   ''' </summary>
   ''' <param name="form">The <see cref="Form"/> used to perform draggable operations.</param>
   ''' <param name="enabled">If set to <c>true</c>, enable dragging on the <see cref="Form"/>.</param>
   ''' <param name="cursor">The <see cref="Cursor"/> used to drag the specified <see cref="Form"/>.</param>
   Public Sub New(ByVal form As Form,
                  Optional enabled As Boolean = False,
                  Optional cursor As Cursor = Nothing)

       Me.forms1 =
           {
               New FormDragInfo(form) With
                        {
                            .Enabled = enabled,
                            .Cursor = cursor
                        }
           }

       Me.AssocHandlers(form)

   End Sub

   ''' <summary>
   ''' Initializes a new instance of the <see cref="FormDragger"/> class.
   ''' </summary>
   ''' <param name="forms">The <see cref="Forms"/> used to perform draggable operations.</param>
   Public Sub New(ByVal forms As IEnumerable(Of Form))

       Me.forms1 = (From form As Form In forms
                    Select New FormDragInfo(form)).ToArray

       For Each form As Form In forms
           Me.AssocHandlers(form)
       Next form

   End Sub

   ''' <summary>
   ''' Initializes a new instance of the <see cref="FormDragger"/> class.
   ''' </summary>
   ''' <param name="formInfo">
   ''' The <see cref="FormDragInfo"/> instance
   ''' that contains the <see cref="Form"/> reference and its draggable info.
   ''' </param>
   ''' <param name="mouseCoordinates">The current mouse coordinates.</param>
   ''' <param name="location">The current location.</param>
   Private Sub New(ByVal formInfo As FormDragInfo,
                   ByVal mouseCoordinates As Point,
                   ByVal location As Point)

       formInfo.InitialMouseCoords = mouseCoordinates
       formInfo.InitialLocation = location

   End Sub

#End Region

#Region " Public Methods "

   ''' <summary>
   ''' Adds the specified <see cref="Form"/> into the draggable <see cref="Forms"/> collection.
   ''' </summary>
   ''' <param name="form">The <see cref="Form"/>.</param>
   ''' <param name="enabled">If set to <c>true</c>, enable dragging on the <see cref="Form"/>.</param>
   ''' <param name="cursor">The <see cref="Cursor"/> used to drag the specified <see cref="Form"/>.</param>
   ''' <exception cref="System.ArgumentException">The specified form is already added.;form</exception>
   Public Function AddForm(ByVal form As Form,
                           Optional enabled As Boolean = False,
                           Optional cursor As Cursor = Nothing) As FormDragInfo

       For Each formInfo As FormDragInfo In Me.forms1

           If formInfo.Form.Equals(form) Then
               Throw New ArgumentException("The specified form is already added.", "form")
               Exit Function
           End If

       Next formInfo

       Dim newFormInfo As New FormDragInfo(form) With {.Enabled = enabled, .Cursor = cursor}
       Me.forms1 = Me.forms1.Concat({newFormInfo})
       Me.AssocHandlers(form)

       Return newFormInfo

   End Function

   ''' <summary>
   ''' Removes the specified <see cref="Form"/> from the draggable <see cref="Forms"/> collection.
   ''' </summary>
   ''' <param name="form">The form.</param>
   ''' <exception cref="System.ArgumentException">The specified form is not found.;form</exception>
   Public Sub RemoveForm(ByVal form As Form)

       Dim formInfoToRemove As FormDragInfo = Nothing

       For Each formInfo As FormDragInfo In Me.forms1

           If formInfo.Form.Equals(form) Then
               formInfoToRemove = formInfo
               Exit For
           End If

       Next formInfo

       If formInfoToRemove IsNot Nothing Then

           Me.forms1 = From formInfo As FormDragInfo In Me.forms1
                       Where Not formInfo Is formInfoToRemove

           formInfoToRemove.Enabled = False
           Me.DeassocHandlers(formInfoToRemove.Form)

       Else
           Throw New ArgumentException("The specified form is not found.", "form")

       End If

   End Sub

   ''' <summary>
   ''' Finds the <see cref="FormDragInfo"/> instance that is associated with the specified <see cref="Form"/> reference.
   ''' </summary>
   ''' <param name="form">The <see cref="Form"/>.</param>
   ''' <returns>The <see cref="FormDragInfo"/> instance that is associated with the specified <see cref="Form"/> reference.</returns>
   Public Function FindFormDragInfo(ByVal form As Form) As FormDragInfo

       Return (From formInfo As FormDragger.FormDragInfo In Me.forms1
               Where formInfo.Form Is form).FirstOrDefault

   End Function

   ''' <summary>
   ''' Finds the <see cref="FormDragInfo"/> instance that is associated with the specified <see cref="Form"/> reference.
   ''' </summary>
   ''' <param name="name">The <see cref="Form"/> name.</param>
   ''' <returns>The <see cref="FormDragInfo"/> instance that is associated with the specified <see cref="Form"/> reference.</returns>
   Public Function FindFormDragInfo(ByVal name As String,
                                    Optional stringComparison As StringComparison =
                                             StringComparison.OrdinalIgnoreCase) As FormDragInfo

       Return (From formInfo As FormDragger.FormDragInfo In Me.forms1
               Where formInfo.Name.Equals(name, stringComparison)).FirstOrDefault

   End Function

#End Region

#Region " Private Methods "

   ''' <summary>
   ''' Associates the <see cref="Form"/> handlers to enable draggable operations.
   ''' </summary>
   ''' <param name="form">The form.</param>
   Private Sub AssocHandlers(ByVal form As Form)

       AddHandler form.MouseDown, AddressOf Me.Form_MouseDown
       AddHandler form.MouseUp, AddressOf Me.Form_MouseUp
       AddHandler form.MouseMove, AddressOf Me.Form_MouseMove
       AddHandler form.MouseEnter, AddressOf Me.Form_MouseEnter
       AddHandler form.MouseLeave, AddressOf Me.Form_MouseLeave

   End Sub

   ''' <summary>
   ''' Deassociates the <see cref="Form"/> handlers to disable draggable operations.
   ''' </summary>
   ''' <param name="form">The form.</param>
   Private Sub DeassocHandlers(ByVal form As Form)

       If Not form.IsDisposed AndAlso Not form.Disposing Then

           RemoveHandler form.MouseDown, AddressOf Me.Form_MouseDown
           RemoveHandler form.MouseUp, AddressOf Me.Form_MouseUp
           RemoveHandler form.MouseMove, AddressOf Me.Form_MouseMove
           RemoveHandler form.MouseEnter, AddressOf Me.Form_MouseEnter
           RemoveHandler form.MouseLeave, AddressOf Me.Form_MouseLeave

       End If

   End Sub

   ''' <summary>
   ''' Return the new location.
   ''' </summary>
   ''' <param name="formInfo">
   ''' The <see cref="FormDragInfo"/> instance
   ''' that contains the <see cref="Form"/> reference and its draggable info.
   ''' </param>
   ''' <param name="mouseCoordinates">The current mouse coordinates.</param>
   ''' <returns>The new location.</returns>
   Private Function GetNewLocation(ByVal formInfo As FormDragInfo,
                                   ByVal mouseCoordinates As Point) As Point

       Return New Point(formInfo.InitialLocation.X + (mouseCoordinates.X - formInfo.InitialMouseCoords.X),
                        formInfo.InitialLocation.Y + (mouseCoordinates.Y - formInfo.InitialMouseCoords.Y))

   End Function

#End Region

#Region " Hidden Methods "

   ''' <summary>
   ''' Serves as a hash function for a particular type.
   ''' </summary>
   <EditorBrowsable(EditorBrowsableState.Never)>
   Public Shadows Function GetHashCode() As Integer
       Return MyBase.GetHashCode
   End Function

   ''' <summary>
   ''' Gets the System.Type of the current instance.
   ''' </summary>
   ''' <returns>The exact runtime type of the current instance.</returns>
   <EditorBrowsable(EditorBrowsableState.Never)>
   Public Shadows Function [GetType]() As Type
       Return MyBase.GetType
   End Function

   ''' <summary>
   ''' Determines whether the specified System.Object instances are considered equal.
   ''' </summary>
   <EditorBrowsable(EditorBrowsableState.Never)>
   Public Shadows Function Equals(ByVal obj As Object) As Boolean
       Return MyBase.Equals(obj)
   End Function

   ''' <summary>
   ''' Determines whether the specified System.Object instances are the same instance.
   ''' </summary>
   <EditorBrowsable(EditorBrowsableState.Never)>
   Private Shadows Sub ReferenceEquals()
   End Sub

   ''' <summary>
   ''' Returns a String that represents the current object.
   ''' </summary>
   <EditorBrowsable(EditorBrowsableState.Never)>
   Public Shadows Function ToString() As String
       Return MyBase.ToString
   End Function

#End Region

#Region " Event Handlers "

   ''' <summary>
   ''' Handles the MouseEnter event of the Form.
   ''' </summary>
   ''' <param name="sender">The source of the event.</param>
   ''' <param name="e">The <see cref="EventArgs"/> instance containing the event data.</param>
   Private Sub Form_MouseEnter(ByVal sender As Object, ByVal e As EventArgs)

       Dim formInfo As FormDragInfo = FindFormDragInfo(DirectCast(sender, Form))

       formInfo.OldCursor = formInfo.Form.Cursor

       If formInfo.Enabled Then
           formInfo.Form.Cursor = formInfo.Cursor
           ' Optional:
           ' formInfo.Form.BringToFront()
       End If

   End Sub

   ''' <summary>
   ''' Handles the MouseLeave event of the Form.
   ''' </summary>
   ''' <param name="sender">The source of the event.</param>
   ''' <param name="e">The <see cref="EventArgs"/> instance containing the event data.</param>
   Private Sub Form_MouseLeave(ByVal sender As Object, ByVal e As EventArgs)

       Dim formInfo As FormDragInfo = FindFormDragInfo(DirectCast(sender, Form))

       formInfo.Form.Cursor = formInfo.OldCursor

   End Sub

   ''' <summary>
   ''' Handles the MouseDown event of the Form.
   ''' </summary>
   ''' <param name="sender">The source of the event.</param>
   ''' <param name="e">The <see cref="MouseEventArgs"/> instance containing the event data.</param>
   Private Sub Form_MouseDown(ByVal sender As Object, ByVal e As MouseEventArgs)

       Dim formInfo As FormDragInfo = FindFormDragInfo(DirectCast(sender, Form))

       If formInfo.Enabled Then
           formInfo.DragInfo = New FormDragger(formInfo, Form.MousePosition, formInfo.Form.Location)
       End If

   End Sub

   ''' <summary>
   ''' Handles the MouseMove event of the Form.
   ''' </summary>
   ''' <param name="sender">The source of the event.</param>
   ''' <param name="e">The <see cref="MouseEventArgs"/> instance containing the event data.</param>
   Private Sub Form_MouseMove(ByVal sender As Object, ByVal e As MouseEventArgs)

       Dim formInfo As FormDragInfo = FindFormDragInfo(DirectCast(sender, Form))

       If formInfo.Enabled AndAlso (formInfo.DragInfo IsNot FormDragger.Empty) Then
           formInfo.Form.Location = formInfo.DragInfo.GetNewLocation(formInfo, Form.MousePosition)
       End If

   End Sub

   ''' <summary>
   ''' Handles the MouseUp event of the Form.
   ''' </summary>
   ''' <param name="sender">The source of the event.</param>
   ''' <param name="e">The <see cref="MouseEventArgs"/> instance containing the event data.</param>
   Private Sub Form_MouseUp(ByVal sender As Object, ByVal e As MouseEventArgs)

       Dim formInfo As FormDragInfo = FindFormDragInfo(DirectCast(sender, Form))

       formInfo.DragInfo = FormDragger.Empty

   End Sub

#End Region

#Region " IDisposable "

   ''' <summary>
   ''' To detect redundant calls when disposing.
   ''' </summary>
   Private isDisposed As Boolean = False

   ''' <summary>
   ''' Performs application-defined tasks associated with freeing, releasing, or resetting unmanaged resources.
   ''' </summary>
   Public Sub Dispose() Implements IDisposable.Dispose
       Me.Dispose(True)
       GC.SuppressFinalize(Me)
   End Sub

   ''' <summary>
   ''' Releases unmanaged and - optionally - managed resources.
   ''' </summary>
   ''' <param name="IsDisposing">
   ''' <c>true</c> to release both managed and unmanaged resources;
   ''' <c>false</c> to release only unmanaged resources.
   ''' </param>
   Protected Sub Dispose(ByVal isDisposing As Boolean)

       If Not Me.isDisposed Then

           If isDisposing Then

               For Each formInfo As FormDragInfo In Me.forms1

                   With formInfo

                       .Enabled = False
                       .OldCursor = Nothing
                       .DragInfo = FormDragger.Empty
                       .InitialMouseCoords = Point.Empty
                       .InitialLocation = Point.Empty

                       Me.DeassocHandlers(.Form)

                   End With ' form

               Next formInfo

               Me.forms1 = Nothing

           End If ' IsDisposing

       End If ' Not Me.IsDisposed

       Me.isDisposed = True

   End Sub

#End Region

End Class

#End Region

[HKEY_LOCAL_MACHINE]

El cambio de registro en HKEY Current user no ? Es que no estoy seguro y prefiero preguntar por no liarla.

La raíz HKEY_LOCAL_MACHINE (o HKLM) afecta a todo el grupo de usuarios, y la rama HKEY_CURRENT_USER (o HKCU) afecta al usuario activo.
Si, realiza las modificaciones en HKCU.

He visto ademas que hay un programa que se llama Instansheller que lo modifica automaticamente con lo que tu le digas.Eso podria valerme ?

Ni idea de lo que es eso. He buscado "Instant Sheller" por curiosidad y me sale una aplicación para el emulador M.A.M.E de video juegos arcade...
No uses cosas raras si no estás seguro de para que sirven.

El tema de abrir el "explorer.exe" lo podria hacer con un System.Process.Start y llamar a explorer.exe o hay que hacerlo a traves del administrador de tareas ?

El explorer es un proceso y el taskmanager otro, son procesos cómo otros cualquiera, por ende, ¿por qué usar el taskmanager cómo medio para iniciar un proceso secundario, pudiendo iniciar el proceso directamente?.
Sí, puedes utilizar el método Start de la Class Process (System.Diagnostics.Process) para ejecutar el explorer.exe.

Saludos

Pero lo complicas demasiado, en realidad no tiene más misterio que utilizar la clausula 'Order By' ( o la extensión '.OrderBy' ) cómo te sugerí al principio.

Así:

Código (vbnet) [Seleccionar] Expandir

Dim selecctedValues23aa As IEnumerable(Of Integer) =
   From value As Integer In Result22aa55e
   Take 11
   Order By value Ascending

O así:

Código (vbnet) [Seleccionar] Expandir

Dim selecctedValues23aa As IEnumerable(Of Integer) =
   Result22aa55e.
   Take(11).
   OrderBy(Function(value As Integer)
              Return value
           End Function)

Saludos

Me has dado ideas para hacer otra cosilla similar a esta, gracias.

Genial, mientras no utilices esa información para hacer el mal xD.

Me alegro de que el "tip" le haya servido a alguien de utilidad.

Saludos

[ASP.Net]

Para desarrollar una aplicación Web debes utilizar tecnología ASP.Net (o el obsoleto Silverlight).

⇲ Por otro lado, puedes utilizar tecnología XBAP (XAML Browser Application), que combina las características de las aplicaciones web y las aplicaciones de escritorio (basado en el modelo de aplicación WPF, pero con ciertas limitaciones).
How to: Create a New WPF Browser Application Project - MSDN

Saludos!

[PROHIBIDO]

@dani1994
Lee las normas del foro, pedir ayuda para cometer actos delictivos es un tema PROHIBIDO.

Aquí no se ayuda a robar, los código fuente de las aplicaciones publicados son con fines educativos.

Conclusión, evita hablar de esos temas.

@Doddy
Gracias por compartir, pero conoces las reglas del foro, si publicas una aplicación que sabes que se va a utilizar con fines no éticos al menos intenta cuidar las palabras que utilices... como 'ROBAR'.

Tema cerrado.

Saludos!

[C:\Windows\Regedit.exe]

En mi opinión, si tienes una conexión estable, es decir, si puedes navegar/descargar/transferir con normalidad entonces no debes darle importancia al aspa roja de dicho icono, ya que dicho problema no estaría afectando gravemente (ni levemente) al estado de tu conexión...

· ¿Has utilizado el solucionador de problemas de red de Windows?, eso lo primero.
Click derecho en el icono > "Solucionar problemas".

· ¿Te indica algo el resultado del solucionador de problemas?.



Sigue estas indicaciones para intentar solucionar el problema:

1. Inicia la aplicación Regedit (C:\Windows\Regedit.exe)

2. Localiza y exporta (click derecho > exportar) la siguiente clave de registro para guardar una copia de seguridad:
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Network

3. En dicha clave, elimina el valor de tipo binario (REG_BIN) que tiene el nombre Config.
El valor se reconstruirá cuando reinicies sesión de usuario en Windows.

4. Desconecta el router, reinicia el PC, y reconecta el router, hazlo en ese orden.

Con suerte será suficiente para solucionar el problema causante del aspa roja en el icono.



O también puedes probar suerte con estas indicaciones del soporte de Microsoft:

Lost all my network adapters - network icon is X'ed out but still online

Hi,

Have you installed Norton on your computer?

If yes, then uninstall it and check if the issue persists. Such issues are caused by security softwares like Norton. If you have any other security softwares installed then, uninstall it and check of the issue. Post back the status.

Note: You may reinstall those security softwares after checking.

Uninstall or change a program

http://windows.microsoft.com/en-US/windows7/Uninstall-or-change-a-program

You may also try performing clean boot on your computer.

Starting your computer by using a minimal set of drivers and startup programs so that you can determine whether a background program is interfering with your game or program. This kind of startup is known as a "Clean boot."

To perform a clean boot on a computer, follow these steps.
  1.    Click Start, type msconfig in the Start Search box, and then press ENTER.

   If you are prompted for an administrator password or for a confirmation, type the password, or click Continue.

  2.    On the General tab, click Selective Startup.
  3.    Under Selective Startup, click to clear the Load Startup Items check box.
  4.    Click the Services tab, click to select the Hide All Microsoft Services check box, and then click Disable All.
  5.    Click OK.
  6.    When you are prompted, click Restart.
  7.    After the computer starts, check whether the problem is resolved.

  Please monitor the system in the Clean Boot environment. If the problem does not occur, it indicates that the problem is related to one application or service we have disabled. You may use the MSCONFIG tool again to re-enable the disabled item one by one to find out the culprit.

  If your issue is resolved, follow the How to Determine What is Causing the Problem section in the KB article to narrow down the exact source.

For more information visit: http://support.microsoft.com/kb/929135

After you determine the startup item or the service that causes the problem, contact the program manufacturer to determine whether the problem can be resolved. Or, run the System Configuration Utility, and then click to clear the check box for the problem item.

To return your computer to a Normal startup mode, follow these steps:

1. Click Start in the Start Search box.
2. Type msconfig, and then press ENTER.

If you are prompted for an administrator password or for a confirmation, type the password, or provide confirmation.

3. On the General tab, click Normal Startup - load all device drivers and services, and then click OK.
4. When you are prompted, click Restart.

Also update you network card driver. For this you may try the steps provided in the below article.
http://windows.microsoft.com/en-us/windows7/Update-a-driver-for-hardware-that-isnt-working-properly

Hope this information is helpful.

Umesh P - Microsoft Support

Saludos