Obtener porcentaje de descarga desde un módulo

Iniciado por okik, 1 Julio 2015, 19:18 PM

0 Miembros y 1 Visitante están viendo este tema.

okik

Hola,

Pues aquí otra nueva duda.

No me gusta cargar demasiado de código el Form1, así que suelo poner las funciones por separado en módulos, o en módulos de clases.  El caso es que tengo un código de descarga de archivos desde un módulo y no consigo mostrar el proceso de descarga desde él.

Código (vbnet) [Seleccionar]

Imports System.Net
Module modDownloadURL
   Public Progress As String
   Private Sub DownloadProgressCallback(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs)
       Dim intBytes As Double = Double.Parse(e.BytesReceived.ToString()) 'Bytes recibidos
       Dim AllBytes As Double = Double.Parse(e.TotalBytesToReceive.ToString()) 'Total bytes recibidos
       Dim percentage As Double = intBytes / AllBytes * 100
       Progress = CStr(e.ProgressPercentage & (" %"))
   End Sub
   Private Sub Client_DownloadCompleted(ByVal sender As Object, ByVal e As System.ComponentModel.AsyncCompletedEventArgs)
       MessageBox.Show("Descarga completada")
   End Sub

   Public Sub DownLoadFileInBackground2(ByVal address As String, ByVal strDirFile As String)
       Dim Client As WebClient = New WebClient()
       AddHandler Client.DownloadProgressChanged, AddressOf DownloadProgressCallback
       AddHandler Client.DownloadFileCompleted, AddressOf client_DownloadCompleted
       Dim uri As Uri = New Uri(address)
       Client.DownloadFileAsync(uri, strDirFile)
   End Sub
End Module


El porcentaje se carga en la variable string Progress  , y desde un botón en el formulario llamo a DownLoadFileInBackground2(url, [Dir+Namefile]) para descargar el archivo

Gracias


Eleкtro

#1
Habría que analizar lo que haces con el Control de tipo Label, por que el código que has mostrado funciona.

De todas formas lo he simplificado (un poco) y he corregido varios conflictos de convención o estándares de VB.Net en los nombres que le diste a los miembros del código.

Esto te debería funcionar. Adapta el código a tus necesidades.

Código (vbnet) [Seleccionar]
DownLoadAsynchronously("http://download.thinkbroadband.com/5MB.zip")

Código (vbnet) [Seleccionar]
Module ModDownloadUrl

   Private WithEvents wc As WebClient

   Private Sub WC_DownloadProgressChanged(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs) _
   Handles wc.DownloadProgressChanged

       If Not e.ProgressPercentage = 100 Then
           Trace.WriteLine(String.Format("Progress: {0}", ((e.BytesReceived / e.TotalBytesToReceive) * 100.0R).ToString(format:="00.00 \%")))
       End If

   End Sub

   Private Sub WC_DownloadFileCompleted(ByVal sender As Object, ByVal e As AsyncCompletedEventArgs) _
   Handles wc.DownloadFileCompleted

       wc.Dispose()
       Trace.WriteLine(String.Format("Progress: {0}", 100.0R.ToString(format:="00.00 \%")))
       MessageBox.Show("Download Complete.", "", MessageBoxButtons.OK, MessageBoxIcon.Information)

   End Sub

   Public Sub DownLoadAsynchronously(ByVal url As String,
                                     Optional ByVal targetFilepath As String = "",
                                     Optional ByVal ctrl As Control = Nothing)

       If String.IsNullOrWhiteSpace(targetFilepath) Then
           targetFilepath = Path.GetFileName(url)
       End If

       wc = New WebClient
       wc.DownloadFileAsync(New Uri(url), targetFilepath)

   End Sub

End Module


Saludos








okik

#2
Hola
Gracias por el código, funciona bien, pero no he conseguido que haga lo siguiente, ni aún añadiendo el opcional. Quizás es que no lo utilizo bien.

Lo que yo quería era pasar el porcentaje  a la variable Progress, para luego desde el Form capturar la información de esa variable y mostrarlo en un Label mientras se produce la descarta y en tiempo real, desde el evento Click. Pero pasa que  el label se queda en blanco. Tan solo muestra la información cuando hago esto, desde el módulo. Sustituyendo directamente la variable Progress por el control Label

Código (vbnet) [Seleccionar]
Private Sub DownloadProgressCallback(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs)
       Dim intBytes As Double = Double.Parse(e.BytesReceived.ToString()) 'Bytes recibidos
       Dim AllBytes As Double = Double.Parse(e.TotalBytesToReceive.ToString()) 'Total bytes recibidos
       Dim percentage As Double = intBytes / AllBytes * 100
      Form1.Label1.text = CStr(e.ProgressPercentage & (" %"))
   End Sub


