Obtener el índice de un elemento obtenido con Split

[okik]

Quiero obtener el índice de un elemento obtenido con Split utilizando IndexOf pero no lo consigo.

Si hago esto:

Código (vbnet) [Seleccionar] Expandir

Dim P As String() = {"[Primero]", "a", "b", "c", "[Segundo]"}
       MessageBox.Show(CStr(P.ToList.IndexOf("[Segundo]")))

Me devuelve el índice correctamente.


Si hago esto otro:

Código (vbnet) [Seleccionar] Expandir

Dim P As New List(Of String)
       P.AddRange({"[Primero]", "a", "b", "c", "[Segundo]"})
       MessageBox.Show(CStr(P.IndexOf("[Segundo]")))

También me devuelve el índice correctamente

Sin embargo con un array obtenido con Split no funciona, me devuelve -1.

Código (vbnet) [Seleccionar] Expandir

       

Dim Texto As String =
              "[Primero]" & Environment.NewLine &
              "a" & Environment.NewLine &
              "b" & Environment.NewLine &
              "c" & Environment.NewLine &
              "[Segundo]"

       Dim P As New List(Of String)
       P.AddRange((Texto.ToString.Trim.Split(CChar(Environment.NewLine))))

       MessageBox.Show(CStr(P.IndexOf("[Segundo]")))
       MessageBox.Show(CStr(P(4)))


No acabo de entender porqué si al llamarlo con P(4), si que me devuelve el valor. O sea que el elemento está en la lista P, sin embargo no me devuelve el índice.

Gracias



Conseguí hacerlo:

Código (vbnet) [Seleccionar] Expandir

       Dim Texto As String =
              "[Primero]" & Environment.NewLine &
              "a" & Environment.NewLine &
              "b" & Environment.NewLine &
              "c" & Environment.NewLine &
              "[Segundo]"

       Dim spl() As String = Texto.Split(CChar(Environment.NewLine))
       Dim Lista As New List(Of String)
       For Each Item As String In spl
               Lista.Add(Item.Trim)
       Next

       MessageBox.Show(Lista.IndexOf("[Segundo]").ToString)

Pero sigo si entender porque no puedo obtenerlo directamente como puse antes o usando directamente el array String:

Código (vbnet) [Seleccionar] Expandir

Dim spl() As String = Texto.Split(CChar(Environment.NewLine))
       MessageBox.Show(spl.ToList.IndexOf("[Segundo]").ToString)

Parece que Split devuelve los valores con espacios, de ahí que haya añadido Trim, para eliminar los caracteres de espacio.

Si lo pusiera así:

Código (vbnet) [Seleccionar] Expandir

 
...
For Each Item As String In spl
           Lista.Add(Item)
       Next
       MessageBox.Show(Lista.IndexOf("[Segundo]").ToString)

me devolvería -1 nuevamente.



Encontré otra solución para quien le sirva. Consiste en reemplazar el espacio de cada elemento, sin necesidad de crear otro array

Código (vbnet) [Seleccionar] Expandir

        Dim Texto As String =
            "[Primero]" & Environment.NewLine &
            "a" & Environment.NewLine &
            "b" & Environment.NewLine &
            "c" & Environment.NewLine &
            "[Segundo]"

       Dim spl() As String = Texto.Split(CChar(Environment.NewLine))
       For Index As Integer = 0 To spl.Count - 1
           spl(Index) = spl(Index).Trim
       Next
       MessageBox.Show(spl.ToList.IndexOf("[Segundo]").ToString)


Lo suyo sería poder hacerlo todo en la misma línea, en esta:

Código (vbnet) [Seleccionar] Expandir

Dim spl() As String = Texto.Split(CChar(Environment.NewLine))



Vale, pues este sería otro modo más reducido. Usando  Regex

Código (vbnet) [Seleccionar] Expandir

       Dim Texto As String =
            "[Primero]" & Environment.NewLine &
            "a" & Environment.NewLine &
            "b" & Environment.NewLine &
            "c" & Environment.NewLine &
            "[Segundo]"
       Dim spl() As String = System.Text.RegularExpressions.Regex.Split(Texto, Environment.NewLine)
       MessageBox.Show(spl.ToList.IndexOf("[Segundo]").ToString)

[Eleкtro]

Sin embargo con un array obtenido con Split no funciona, me devuelve -1.

Código (vbnet) [Seleccionar] Expandir

       Dim Texto As String =
              "[Primero]" & Environment.NewLine &
              "a" & Environment.NewLine &
              "b" & Environment.NewLine &
              "c" & Environment.NewLine &
              "[Segundo]"

       Dim P As New List(Of String)
       P.AddRange((Texto.ToString.Trim.Split(CChar(Environment.NewLine))))

       MessageBox.Show(CStr(P.IndexOf("[Segundo]")))
       MessageBox.Show(CStr(P(4)))

No acabo de entender porqué si al llamarlo con P(4), si que me devuelve el valor.

