Problema ocultando Form1 y liberando sus controles

[okik]

Hace tiempo que no entro aquí XD

Pero este es un problema difícil de buscar. No se ni que poner en google.

Es muy simple, cargo un formulario principal A, con X controles. Luego oculto A y libero sus controles al cargar el formulario B. Al cerrar B, se liberan los controles y eventos de B y se vuelve a mostrar el formulario A y recarga sus controles y eventos. Pero tras esto el formulario A no se cierra. Lo podría solucionar simplemente usando End. Pero no es elegante, está claro que no aplico bien el método.

Formulario 1

Código (vbnet) [Seleccionar] Expandir


Public NotInheritable Class frmMain
   Inherits Form
   Friend MyButton1 As Button

   Public Sub New()

       ' Llamada necesaria para el diseñador.
       MyClass.InitializeComponent()
       Me.MyButton1 = New Button With {
           .Text = "Show Form2",
           .Location = New Point(10, 10)
       }
       ' Agregue cualquier inicialización después de la llamada a InitializeComponent().
       AddHandler MyButton1.Click, AddressOf MyButton1_Click
   End Sub


   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(MyButton1)
       Me.Text = "frmMain"
   End Sub
   Private Sub MyButton1_Click(sender As Object, e As EventArgs)
       DisposeControls()
       Me.Hide()
       frmDialog.Show()
   End Sub

   Sub DisposeControls()
       Me.MyButton1.Dispose()
       RemoveHandler MyButton1.Click, AddressOf MyButton1_Click
   End Sub

End Class



Formulario 2

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class frmDialog
   Inherits Form
   Friend MyButton2 As Button
   Friend fmain As New frmMain
   Public Sub New()
       ' Llamada necesaria para el diseñador.
       MyClass.InitializeComponent()
       MyButton2 = New Button With
       {
           .Text = "Show Form1",
           .Location = New Point(10, 10)
       }
       ' Agregue cualquier inicialización después de la llamada a InitializeComponent().
       AddHandler MyButton2.Click, AddressOf MyButton2_Click
   End Sub

   Private Sub frmDialog_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
       fmain.Show()
       ' fmain.Visible=tue

   End Sub
   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(MyButton2)
       Me.Text = "frmDialog"
   End Sub
   Private Sub MyButton2_Click(sender As Object, e As EventArgs)
       DisposeControls()
       Me.Close()
   End Sub
   Sub DisposeControls()

       RemoveHandler MyButton2.Click, AddressOf MyButton2_Click
       Me.MyButton2.Dispose()
   End Sub
End Class

He probado de todo.



gracias por la ayuda



Si no libero los controles y eventos creados en el formulario A, entonces va bien. Pero deberían poderse liberar.

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class frmMain
    Inherits Form
    Friend MyButton1 As Button

    Public Sub New()

        ' Llamada necesaria para el diseñador.
        MyClass.InitializeComponent()
        Me.MyButton1 = New Button With {
            .Text = "Show Form2",
            .Location = New Point(10, 10)
        }
        ' Agregue cualquier inicialización después de la llamada a InitializeComponent().
        AddHandler MyButton1.Click, AddressOf MyButton1_Click
    End Sub


    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Me.Controls.Add(MyButton1)
        Me.Text = "frmMain"
    End Sub
    Private Sub MyButton1_Click(sender As Object, e As EventArgs)
        DisposeControls()
        Me.Hide()
        frmDialog.Show()
    End Sub

    Sub DisposeControls()
        Me.MyButton1.Dispose()
        RemoveHandler MyButton1.Click, AddressOf MyButton1_Click
    End Sub

End Class

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class frmDialog
    Inherits Form
    Friend MyButton2 As Button
    Public Sub New()
        ' Llamada necesaria para el diseñador.
        MyClass.InitializeComponent()
        MyButton2 = New Button With
        {
            .Text = "Show Form1",
            .Location = New Point(10, 10)
        }
        ' Agregue cualquier inicialización después de la llamada a InitializeComponent().
        AddHandler MyButton2.Click, AddressOf MyButton2_Click
    End Sub

    Private Sub frmDialog_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
        '  fmain.Show()
        frmMain.Show()

    End Sub
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Me.Controls.Add(MyButton2)
        Me.Text = "frmDialog"
    End Sub
    Private Sub MyButton2_Click(sender As Object, e As EventArgs)
        'DisposeControls()
        Me.Close()
    End Sub
    Sub DisposeControls()

        RemoveHandler MyButton2.Click, AddressOf MyButton2_Click
        Me.MyButton2.Dispose()
    End Sub
End Class

[Eleкtro]

Tienes que modificar toda la lógica del problema que estés intentando resolver...