Con tu código quedaría así:

Código (vbnet) [Seleccionar]
   Private Sub WC_DownloadProgressChanged(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs) Handles wc.DownloadProgressChanged
       If Not e.ProgressPercentage = 100 Then
           Form1.Label1.Text = String.Format("Progress: {0}", ((e.BytesReceived / e.TotalBytesToReceive) * 100.0R).ToString(format:="00.00 \%"))
       End If
   End Sub


Pero lo extraño es que la el porcentaje se para en 94%, 89%, etc. Nunca en 100%, aunque el archivo se descargue por completo. He usado el url de un archivo pequeño (el de mi avatar, el gif).

Queda corregido sustituyendo 100 por 101
Código (vbnet) [Seleccionar]
Not e.ProgressPercentage = 101

Probaré mañana, si puedo, creando un módulo de clase. Con la propiedad Get, creo que debería funcionar.

La idea es crear una función de código independiente y aparte sin tener que estar modificando dicho código para que devuelva la información de descarga a un determinado control.

Sl2

Eleкtro

#3
Cómo ya te digo, habría que ver el resto del código, por que las modificaciones que comentas en mi caso me funcionan correctamente, el label se actualiza correctamente.

De todas formas que estés utilizando un módulo para operaciones asíncronas, objetos disposables, y eventos, no me convence en absoluto, no debería causarte problemas, pero tampoco hay necesidad de que los miembros definidos en ese modulo sean compartidos con el resto de classes, por ese motivo yo usaría una Class instanciable y liberaría los objetos cuando sea necesario.

Aparte de eso, en otras circunstancias te diría que utilizases un BackgroundWorker, pero en este caso considero que sería practicamente el mismo resultado.

Prueba esto, si no te funciona entonces no sé que decirte a menos que muestres tu código completo para buscar un posible problema que en el código que has mostrado hasta ahora no aparece o no lo puedo detectar.

Así es más o menos cómo yo encapsularía esos datos:

Código (vbnet) [Seleccionar]
#Region " Imports "

Imports System
Imports System.ComponentModel
Imports System.IO
Imports System.Linq
Imports System.Net
Imports System.Windows.Forms
Imports System.Threading.Tasks

#End Region

Public NotInheritable Class FileDownloader : Implements IDisposable

#Region " Disposable Members "

   Private WithEvents wc As WebClient

#End Region

#Region " Properties "

   Public ReadOnly Property IsBusy As Boolean
       Get
           If Me.wc IsNot Nothing Then
               Return Me.wc.IsBusy
           Else
               Return False
           End If
       End Get
   End Property

#End Region

#Region " Events "

   Public Event DownloadProgressChanged(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs)
   Public Event DownloadCompleted(ByVal sender As Object, ByVal e As AsyncCompletedEventArgs)

#End Region

#Region " Event-Handlers "

   Private Sub WC_DownloadProgressChanged(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs) _
   Handles wc.DownloadProgressChanged

       If (Me.DownloadProgressChangedEvent IsNot Nothing) AndAlso (e.ProgressPercentage <> 100) Then
           RaiseEvent DownloadProgressChanged(sender, e)
       End If

   End Sub

   Private Sub WC_DownloadFileCompleted(ByVal sender As Object, ByVal e As AsyncCompletedEventArgs) _
   Handles wc.DownloadFileCompleted

       If (Me.DownloadCompletedEvent IsNot Nothing) Then
           RaiseEvent DownloadCompleted(sender, e)
       End If

   End Sub

#End Region