No te funciona por que el texto que buscas y el que crees que devuelve el índice 4 no es "[Segundo]", sino LINEA VACÍA + "[Segundo]", es decir, lo que haces de forma incorrecta es partir la cadena de texto, puesto que estás añadiendo lineas en blanco, no tiene más misterio ...todas esas soluciones que encontraste usando RegEx y etc. son innecesarias, puesto que el único fallo que tuviste fue no darte cuenta de cual era el problema real.

La solución es muy sencilla, puedes utilizar el overload de la función String.Split() en donde puedes especificar el parámetro StringSplitOptions para eliminar lineas en blanco sobrantes:

Código (vbnet) [Seleccionar] Expandir

P.AddRange((Texto.Split({ControlChars.NewLine}, StringSplitOptions.RemoveEmptyEntries)))

Te dejo el ejemplo completo (usando la sintaxis compatible con VB 14):

Código (vbnet) [Seleccionar] Expandir

Dim str As String =
"[Primero]
a
b
c
[Segundo]"

Dim strList As New List(Of String)
strList.AddRange((str.Split({ControlChars.CrLf}, StringSplitOptions.RemoveEmptyEntries)))

MessageBox.Show(CStr(strList.IndexOf("[Segundo]")))
MessageBox.Show(String.Format("""{0}""", strList(4)))

Saludos!

[okik]

Genial @Elektro, pues no tenía ni idea de StringSplitOptions.RemoveEmptyEntries y mira que estuve mirando a ver si había algo pero nada.

Pues ya me lo apunto y le quito el regex al programa que estaba haciendo..



Ya no hace falta que añada el list

Código (vbnet) [Seleccionar] Expandir

        Dim Texto As String =
           "[Primero]" & Environment.NewLine &
           "a" & Environment.NewLine &
           "b" & Environment.NewLine &
           "c" & Environment.NewLine &
           "[Segundo]"
        Dim spl() As String = Texto.Split({Environment.NewLine}, StringSplitOptions.RemoveEmptyEntries)
        MessageBox.Show(spl.ToList.IndexOf("[Segundo]").ToString)


No encontraba la forma porque la clave está en ponerlo entre corchetes {Environment.NewLine}, entonces la función Split si que ya te ofrece la opción de añadir StringSplitOptions

[Eleкtro]

la clave está en ponerlo entre corchetes {Environment.NewLine}, entonces la función Split si que ya te ofrece la opción de añadir StringSplitOptions

Sé que este tema ya ha quedado solucionado pero me gustaría comentarte algo que podría serte de utilidad en el futuro.

Efectivamente ese overload solo acepta un {Array} de caracteres y/o de strings, no acepta un string individual, yo por eso utilizo las siguientes extensiones (ATENCIÓN, PROPAGANDA GRATUITA ) que puedes encontrar en mi set de librerías ElektroKit para acomodar diferentes situaciones de uso en la vida real:

Código (vbnet) [Seleccionar] Expandir

''' <summary>
''' Contains custom extension methods to use with the <see cref="System.String"/> type.
''' </summary>
<ImmutableObject(True)>
<HideModuleName>
Public Module StringExtensions

       ''' <summary>
       ''' Splits a string into substrings that are based on the specified string.
       ''' </summary>
       <DebuggerStepThrough>
       <Extension>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public Function Split(ByVal sender As String,
                             ByVal separator As String,
                             ByVal options As StringSplitOptions) As String()

           Return sender.Split({separator}, options)

       End Function

       ''' <summary>
       ''' Splits a string into a maximum number of substrings based on the specified string.
       ''' </summary>
       <DebuggerStepThrough>
       <Extension>
       <EditorBrowsable(EditorBrowsableState.Always)>
       Public Function Split(ByVal sender As String,
                             ByVal separator As String,
                             ByVal count As Integer,
                             ByVal options As StringSplitOptions) As String()

           Return sender.Split({separator}, count, options)

       End Function

End Module

Lo puedes copiar y pegar y listo (o puedes ignorar lo que te digo xD), siempre viene bien tener utensilios así a mano. En el código he eliminado toda la documentación adicional (que es mucha) de los parámetros y etc. para que no se haga tediosa la lectura.

Como puedes ver, esas funciones no hacen nada más lejos que llamar a las funciones originales de .NET Framework pero pasando el string como array (así que no hay que preocuparse por un error humano por mi parte).

Ejemplo de uso:

Código (vbnet) [Seleccionar] Expandir

Dim str As String = "Hello" & Environment.NewLine & "World"
Dim arr As String() = str.Split(ControlChars.NewLine, StringSplitOptions.RemoveEmptyEntries)

For Each item As String In arr
   Console.WriteLine(item)
Next

y:

Código (vbnet) [Seleccionar] Expandir

Dim str As String = "Hello" & Environment.NewLine & Environment.NewLine & "World"
Dim arr As String() = str.Split(ControlChars.NewLine, 3, StringSplitOptions.None)

For Each item As String In arr
   Console.WriteLine(item)
Next

¡Un saludo!