1. Una aplicación WindowsForms no puede coexistir sin un Form principal, puesto que el Form contiene el método del punto de entrada (Entry point) de la aplicación. Si liberas/cierras el Form principal, es exactamente lo mismo que finalizar la aplicación. En resumen, NO debes liberar el Form principal (a menos que quieras terminar la ejecución de la app).

2. En el Form-diálogo tienes declarado esto:

Código [Seleccionar] Expandir

Friend fmain As New frmMain

...lo que consigues haciendo eso es crear una nueva instancia de frmMain, distinta, duplicada, e innecesariamente puesto que no necesitas crear ni 1 ni 2 ni ninguna instancia adicional del Form principal de tu aplicación, ya la tienes instanciada, úsala. No se si he explicado bien esta parte, ¿entiendes lo que intento decirte?.

3. No necesitas asegurarte de liberar ningún control ni de eliminar ninguna asociación de eventos, todo eso ya lo hace .NET Framework automáticamente al llamar al método Form.Dispose(), se encarga de liberar todos los controles de la colección de controles del Form, entre otros recursos administrados y no administrados...

4. La manera de implementar un método de liberación de recursos (Dispose) no es añadiendo un método cualquiera al que llamaremos "DisposeControls" al tún tún y liberar allí los objetos, no, se hace implementando la interfáz IDIsposable:

Código (vbnet) [Seleccionar] Expandir

Class Class1 : Implements IDisposable

#Region " IDisposable Implementation "

   Private isDisposed As Boolean

   Public Sub Dispose() Implements IDisposable.Dispose
       Me.Dispose(isDisposing:=True)
       GC.SuppressFinalize(obj:=Me)
   End Sub

   Protected Overridable Sub Dispose(ByVal isDisposing As Boolean)
       If (Not Me.isDisposed) AndAlso (isDisposing) Then
           ' Free managed resources here...
       End If

       ' Free unmanaged resources here...
       Me.isDisposed = True
   End Sub

#End Region

End Class

El type Form logicamente ya implementa dicha interfaz, así que solamente debes hacer una suplantación:

Código (vbnet) [Seleccionar] Expandir

Class Form1 : Inherits Form

   Protected Overrides Sub Dispose(ByVal isDisposing As Boolean)
       ' Free additional managed and unmanaged resources here...
       MyBase.Dispose(disposing:=True)
   End Sub

End Class



No se muy bien lo que pretendes hacer, ya que en realidad ese diálogo dista bastante de ser un diálogo puesto que no le das el uso que se le daría a un diálogo, de todas formas he escrito este ejemplo de aquí abajo que creo te podrá servir.

Lo que hace este ejemplo es mostrar un diálogo a través de un botón del Form principal, y volver a mostrar el Form principal despues de devolver el resultado del diálogo. Eso es lo que creo haber entendido que quieres hacer... y yo solo te muestro una manera apropiada de hacerlo.

Form Principal:

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class FormMain : Inherits Form

   Friend WithEvents ButtonShowDlg As Button

   Public Sub New()
       ' MyClass.InitializeComponent()

       Me.Text = "Main Window"

       Me.ButtonShowDlg = New Button With
           {
             .Text = "Show Dialog Window...",
             .Location = New Point(10, 10)
           }
   End Sub

   Private Sub FormMain_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(Me.ButtonShowDlg)
   End Sub

   Private Sub ButtonShowDlg_Click(ByVal sender As Object, ByVal e As EventArgs) Handles ButtonShowDlg.Click
       Me.Hide()

       Dim dlgPos As Point
       Dim dlgResult As DialogResult

       Using dlg As FormDlg = My.MyProject.Forms.FormDlg
           dlgResult = dlg.ShowDialog(Me)
           dlgPos = dlg.Location
           Debug.WriteLine(dlgResult.ToString())
       End Using

       Me.Location = dlgPos
       Me.Show()
   End Sub

End Class

Diálogo:

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class FormDlg : Inherits Form

   Friend WithEvents ButtonClose As Button

   Public Sub New()
       ' MyClass.InitializeComponent()

       With Me
           .Text = "Dialog Window"
           .FormBorderStyle = FormBorderStyle.FixedDialog
           .Owner = My.MyProject.Forms.FormMain
           .StartPosition = FormStartPosition.CenterParent
       End With

       Me.ButtonClose = New Button With
           {
             .Text = "Show Main Window...",
             .Location = New Point(10, 10)
           }

   End Sub

   Private Sub FormDlg_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(Me.ButtonClose)
   End Sub

   Private Sub FormDlg_FormClosing(ByVal sender As Object, ByVal e As FormClosingEventArgs) Handles Me.FormClosing
       If (e.CloseReason = CloseReason.ApplicationExitCall) Then
           Me.DialogResult = DialogResult.Cancel
       End If
   End Sub

   Private Sub ButtonClose_Click(ByVal sender As Object, ByVal e As EventArgs) Handles ButtonClose.Click
       Me.DialogResult = DialogResult.OK
       Me.Close()
   End Sub