#Region " Public Methods "

   Public Sub DownloadAsync(ByVal url As String,
                            Optional ByVal targetFilepath As String = "")

       If String.IsNullOrWhiteSpace(url) Then
           Throw New ArgumentNullException(paramName:="url")

       Else

           If (Me.wc IsNot Nothing) AndAlso (Me.wc.IsBusy) Then
               Throw New Exception(message:="Another download is in progress.")

           Else
               Me.wc = New WebClient With
                {
                    .UseDefaultCredentials = True
                }

               If String.IsNullOrWhiteSpace(targetFilepath) Then
                   targetFilepath = Path.GetFileName(url)
               End If

               Task.Factory.StartNew(Sub() wc.DownloadFileAsync(New Uri(url), targetFilepath))

           End If

       End If

   End Sub

   ''' <summary>
   ''' Cancels the current asynchronous download.
   ''' </summary>
   Public Sub Cancel()

       If Me.wc Is Nothing Then
           Throw New NullReferenceException(message:="", innerException:=New ObjectDisposedException(objectName:="wc"))

       ElseIf Me.wc.IsBusy Then
           Me.wc.CancelAsync()

       End If

   End Sub

#End Region

#Region "IDisposable Support"

   ''' ----------------------------------------------------------------------------------------------------
   ''' <summary>
   ''' To detect redundant calls when disposing.
   ''' </summary>
   ''' ----------------------------------------------------------------------------------------------------
   Private isDisposed As Boolean = False

   ''' ----------------------------------------------------------------------------------------------------
   ''' <summary>
   ''' Performs application-defined tasks associated with freeing, releasing, or resetting unmanaged resources.
   ''' </summary>
   ''' ----------------------------------------------------------------------------------------------------
   Public Sub Dispose() Implements IDisposable.Dispose
       Me.Dispose(isDisposing:=True)
       GC.SuppressFinalize(obj:=Me)
   End Sub

   ''' ----------------------------------------------------------------------------------------------------
   ''' <summary>
   ''' Releases unmanaged and - optionally - managed resources.
   ''' </summary>
   ''' ----------------------------------------------------------------------------------------------------
   ''' <param name="isDisposing">
   ''' <c>True</c> to release both managed and unmanaged resources;
   ''' <c>False</c> to release only unmanaged resources.
   ''' </param>
   ''' ----------------------------------------------------------------------------------------------------
   Protected Sub Dispose(ByVal isDisposing As Boolean)

       If Not Me.isDisposed Then

           If isDisposing Then

               If Me.wc IsNot Nothing Then
                   Me.wc.Dispose()
               End If

           End If

       End If

       Me.isDisposed = True

   End Sub

#End Region

End Class


Y el uso que le daría ...más o menos también:

Código (vbnet) [Seleccionar]
Imports System.ComponentModel
Imports System.Threading.Tasks

Public NotInheritable Class Form1 : Inherits Form

   Dim WithEvents downloader As New FileDownloader

   Private Sub Test() Handles MyBase.Shown

       Me.downloader.DownloadAsync("http://download.thinkbroadband.com/10MB.zip")

   End Sub

   Private Sub Button1_Click(sender As Object, e As EventArgs) _
   Handles Button1.Click

       If Me.downloader.IsBusy Then
           Me.downloader.Cancel()
       End If

   End Sub

   Private Sub Downloader_DownloadProgressChanged(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs) _
   Handles downloader.DownloadProgressChanged

       Dim progress As Double = (e.BytesReceived / e.TotalBytesToReceive) * 100.0R

       If Me.Label1.InvokeRequired Then
           Me.Label1.Invoke(Sub() Me.Label1.Text = progress.ToString(format:="00.00 \%"))

       Else
           Me.Label1.Text = progress.ToString(format:="00.00 \%")

       End If

   End Sub

   Private Sub Downloader_DownloadCompleted(ByVal sender As Object, ByVal e As AsyncCompletedEventArgs) _
   Handles downloader.DownloadCompleted

       If e.Cancelled Then
           Exit Sub
       End If

       If Me.Label1.InvokeRequired Then
           Me.Label1.Invoke(Sub() Me.Label1.Text = 100.0R.ToString(format:="00.00 \%"))

       Else
           Me.Label1.Text = 100.0R.ToString(format:="00.00 \%")

       End If

   End Sub

End Class


Saludos.








okik

#4
Eres un maestro

Lo que busco es tan simple como esto, y te juro que el label se queda en blanco, la verdad que no lo entiendo

Código (vbnet) [Seleccionar]
Public Class Form1

   Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
       Dim ns As New modDownloadURL
       ns.DownLoadFileInBackground2("http://3.bp.blogspot.com/-08K8K-44ouk/VYg40YxJvxI/AAAAAAAAARw/wrLQDfGDW-8/s1600/OKIK2.gif", _
"E:\jk.gif")
       Label1.Text = ns.getProgress
   End Sub
End Class

Class modDownloadURL
   Public Progress As Object
   Private Sub DownloadProgressCallback(ByVal sender As Object, _
ByVal e As System.Net.DownloadProgressChangedEventArgs)
       Dim intBytes As Double = Double.Parse(e.BytesReceived.ToString()) 'Bytes recibidos
       Dim AllBytes As Double = Double.Parse(e.TotalBytesToReceive.ToString()) 'Total bytes recibidos
       Dim percentage As Double = intBytes / AllBytes * 100
       Progress = (e.ProgressPercentage & (" %"))
   End Sub
   Private Sub Client_DownloadCompleted(ByVal sender As Object, _
ByVal e As System.ComponentModel.AsyncCompletedEventArgs)
       MessageBox.Show("Descarga completada")
   End Sub

   Public Sub DownLoadFileInBackground2(ByVal address As String, _
ByVal strDirFile As String)
       Dim Client As System.Net.WebClient = New System.Net.WebClient()
       AddHandler Client.DownloadProgressChanged, AddressOf DownloadProgressCallback
       AddHandler Client.DownloadFileCompleted, AddressOf Client_DownloadCompleted
       Dim uri As Uri = New Uri(address)
       Client.DownloadFileAsync(uri, strDirFile)
   End Sub
   ReadOnly Property getProgress() As String
       Get
           Return Progress
       End Get
   End Property

End Class


Me ha gustado tu opción de cancelar, también buscaba eso...

Eleкtro

#5
Cita de: okik en  2 Julio 2015, 20:38 PMLo que busco es tan simple como esto

¿Ese es el código completo que estás utilizando?, en ese caso, ¿còmo esperas que no se quede en blanco el label?, jeje, estás devolviendo un objeto una única vez, un objeto vacío/nulo.

En resumidas cuentas, descartando el resto del código esta es la trayectoria que haces, de la linea 5 a la 15, FIN.

Código (vbnet,5,15) [Seleccionar]
   Public Class Form1
   
       Private Sub Button1_Click(...) Handles Button1.Click
           ...
           Label1.Text = ns.getProgress
       End Sub

   End Class
   
   Class modDownloadURL
       Public Progress As Object

       ReadOnly Property getProgress() As String
           Get
               Return Progress
           End Get
       End Property
   
   End Class


Primero llamas al método que descarga el archivo, y mientras tanto asignas el texto al label, pero solo lo asignas una vez, y el valor seguramente esté en blanco por que al objeto "Progress" no lo inicializaste con un valor inicial y el texto del label se asigna más rápido de lo que la operación asincrona tarda en disparar el evento del WebClient para asignarle un valor inicial a ese objeto "Progress".

Vamos, que despues de la primera vez que le asignas el texto vacío al label, no llegas a actualizar el texto del label nunca más.

Debes controlar cuando los eventos del Webclient se disparan, para actualizar el texto del label cuando eso suceda (cómo en el ejemplo que he publicado arriba).
El control no se va a actualizar por arte de magia.


¿Hay algo que no entiendas de tú código, de lo que estás haciendo?.


Saludos!








okik

#6
 ;D
La verdad es que en muchos casos en .NET no tengo ni idea de lo que hago, solo se que esto o lo otro funciona o hace esto o  aquello. En fin que hace lo que yo quiero.

Voy a aclarar algunos puntos.
A. No soy programador, solo aficionado. No trabajo para ninguna empresa ni tengo intención de ello, ni creo que pueda.

B. Acabo de empezar con VB.NET hace como un par de meses o tres, más o menos. Empecé tonteando un poco para adaptarme al entorno, del cual solo he usado seguramente como el 2% de lo que tiene.

C. No soy "programador" de escuela, ni de libro, es decir, no estudio la teoría, aprendo de forma empírica. Quiero hacer algo y busco la forma. Muchas veces es a base de prueba y error. Por supuesto entiendo conceptos como array, bucles, funciones, eventos, etc. y leo definiciones, que muchas veces tengo que decirlo no las entiendo. Por ejemplo, hace unos días pregunté sobre el operador XOR porque por la definición del MSDN no entendía ni papa. Pero afortunadamente dos usuarios respondieron de forma fantástica y pude entenderlo.

D.
Código (xml) [Seleccionar]
¿Ese es el código completo que estás utilizando?

Me gusta programar por bloques, algo así como una conexión en red pero de código. No me gusta mezclarlo todo, porque en el momento que se me ocurre algo y quiero hacer una modificación, puede resultar o bien que  la modificación produzca un error que me obliga a modificar todo  o empezar casi desde el principio por incompatibilidad o bien haya pasado tanto tiempo desde que revisé el código que ya no recuerdo ni lo que hice y no se lo que hacía esto o aquello, sobre todo con códigos muy grandes.
También facilita y agiliza la creación  de programas pues solo tengo que hacer un copia y pega. Tengo cientos de plantillas de código simple y ejemplos sólo de VB, los cuales hacen lo básico y lo importante. Por supuesto son modificables y ajustables  a la necesidades del programa.
Y por supuesto mi me memoria es pésima, cuando dejo de usar algo se me olvida, y es muy práctico tener un código de ejemplo para cuando lo necesite.

El código que he puesto NO es el programa que estoy haciendo, tan sólo quiero hacer como he dicho un bloque de código independiente que me va a servir para el programa o para futuros programas.  Tan sólo quiero:

Form1 (o cualquier otro, o módulo)
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
-Llama a la función y la URL
-Recibir información de descarga mientras se produce
-Opción cancelar
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
              ▲
               •
               •
               •
              ▼
Bloque de código aparte
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
- Función de descarga con la URL  
- Obtener información de descarga
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀

Por lo tanto como ejemplo y como base, tan solo necesito un label el cual va a recibir la información del porcentaje, todo lo demás es irrelevante.

A veces encuentro en la red, que gente pone ejemplos supercomplejos, casi programas completos, con variables incomprensibles,  por ejemplo como usar un Listview, y en lugar de decir para crear columnas, tal, para introducir filas, tal, para esto tal. Pues te ponen un entramado inconprensible que tienes que ir desglosando. Lo cual dificulta el aprendizaje de aquellos que están aprendiendo y solo buscan algo muy concreto. Además, no todos somos unos gurús de la informática. Esto me ha pasado especialmente, buscando información sobre GDI, que siempre aparecen ejemplo de programas completos y bastante complejos. Hace poco modifiqué un programa de Leandro (no se qué) que semitransparenta un Form de modo que se vean nítidamente los controlos y demás pero el fondo del form sea semitransparente. Pero tengo que decir que no comprendo el código completo. Tuve que modificarlo porque su código degradaba el form en dos colores sin opción o propiedad 'set' para cambiar dichos colores o ponerlo todo a un solo color. También hace poco también puse un ejemplo muy sencillo para convertir una imagen en blanco y negro con GDI. Poniendo lo básico, sin florituras.

Estas cosas:
AddHandler, Task, WithEvents, RaiseEvent ,IsNullOrWhiteSpace, InvokeRequired

todavía no se como van, es nuevo para mí, tendré que mirar uno por uno para poder entender el código y conseguir lo que busco.

Intentaré conseguir lo más básico y simple posible y luego lo colgaré.

Sl2






Eleкtro

#7
Cita de: okik en  3 Julio 2015, 14:18 PMNo trabajo para ninguna empresa ni tengo intención de ello, ni creo que pueda.

No te preocupes, la mayoría de usuarios (y moderadores) tampoco trabajamos para empresas, si lo hicieramos probablemente no tendriamos tiempo para pasarnos a ayudar por aquí a los demás, cómo es el caso de algún que otro moderador que si se dedica a la programación profesional y que ya no se le ve el pelo por el foro...




Cita de: okik en  3 Julio 2015, 14:18 PMB. Acabo de empezar con VB.NET hace como un par de meses o tres, más o menos.
Empecé tonteando un poco para adaptarme al entorno, del cual solo he usado seguramente como el 2% de lo que tiene.

Si acabas de empezar hace unos meses entonces no has podido llegar a tocar ni un 0,2% en ese tiempo. No exagero, creeme, la librería de classes de .Net Framework es colosalmente extensa, más de lo que te puedes imaginar, igual que todos los conceptos que se pueden aprender.




Cita de: okik en  3 Julio 2015, 14:18 PMEstas cosas:
AddHandler, Task, WithEvents, RaiseEvent ,IsNullOrWhiteSpace, InvokeRequired

todavía no se como van, es nuevo para mí, tendré que mirar uno por uno para poder entender el código y conseguir lo que busco.

La declaración AddHandler asocia un evento a un método.

La declaración RemoveHandler desaasocia un evento de un método.

La declaración RaiseEvent dispara un evento.

El keyword WithEvents indica que el objeto declarado puede disparar eventos, por ende, esto posibilita que se pueda usar directamente el keyword Handles para declarar el evento que controla un método (ej: sub metodo() Handles evento; Esto así mismo evita la necesitad de llenar el código con las sentencias AddHandler y RemoveHandler, queda muy feo cuando no es necesario hacerlo.

La extensión o función String.IsNullOrWhiteSpace determina si un string es nulo, vacío, o solo contiene espacios en blanco.

El método Threading.Tasks.Task.Factory.StartNew invoka un método encapsulado en un delegado o expresión Lambda, en un nuevo hilo (thread).

La propiedad Control.InvokeRequired determina si un control debe ser invocado, esto será así siempre que se intente llamar al control desde un hilo distinto al hilo donde se creó el control, de lo contrario, si no se invoca en dicha condición, se producirá una excepción de tipo Cross-Thread Exception.




Citarbuscando información sobre GDI, que siempre aparecen ejemplo de programas completos y bastante complejos.

Bueno, ese argumento es discutible, por que GDI/GDI+ de por si ya es algo complejo según se mire, hay características muy sencillas pero también otras muchas que se dificultan.




Cita de: okik en  3 Julio 2015, 14:18 PMHace poco modifiqué un programa de Leandro (no se qué) que semitransparenta un Form de modo que se vean nítidamente los controlos y demás pero el fondo del form sea semitransparente.

Pero tengo que decir que no comprendo el código completo. Tuve que modificarlo porque su código degradaba el form en dos colores sin opción o propiedad 'set' para cambiar dichos colores o ponerlo todo a un solo color.

Un consejo:
Olvida todos esos hacks para hacer transparente o semi-transparente un Form, WinForms no fue pensado ni está capacitado (de forma natural) para ese tipo de cosas, la transparencia y WinForms se llevan muy mal.

Todo ese tipo de códigos "transparentes" provocan un efecto muy negativo en la app, ya que ralentizan el form (todo lo que compone el form, sus controles), y mucho más si en dicho código se ua el hack de suplantar la función CreateParams para reducir el flickering. Si hicieses cualquier tipo de test de rendimiento en una app "transparente" (el tiempo que tarda un RichTextBox en mostrar X cantidad de caracteres por ejemplo) te dará resultados nefastos, y, si eres tan meticuloso (o tiquismiquis) cómo yo en ese sentido, entonces no querrás volver a hacer transparente una app utilzando ese tipo de técnicas esotéricas.

Confórmate con la manera natural de hacer transparente las cosas, ajustando la propiedad TransparencyKey.

Si quieres hacer algo más del estilo de ese tipo de códigos que mencionas, entonces olvida WinForms y ponte a programar en tecnología WPF, que está considerablemente más extendido en ese sentido, y en todos los demás sentidos también, ya que WPF es el sucesor de WinForms, y WPF sigue estando en desarrollo/actualización por parte de Microsoft, cosa que WinForms no.




Cita de: okik en  3 Julio 2015, 14:18 PMporque en el momento que se me ocurre algo y quiero hacer una modificación, puede resultar o bien que  la modificación produzca un error que me obliga a modificar todo  o empezar casi desde el principio por incompatibilidad o bien haya pasado tanto tiempo desde que revisé el código que ya no recuerdo ni lo que hice y no se lo que hacía esto o aquello, sobre todo con códigos muy grandes.

Y por supuesto mi me memoria es pésima, cuando dejo de usar algo se me olvida, y es muy práctico tener un código de ejemplo para cuando lo necesite.

Existe algo llamado lineas de comentario (o documentación), aplícalo a tus códigos y no deberías tener problemas de memoria en el futuro :P, preferiblemente la documentación XML de .Net + la característica IntelliSense en la IDE o unas llamadas al Object Inspector, con eso es imposible perderte en códios grandes que estén XML-documentados.

En el código de ejemplo que publiqué arriba puedes ver un ejemplo de documentación XML para un método y sus parámetros:

Citar
Código (vbnet) [Seleccionar]
   ''' ----------------------------------------------------------------------------------------------------
   ''' <summary>
   ''' Releases unmanaged and - optionally - managed resources.
   ''' </summary>
   ''' ----------------------------------------------------------------------------------------------------
   ''' <param name="isDisposing">
   ''' <c>True</c> to release both managed and unmanaged resources;
   ''' <c>False</c> to release only unmanaged resources.
   ''' </param>
   ''' ----------------------------------------------------------------------------------------------------
   Protected Sub Dispose(ByVal isDisposing As Boolean)
      ...
   End Sub

La documentación XML además también te permite añadir ejemplos de código con los tags: <example><code>CÓDIGO AQUÍ</code></example>, y muchas cosas más.

No se si lo he dejado del todo claro, pero por si no lo has pillado lo diré con otras palabras:
Cuando pasas el puntero del mouse por el nombre de un miembro en la IDE y te sale un tooltip con una descripción del miembro y de sus parámetros y tal, pues eso es lo que se consigue con la documentación XML, además la misma documentación también sirve para crear el archivo de referencia de una API, es decir, se documenta con XML los miembros de una librería .dll y se refleja toda esa información al compilar la dll en un archivo de ayuda (.chm, .html, pdf, etc).




Cita de: okik en  3 Julio 2015, 14:18 PMTengo cientos de plantillas de código simple y ejemplos sólo de VB, los cuales hacen lo básico y lo importante. Por supuesto son modificables y ajustables  a la necesidades del programa.

Quizás te pueda interesar este hilo:

Librería de Snippets para VB.Net !! (Compartan aquí sus snippets)




CitarTan sólo quiero:

Form1 (o cualquier otro, o módulo)
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
-Llama a la función y la URL
-Recibir información de descarga mientras se produce
-Opción cancelar
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
              ▲
               •
               •
               •
              ▼
Bloque de código aparte
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
- Función de descarga con la URL  
- Obtener información de descarga
▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀

Por lo tanto como ejemplo y como base, tan solo necesito un label el cual va a recibir la información del porcentaje, todo lo demás es irrelevante.

Bien, ¿pero hay algún problema con eso?, ¿el código que te mostré no te ha servido?.

Saludos!








okik

#8
CitarSi acabas de empezar hace unos meses entonces no has podido llegar a tocar ni un 0,2% en ese tiempo. No exagero, creeme, la librería de classes de .Net Framework es colosalmente extensa, más de lo que te puedes imaginar, igual que todos los conceptos que se pueden aprender.

Manuel :  Madre mía, el tren habrá pasado a la velocidad de la luz por lo menos
Jose:  No creo que haya pasado a esa velocidad, esos trenes lo máximo a lo que pueden ir es a 320 km/h

Evidentemente, es un decir, una forma de hablar. En el ejemplo de arriba Manuel quiere decir que el tren iba muy rápido y en mi caso que he usado muy poco.  Entiendo que como moderador hayas cogido "vicios" y puntillees  todo, pero esto, es demasiado.

CitarLa declaración AddHandler asocia un evento a un método.
La declaración RemoveHandler desaasocia un evento de un método.
La declaración RaiseEvent dispara un evento.

Si ya lo pone en el MSDN, en la ayuda de VB.NET incluso con ejemplos, pero ¿Cómo se usan? A eso me refiero con que tengo que mirármelo. Está bien que lo pongas, pero es innecesario, "El objeto Array permite la creación de matrices de cualquier tipo de datos" ¿Si yo no se usar un Array o lo que es esto me ayuda en algo?, No, vale, sabrá que "permite la creación de matrices de cualquier tipo de datos" pero ya está.  Se lo que es un array, y poniéndome en el lugar de otra persona que no lo sepa, no veo en qué le puede ayudar esa definición. De todos modos, se mirar el MSDN, hasta ahí llego. De hecho el código de descarga que dices que tiene "conflictos de convención", lo he sacado de ahí.

Código (vbnet) [Seleccionar]
      '  Sample call : DownLoadFileInBackground2 ("http:' www.contoso.com/logs/January.txt")
       Public Shared Sub DownLoadFileInBackground2(ByVal address As String)

           Dim client As WebClient = New WebClient()

           '  Specify that the DownloadFileCallback method gets called
           '  when the download completes.
           AddHandler client.DownloadFileCompleted, AddressOf DownloadFileCallback2
           '  Specify a progress notification handler.
           AddHandler client.DownloadProgressChanged, AddressOf DownloadProgressCallback
                       Dim uri as Uri = New Uri(address)
           client.DownloadFileAsync(uri, "serverdata.txt")
       End Sub



Private Shared Sub UploadProgressCallback(ByVal sender As Object, ByVal e As UploadProgressChangedEventArgs)

   '  Displays the operation identifier, and the transfer progress.
   Console.WriteLine("{0}    uploaded {1} of {2} bytes. {3} % complete...", _
    CStr(e.UserState), e.BytesSent, e.TotalBytesToSend, e.ProgressPercentage)
End Sub
Private Shared Sub DownloadProgressCallback(ByVal sender As Object, ByVal e As DownloadProgressChangedEventArgs)

   '  Displays the operation identifier, and the transfer progress.
   Console.WriteLine("0}    downloaded 1} of 2} bytes. 3} % complete...", _
    CStr(e.UserState), e.BytesReceived, e.TotalBytesToReceive, e.ProgressPercentage)
End Sub




CitarOlvida todos esos hacks para hacer transparente o semi-transparente un Form, WinForms no fue pensado ni está capacitado (de forma natural) para ese tipo de cosas, la transparencia y WinForms se llevan muy mal.

Lo de esos "hacks", que no se a que viene lo de "hack". Ya que, que yo sepa hack, viene de "to hack into a computer" que es "Entrar ilegalmente en un ordenador". Pero bueno, la filología inglesa no es mi fuerte.
Lo de usar GDI para semitransparentar el Form, no lo he dicho, pero era en VB6. Creí lo  entenderías pues ya te comenté que yo soy de los que han pasado de VB6 a VB.Net.

Citar
Existe algo llamado líneas de comentario (o documentación)

Como Moderador Global supongo que habrás visto algunas de mis respuestas a otros usuarios, especialmente en VB6 ya que en .net creo que solo he respondido como loguear una web y clicar un botón de una web desde nuestro programa. Puede que alguna cosilla más. Verás que he usado "líneas de comentario" pero, aún así cuando el programa es grande a veces puede ser todo muy confuso aún con las líneas de comentarios. Sobre todo cuando se trata de algoritmos para solucionar problemas matemáticos en las que se usan muchas variables y he usado nombres breves. Si que puedo poner:
'A es esto
'B es cual

Pero se te hace eterno hacer el programa, solo pongo comentarios generales y no puntuales. También ocurre que hay cosas que me parecen muy obvias para hacer comentario en ese momento, pero que con el tiempo se olvidan. Además hay cosas que es difícil de transcribir de lenguaje de programación a lenguaje coloquial.  Pero bueno que si tu no tienes problemas con eso me parece fantástico, pero no es mi caso.

Citar"Tengo cientos de plantillas de código simple y ejemplos sólo de VB, los cuales hacen lo básico y lo importante. Por supuesto son modificables y ajustables  a la necesidades del programa."

Con este comentario,  me refería a VB6, y la mayoría de ellas son creadas por mí (y con sus líneas de comentario). Ahora lo estoy haciendo  con vb.net por eso  te digo que me tengo que mirar lo AddHandler y lo demás, pero no las definiciones que me producen urticaria en la mayoría de los casos, si no para hacerme ejemplos que yo entienda y sin florituras.


CitarBien, ¿pero hay algún problema con eso?, ¿el código que te mostré no te ha servido?

Sinceramente, no. La razón es que 'contamina' el código del Form, que como he dicho yo programo por bloques y dichos bloques se comunican pero no se entremezclan, por lo menos eso intento.  Además, es demasiado extenso. Pero como esto es público, seguro a otro usuario le sirve

Otra razón es que no entiendo una porra del código, y no voy a usar un código que no entiendo, por lo menos saber lo que hace, exactamente, sobre todo si contamina mi código (el que no he puesto). Y no lo que hace en conjunto, sino cada cosa por separado.  Saber lo que hace no es poder decir "La declaración AddHandler asocia un evento a un método." si no poder  usarlo yo mismo conscientemente de lo que hago. Yo no puedo saber que es un array y alguien decirme "El objeto Array permite la creación de matrices de cualquier tipo de datos.". Esto no me ayuda, ni me dice nada, sabiendo que es un array y como se usa, poniéndome en el lugar de quien no lo sabe no veo como esta definición le puede aclarar nada. Creo que se me entiende.

Si yo programo visualbasicestilizado (¿era así?)  tu programas ceestilizado y en C voy más perdido que un gato.

Citar
{
.UseDefaultCredentials = Trae
}
¿En serio? {} esto para qué?


Puedo usar cosas que no se como funcionan, pero si está por separado y realiza una acción determinada. Por ejemplo, puedo tener un módulo que convierte una imagen BMP en JPG, no saber como lo hace, pero llamarlo desde el Form:

Evento_Click
Call ConvertImage(E:\Imagen.bmp", "E:\Imagen.jpg")
Fin Evento

Esto NO contamina el Form ni el código que yo he ingeniado tan sólo llama a la función ConvertImage para convertir la imagen. No creo que sea tan difícil de entender.


Estos días he estado con otras cosas y todavía no he  estado mucho con VB.Net,  ya lo miraré. Que quiere decir, ya lo miraré...

Sl2

Eleкtro

#9
Bueno, chico, ya que desprecias mis comentarios y mi ayuda hasta el punto de habertelo tomado todo mal (o incluso erroneo) sin sentido alguno, y ya que crees saberlo todo (incluso el significado de un hack en el sentido o contexto expuesto, cuanto te falta aprender), y ya que el código que te mostré supuestamente según tú juicio es "contaminante" por que te parece procedural al estilo C (algo ridículo decir eso, cómo todo lo demás, pero bueno), pues creo que estás más que capacitado para apañartelas tu solito y tus equivocadas ideas sin que yo pierda el tiempo en explicarte ningún punto más, ya que aparte de moderador, usuario o programador, primero soy persona, y cómo persona se me hinchan los huevos al ver gente así de desagradecida creyendo tener la razón en todo con ese orgullo, así vas a ir muy mal, pero bueno ya te tropezarás tu solito con las piedras por el camino sin que nadie te venga advirtiendo (por tu bien) de lo que haces mal y lo que debes cambiar o mejorar, o el por qué de las cosas.

Ale, saludetes.