Tamaño Carpeta

[FernandoML]

Hola a todos:

Necesito ayuda con este problema.
     * Intento averiguar que tamaño tiene una carpeta (Usuario Activo de Windows).
     * Cuando miro la  propiedades en Windows, la carpeta me ocupa unos 45 gb.
     * Cuando ejecuto mi codigo la capacidad es distinta. (14 Gb aproximadamente.

En que me estoy equivocando?

Mi código

Código [Seleccionar] Expandir


    Private Function TamDir(sdir As String)
        Dim di As New DirectoryInfo(sdir)
        Dim info As FileInfo
        Dim Suma As Long


        For Each info In di.GetFiles("*", SearchOption.TopDirectoryOnly)
            Suma = Suma + info.Length
        Next

        MsgBox(Suma)
    End Function


Espero me podais ayudar
Muchas gracias y un saludo a todos

[Meta]

Código (csharp) [Seleccionar] Expandir

long suma =0;

DirectoryInfo di = new DirectoryInfo("c:\\temp");

foreach (FileInfo info in di.GetFiles("*", SearchOption.AllDirectories))

{

   suma+=info.Length;

}

[Danielㅤ]

Hola, también podes ejecutar un comando y guardar el uotput/salida en una variable, en una sóla línea podes tener el tamaño de un directorio sin obviamente utilizar bucle.

Podes usar los comandos dir /s o DiskUsage.


Saludos

[Serapis]

Si la carpeta tambien tiene más carpetas... pues logicamente recorriendo y sumando el tamaño de solo los ficheros en raiz, no te arrojará el tamaño correcto.

Debes crear una funcion recursiva que recibe una carpeta...

Necesita pues dos bucles, el primero recorre todas las carpetas que contenga la actual, reinvocando la misma funcion con la carpeta en el bucle.
El segundo bucle recoge el tamaño de todos los ficheros en la raiz de la carpeta cuyo nombre se recibe en la funcion.
La suma se va devolviendo con cada llamada recursiva y en el retorno se va sumando...

El codigo sería más o menos asi en pseudocodigo:

Código [Seleccionar] Expandir


entero = funcion GetSizeFolder( string RutaFolder)
   entero size

   bucle por cada Carpeta en rutafolder
       size += GetsizeFolder(carpeta)
   siguiente

   bucle por cada fichero en RutaFolder
       size += fichero.Size
   Siguiente

   devolver size
fin funcion

p.d.: Es sencillo modificar la funcion con algún parametro adicional para permitir diferentes recorridos (por ejemplo solo el tamaño de lso ficheros en la capeta introducida, o recorre solo cierto nivel de profundidad, o sumar solo determinados tipos de ficheros, los que cumplan cierto criterio de fechas, etc... La base es esa funcion.

[LastChance]

Aquí te dejo una función reutilizable en VB.NET:

Código (vbnet) [Seleccionar] Expandir

''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Gets the size of a directory, in bytes.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <example> This is a code example.
''' <code language="VB.NET">
''' Dim dirSize As Long = GetDirectorySize("C:\Directory\", SearchOption.AllDirectories)
''' </code>
''' </example>
''' ----------------------------------------------------------------------------------------------------
''' <param name="directoryPath">
''' The directory path.
''' </param>
'''
''' <param name="searchOption">
''' The <see cref="SearchOption"/>.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' The directory size, in bytes.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
<DebuggerStepThrough>
Public Shared Function GetDirectorySize(directoryPath As String, searchOption As SearchOption) As Long

   Dim dirInfo As New DirectoryInfo(directoryPath)
   Dim dirSize As Long = dirInfo.EnumerateFiles("*", searchOption).AsParallel().
                                 Sum(Function(fInfo As FileInfo) fInfo.Length)

   Return dirSize

End Function

También se puede adaptar como una extensión de método para la clase DirectoryInfo:

Código (vbnet) [Seleccionar] Expandir

       ''' ----------------------------------------------------------------------------------------------------
       ''' <summary>
       ''' Gets the size of the directory, in bytes.
       ''' </summary>
       ''' ----------------------------------------------------------------------------------------------------
       ''' <param name="directory">
       ''' The source <see cref="DirectoryInfo"/>.
       ''' </param>
       '''
       ''' <param name="searchOption">
       ''' The <see cref="SearchOption"/>.
       ''' </param>
       ''' ----------------------------------------------------------------------------------------------------
       ''' <returns>
       ''' The directory size, in bytes.
       ''' </returns>
       ''' ----------------------------------------------------------------------------------------------------
       <DebuggerStepThrough>
       <Extension>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public Function GetSize(directory As DirectoryInfo, searchOption As SearchOption) As Long
           Return GetDirectorySize(directory.FullName, searchOption)
       End Function

Saludos.