End Class

Saludos!

[okik]

Realmente no quería hacer un formulario Dialog, lo que pasa es que lo puse así para diferenciar el principal del que no lo es y al otro le puse dialog.


Para explicar voy a cambiar: tengo dos formularios FormA (principal) y FormB (secundario)

Lo que quiero es iniciar el segundo formulario y  FormA ocultarlo mediante 'HIDE". Pero al ocultar el principal realmente sigue en memoria y para liberar memoria quería eliminar todos los eventos y controles del FormA , al mostrar el FormB

Cuando cierro FormB todo se libera así que aquí no tengo que usar dispose ni nada, no se porqué lo puse ahí.

Pero cuando vuelvo a mostrar el formulario FormA usando Visible = True, como eliminé todos los controles, ya no aparecen. Así que uso Show.   Así que uso:

Código (vbnet) [Seleccionar] Expandir

     
Dim frmMain As New FormA
       frmMain.Show()


(hay varias maneras, lo se)

Y todos los controles se carga de nuevo, PERO , cuando cierro FormA no se cierra.

Esta es la cosa.


DEMOSTRACIÓN:

FORMA

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class FormA : Inherits Form

   Friend ButtonShowFormB As Button

   Public Sub New()
       MyClass.InitializeComponent()
       Me.Text = "FormA"
       Me.ButtonShowFormB = New Button With
           {
             .Text = "Show FormB",
             .Location = New Point(10, 10)
           }
       AddHandler Me.ButtonShowFormB.Click, AddressOf ButtonShowFormB_Click
   End Sub

   Private Sub FormMain_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(Me.ButtonShowFormB)
   End Sub

   Private Sub ButtonShowFormB_Click(ByVal sender As Object, ByVal e As EventArgs)
       'Libera los controles
       ButtonShowFormB.Dispose()
       RemoveHandler Me.ButtonShowFormB.Click, AddressOf ButtonShowFormB_Click

       'Oculta el form
       Me.Hide()

       'Muestra el Form2
       FormB.Show()
   End Sub

End Class


FORMB

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class FormB : Inherits Form

   Friend WithEvents ButtonShowFormA As Button

   Public Sub New()

       MyClass.InitializeComponent()

       With Me
           .Text = "FormFB"
           .FormBorderStyle = FormBorderStyle.FixedDialog
           .Owner = My.MyProject.Forms.FormA
           .StartPosition = FormStartPosition.CenterParent
       End With

       Me.ButtonShowFormA = New Button With
           {
             .Text = "Show FormA",
             .Location = New Point(10, 10)
           }

   End Sub

   Private Sub FormB_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
       Dim frm As New FormA
       frm.Show()
   End Sub

   Private Sub FormDlg_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(Me.ButtonShowFormA)
   End Sub

   Private Sub ButtonShowFormA_Click(ByVal sender As Object, ByVal e As EventArgs) Handles ButtonShowFormA.Click
       Me.Close()
   End Sub

End Class

Pulsa el botón: se oculta el FORMA (y elimina los controles), y se muestra el FORMB
Pulsa el botón: Se CIERRA el FORMB y se carga el FORMA (recarga los controles)

Y aquí es donde se lía la cosa. Al cerrar (con el botón cerrar X) el formulario FORMA, la aplicación no se cierra se queda pendiente.

Ese es el problema.

No se si es que al hacer esto:

Código (vbnet) [Seleccionar] Expandir

  Private Sub FormB_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
       Dim frm As New FormA
       frm.Show()
   End Sub

Se crea otro FormA visible con todos sus controles y queda pendiente en memoria el FormA inicial sin controles que hemos ocultado mediante HIDE.

La verdad no se.

Se soluciona añadiendo END, pero no debería ser necesario. Algo raro ocurre.

Tiene que haber alguna manera de crear de nuevo todos los controles cuando el FormA vuelva a ser visible

si hago esto al cerrar el FormA y mostrar el FormB, simplemente se cierra la aplicación:

Código (vbnet) [Seleccionar] Expandir

   Private Sub ButtonShowFormB_Click(ByVal sender As Object, ByVal e As EventArgs)
       'Libera los controles
       '  ButtonShowFormB.Dispose()
       'RemoveHandler Me.ButtonShowFormB.Click, AddressOf ButtonShowFormB_Click
       MyBase.Dispose(disposing:=True) 'o  Me.Dispose()

       'Oculta el form
       Me.Hide()

       'Muestra el Form2
       FormB.Show()
   End Sub


Si me solucionas el problema te cuelgo el programa 

[Eleкtro]

Lo que quiero es iniciar el segundo formulario y  FormA ocultarlo mediante 'HIDE". Pero al ocultar el principal realmente sigue en memoria y para liberar memoria quería eliminar todos los eventos y controles del FormA , al mostrar el FormB

Te entiendo, pero no no no no no no, no... no, y ¡NO!.  No debes intentar hacer eso okik, arriba al principio del comentario te expliqué la razón.

De todas formas te explico por que te sucede eso, creo que estás atribuyéndole propósitos adicionales al método Form.Show(), ese método solo sirve para mostrar el Form, no para instanciarlo, es decir, si tu liberas un control del FormA, luego ocultas ese FormA llamando a Form.Hide() y por último muestras el FormA llamando a Form.Show(), en ese procedimiento lo único que has hecho es liberar un control y ocultar y mostrar el form, el control no se va a volver a colocar ahí por arte de mágia, debes volver a crear una instancia del control, y añadirla a la colección de controles del Form.

Para solucionarlo debidamente, podrías controlar el evento Form.VisibleChanged de la siguiente manera:

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class FormMain : Inherits Form

   Friend WithEvents ButtonShowFormB As Button

   Public Sub New()
       MyClass.InitializeComponent()
       Me.Text = "FormA"
   End Sub

   Private Sub FormMain_VisibleChanged(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.VisibleChanged

       If DirectCast(sender, Form).Visible Then
           Me.ButtonShowFormB = New Button With
                   {
                     .Text = "Show FormB",
                     .Location = New Point(10, 10)
                   }
           Me.Controls.Add(Me.ButtonShowFormB)
       End If

   End Sub

   Private Sub ButtonShowFormB_Click(ByVal sender As Object, ByVal e As EventArgs) Handles ButtonShowFormB.Click
       Me.ButtonShowFormB.Dispose()
       Me.ButtonShowFormB = Nothing
       Me.Hide()

       FormB.Show()
   End Sub

End Class

Si realmente te empeñas en liberar los recursos del Form principal a deshora, fíjate bien en esta instrucción que añadí:

Código (vbnet) [Seleccionar] Expandir

Me.ButtonShowFormB = Nothing

...después de llamar al método Control.Dispose() es necesario asignarle un valor nulo al objeto tal y como hice, para facilitarle la tarea al GarbageCollector indicándole que puede proceder a liberar los recursos del control cuanto antes.

Saludos!

[okik]

Bueno gracias funciona.

Sin embargo no es problema así usar Show. Funciona ponga Show que Visible=true. Pero de forma directa sin usar NEW

Código (vbnet) [Seleccionar] Expandir

 
Private Sub FormA_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed
       '  FormA.Visible = True
       FormA.Show()
   End Sub



(Esto todo en un formulario)

Código (vbnet) [Seleccionar] Expandir

Public NotInheritable Class FormA : Inherits Form

   Friend ButtonShowFormB As Button

   Public Sub New()
       MyClass.InitializeComponent()
       Me.Text = "FormA"
   End Sub

   Private Sub FormA_VisibleChanged(sender As Object, e As EventArgs) Handles Me.VisibleChanged

       If DirectCast(sender, Form).Visible Then
           Me.ButtonShowFormB = New Button With
      {
        .Text = "Show FormB",
.Location = New Point(10, 10)
      }
           Me.Controls.Add(Me.ButtonShowFormB)
           AddHandler Me.ButtonShowFormB.Click, AddressOf ButtonShowFormB_Click
     
       End If
   End Sub


   Private Sub FormMain_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(Me.ButtonShowFormB)
   End Sub

   Private Sub ButtonShowFormB_Click(ByVal sender As Object, ByVal e As EventArgs)
       RemoveHandler Me.ButtonShowFormB.Click, AddressOf ButtonShowFormB_Click
       Me.ButtonShowFormB.Dispose()
       Me.ButtonShowFormB = Nothing
       Me.Hide()
       FormB.Show()
   End Sub


End Class

Public NotInheritable Class FormB : Inherits Form
   Friend ButtonShowFormB As Button
   Public Sub New()
       Me.Text = "FormB"
       Me.ButtonShowFormB = New Button With
           {
             .Text = "Show FormA",
             .Location = New Point(10, 10)
           }
       AddHandler Me.ButtonShowFormB.Click, AddressOf ButtonShowFormB_Click
   End Sub

   Private Sub FormA_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed
       '  FormA.Visible = True
       FormA.Show()
   End Sub

   Private Sub FormMain_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
       Me.Controls.Add(Me.ButtonShowFormB)
   End Sub

   Private Sub ButtonShowFormB_Click(ByVal sender As Object, ByVal e As EventArgs)
       Me.Close()
   End Sub
End Class


Esto ya lo contemple y crear un proceso que cargue los controles desde el Closing del Form2. Pero pensé que no era la forma correcta de hacerlo. Supongo que si el número de controles y eventos del formulario principal no es muy grande, no pasa nada que no se eliminen los eventos y los controles.