Modificar registro de windows a 64 bits

[Tomas1982]

Estoy tratando de modificar una clave de registro en windows 10 64b,

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows

pero la que me modifica es esta otra

HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows
NT\CurrentVersion\Windows

como pudiera solucionar este problema
Este es el código

Código (vbnet) [Seleccionar] Expandir


My.Computer.Registry.SetValue("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows", "Spooler", "no,")

Saludos y gracias ante todo...

[okik]

Tienes que compilar el programa como aplicación de 64bits.

Supongo que lo debes tener en AnyCPU, pues lo cambias a x64.




En propiedades del proyecto, ves a 'COMPILAR' o 'BUILD' en inglés y luego en CPU selecciona x64


por cierto, deberías quitar la coma en "no,"



Por curiosidad ¿Para qué este cambio? ¿para que és "Spooler"?

Código [Seleccionar] Expandir

My.Computer.Registry.SetValue("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows", "Spooler", "no")

[Eleкtro]

Hola.

En realidad no es necesario que modifiques las propiedades de tu proyecto para compilarlo explicitamente a arquitectura de 64 Bits, puedes seguir compilando a modo neutral ("AnyCPU", con o sin preferencia por 32 Bits) o incluso a arquitectura x86. Simplemente debes dejar de utilizar los métodos de la infraestructura My, ya que son miembros con limitaciones, destinados a ser usados para tareas básicas que no requieran un control avanzado.

En su lugar, puedes usar la class Microsoft.Win32.RegistryKey, en la que podrás especificar el modo de representación del registro (32/64 Bit):

Código (vbnet) [Seleccionar] Expandir

Dim root As RegistryHive = RegistryHive.LocalMachine
Dim subkey As String = "SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows"
Dim value As String = "spooler"
Dim data As String = "no"

Using key As RegistryKey = RegistryKey.OpenBaseKey(root, RegistryView.Registry64)
   key.CreateSubKey(subkey, RegistryKeyPermissionCheck.ReadWriteSubTree).
       SetValue(value, data, RegistryValueKind.String)
End Using

Si en el algoritmo de arriba modificas RegistryView.Registry64 por RegistryView.Registry32, entonces escribirá el valor en la clave HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows NT\CurrentVersion\Windows. Teoricamente esto que acabo de decir no debería tener ningú efecto si inicias el executable compilado bajo un Windows de 32 Bits, me refiero, elijas el modo/visor que elijas el valor siempre se debería escribir en la clave HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows bajo un Windows de 32 Bits.

Saludos!

Por curiosidad ¿Para qué este cambio? ¿para que és "Spooler"?

El término spooler suele hacer referencia a la cola de impresión de la impresora, eso debería dar una pista junto al valor asignable yes/no. Yo tampoco se exactamente para que sirve ese cambio, no lo he buscado (seguro que habrá miles de resultados en Google xD), pero supongo que servirá para simular que no haya impresora conectada, o algo relacionado.

Saludos!

[okik]

En realidad no es necesario que modifiques las propiedades de tu proyecto para compilarlo explicitamente a arquitectura de 64 Bits

Respetando las formas del usuario que ha usado My, en tal caso debe compilar como x64. Que tras probar su ejemplo comprobé que era por eso, por compilar como AnyCPU. En realidad, esa es la razón por la cual  se modifica esta clave

HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows
NT\CurrentVersion\Windows

y no esta otra

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows

como  pregunta @Tomas1982

El término spooler suele hacer referencia a la cola de impresión de la impresora, eso debería dar una pista junto al valor asignable yes/no. Yo tampoco se exactamente para que sirve ese cambio, no lo he buscado (seguro que habrá miles de resultados en Google xD), pero supongo que servirá para simular que no haya impresora conectada, o algo relacionado.

Sí, lo busqué en Google, pero lo que he encontrado efectivamente hace referencia a la cola de impresión, como dices, pero me sale en otros puntos de registro sin el valor "spooler" y no en [..\CurrentVersion\Windows], además de hacer referencias a servicios de impresora. Por defecto está en Yes, pero vamos, ni idea de para qué.

El servicio de cola de impresión se llama Spooler, y el proceso del servicio es [C:\Windows\System32\spoolsv.exe]. Tras deshabilitar este servicio el valor seguía en YES. Así que probé con gpedit.msc, estuve habilitando y deshabilitando valores relacionados con la impresión y el registro no cambiaba el valor.

[Tomas1982]

OkiK:  Lo que me recomendaste me pincho elegante, pero estuve viendo la opción que propone Elektro y me parece que me va mejor.

Pregunto: esta variante me permitiera con un if utilizar  RegistryView.Registry64 o RegistryView.Registry32 en dependencia del SO 32 o 64.

En cuanto al ejemplo que pone Elektro me da 2 errors 

RegistryKey.OpenBaseKey Me dice que no es un miembro de Microsoft.Win32.RegistryKey y
(root, RegistryView.Registry64) Me dice que no esta declarado.   

[okik]

Hola

No se si @Elektro te responderá a si que a ver si este cambio te sirve.
(no te servirá por la razón que verás más abajos - usas Net Framework anterior a 4.0-)

Código (vbnet) [Seleccionar] Expandir


            Dim ClaveRaíz As Microsoft.Win32.RegistryHive = Microsoft.Win32.RegistryHive.LocalMachine    ' HKEY_LOCAL_MACHINE
       ' Crea un puntero de clave de Registro para HKEY_LOCAL_MACHINE en la máquina actual
       Dim Clave = Microsoft.Win32.RegistryKey.OpenBaseKey(ClaveRaíz, Microsoft.Win32.RegistryView.Registry64) '<-- Para x64


       Dim Dato As Byte() = New Byte() {&H43, &H61, &H63, &H61, &H72, &H72, &H75,
                        &H74, &H61, &H20, &H64, &H65, &H20, &H70,
                        &H6F, &H6C, &H6C, &H6F}

       ' Crea las claves y valores en la localización especificada
       Using key As Microsoft.Win32.RegistryKey = Clave.CreateSubKey("SOFTWARE\CacarrutaDePollo\",
                                                     Microsoft.Win32.RegistryKeyPermissionCheck.ReadWriteSubTree)

           key.SetValue("Valor_DWORD", 1, Microsoft.Win32.RegistryValueKind.DWord) 'Valor DWORD
           key.SetValue("Valor_Binario", Dato, Microsoft.Win32.RegistryValueKind.Binary) 'Valor Binario
           key.SetValue("Valor_String", "Hola mundo", Microsoft.Win32.RegistryValueKind.String) 'Valor String
       End Using




OpenRemoteBaseKey es para un equipo remoto.

Código (vbnet) [Seleccionar] Expandir

   Dim Clave = Microsoft.Win32.RegistryKey.OpenRemoteBaseKey(ClaveRaíz, Environment.MachineName, RegistryView.Registry64) '<-- Para x64

Lo de que Microsoft.Win32 no está declarado es porque debes importar la clase primero.

Código [Seleccionar] Expandir

Imports  Microsoft.Win32

Código (vbnet) [Seleccionar] Expandir


Imports Microsoft.Win32

Public Class Form1

   Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
   End Sub

   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
       Dim ClaveRaíz As RegistryHive = RegistryHive.LocalMachine    ' HKEY_LOCAL_MACHINE
       ' Crea un puntero de clave de Registro para HKEY_LOCAL_MACHINE en la máquina actual
       Dim Clave = RegistryKey.OpenBaseKey(ClaveRaíz, RegistryView.Registry64) '<-- Para x64


       Dim Dato As Byte() = New Byte() {&H43, &H61, &H63, &H61, &H72, &H72, &H75,
                        &H74, &H61, &H20, &H64, &H65, &H20, &H70,
                        &H6F, &H6C, &H6C, &H6F}

       ' Crea las claves y valores en la localización especificada
       Using key As RegistryKey = Clave.CreateSubKey("SOFTWARE\CacarrutaDePollo\",
                                                     RegistryKeyPermissionCheck.ReadWriteSubTree)

           key.SetValue("Valor_DWORD", 1, RegistryValueKind.DWord) 'Valor DWORD
           key.SetValue("Valor_Binario", Dato, RegistryValueKind.Binary) 'Valor Binario
           key.SetValue("Valor_String", "Hola mundo", RegistryValueKind.String) 'Valor String
       End Using
   End Sub

End Class


O bien ponerlo como te lo he puesto yo

Código (vbnet) [Seleccionar] Expandir

               Dim ClaveRaíz As Microsoft.Win32.RegistryHive = Microsoft.Win32.RegistryHive.LocalMachine
...



He estado mirando la razón por la cual te aparece el error de que OpenBaseKey no es miembro de Microsoft.Win32.RegistryKey

Eso es debido a que estás usando .Net Framework anterior 4.0. Si usas Framework 3.5 por ejemplo solo dispones de la función OpenRemoteBaseKey.

Usando Framework 3.5 lo he estado testando y puedes hacerlo de la siguiente manera usando OpenRemoteBaseKey en lugar de OpenBaseKey:

Código (vbnet) [Seleccionar] Expandir

   
       Dim ClaveRaíz As Microsoft.Win32.RegistryHive = Microsoft.Win32.RegistryHive.LocalMachine    ' HKEY_LOCAL_MACHINE
       ' Crea un puntero de clave de Registro para HKEY_LOCAL_MACHINE en la máquina actual
       Dim Clave = Microsoft.Win32.RegistryKey.OpenRemoteBaseKey(ClaveRaíz,
                                                                 Environment.MachineName) '<-- Para x64 '<-- Para x64


       Dim Dato As Byte() = New Byte() {&H43, &H61, &H63, &H61, &H72, &H72, &H75,
                        &H74, &H61, &H20, &H64, &H65, &H20, &H70,
                        &H6F, &H6C, &H6C, &H6F}

       Clave.CreateSubKey("SOFTWARE\CacarrutaDePollo").
           SetValue("Valor_DWORD", 1, Microsoft.Win32.RegistryValueKind.DWord)

       Clave.CreateSubKey("SOFTWARE\CacarrutaDePollo").
           SetValue("Valor_Binario", Dato, Microsoft.Win32.RegistryValueKind.Binary)

       Clave.CreateSubKey("SOFTWARE\CacarrutaDePollo").
           SetValue("Valor_String", "Hola mundo", Microsoft.Win32.RegistryValueKind.String)

      Clave.Close()



con Using;

Código (vbnet) [Seleccionar] Expandir

Imports Microsoft.Win32

Public Class Form1
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
  Dim ClaveRaíz As RegistryHive = RegistryHive.LocalMachine    ' HKEY_LOCAL_MACHINE
       ' Crea un puntero de clave de Registro para HKEY_LOCAL_MACHINE en la máquina actual
       Dim Clave = RegistryKey.OpenRemoteBaseKey(ClaveRaíz, Environment.MachineName) '<-- Para x64
       Dim Dato As Byte() = New Byte() {&H43, &H61, &H63, &H61, &H72, &H72, &H75,
                        &H74, &H61, &H20, &H64, &H65, &H20, &H70,
                        &H6F, &H6C, &H6C, &H6F}

       ' Crea las claves y valores en la localización especificada
       Using key As RegistryKey = Clave.CreateSubKey("SOFTWARE\CacarrutaDePollo\",
                                                     RegistryKeyPermissionCheck.ReadWriteSubTree)

           key.SetValue("Valor_DWORD", 1, RegistryValueKind.DWord) 'Valor DWORD
           key.SetValue("Valor_Binario", Dato, RegistryValueKind.Binary) 'Valor Binario
           key.SetValue("Valor_String", "Hola mundo", RegistryValueKind.String) 'Valor String
       End Using

 End Sub
 End Class



ACCESO AL REGISTRO MEDIANTE VBSCRIPT

VBScript está obsoleto y como nos ha mostrado @Elektro Net dispone de funciones para acceder al registro.  Sin embargo si lo prefieres puedes usar VBScript, que además es compatible con cualquier versión de Framework que uses incluso el 2.0.

La verdad es que quise hacerlo como lo hacía en VB6, per no funciona en modo Option Sctrit en ON. No encontré nada de nada por mucho que busqué, pero sí un método para poder ejecutar funciones  de VBScript en Net y con Option Strict activado y con System.Reflection.

Aplicando dicho método he creado el siguiente código:

Código (vbnet) [Seleccionar] Expandir


Option Strict On

Imports System.Runtime.InteropServices
Imports System.Reflection

Public Class Form1
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
       Dim Shell As Object = Nothing
       Dim WSHType As Type = Type.GetTypeFromProgID("WScript.Shell")
       If Not WSHType Is Nothing Then
           Shell = Activator.CreateInstance(WSHType)
       End If
       If Not Shell Is Nothing Then
           'Introduce un dato en el valor predeterminado de la clave
           WSHType.InvokeMember("RegWrite", BindingFlags.InvokeMethod Or BindingFlags.Public Or BindingFlags.Instance, Nothing, Shell,
  New String() {"HKEY_LOCAL_MACHINE\SOFTWARE\MiClave\", "Dato_Predeterminado", "REG_SZ"})

           'Crea un Valor String
           WSHType.InvokeMember("RegWrite", BindingFlags.InvokeMethod, Nothing, Shell,
                                New String() {"HKEY_LOCAL_MACHINE\SOFTWARE\MiClave\Valor_String",
                                 "Hola mundo",
                                 "REG_SZ"})

           'Crea un Valor EXPAND
           WSHType.InvokeMember("RegWrite", BindingFlags.InvokeMethod, Nothing, Shell,
           New String() {"HKEY_LOCAL_MACHINE\SOFTWARE\MiClave\Valor_EXPAND",
             "Hola mundo",
             "REG_EXPAND_SZ"})

           'Crea un valor DWORD
           WSHType.InvokeMember("RegWrite", BindingFlags.InvokeMethod, Nothing, Shell,
              New String() {"HKEY_LOCAL_MACHINE\SOFTWARE\MiClave\Valor_DWORD",
                "25",
                "REG_DWORD"})

           Marshal.ReleaseComObject(Shell)
       End If


   End Sub
End Class



Sólo que no tengo muy claro que marcador de enlace usar. He usado BindingFlags.InvokeMethod, podría usar BindingFlags.Public o BindingFlags.Instance, y muchos más.

Además se pueden combinar

Código (vbnet) [Seleccionar] Expandir

           WSHType.InvokeMember("RegWrite",
                                BindingFlags.InvokeMethod Or
                                BindingFlags.Public Or
                                BindingFlags.Instance, Nothing, Shell,
       New String() {"HKEY_LOCAL_MACHINE\SOFTWARE\MiClave\Valor_String", "Hola mundo", "REG_SZ"})


El inconveniente son los datos binarios que sólo admite 4 valores "43 61 63 61" por ejemplo. Quizás si que se pueda añadir más, no se. La forma de escribir los datos binarios es extraña. Hay que invertir los valores y unirlos, formando un nuevo valor hexadecimal compuesto por los anteriores e invertido -->61636143. Luego hay que convertirlo a un valor decimal entero 1633902915 y este dato es el que se escribe en el registro, pero quedará registrado como "43 61 63 61".

Código (vbnet) [Seleccionar] Expandir


Option Strict On

Imports System.Runtime.InteropServices
Imports System.Reflection

Public Class Form1
   Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
       Dim Shell As Object = Nothing
       Dim WSHType As Type = Type.GetTypeFromProgID("WScript.Shell")
       If Not WSHType Is Nothing Then
           Shell = Activator.CreateInstance(WSHType)
       End If
       If Not Shell Is Nothing Then
           'Crea un valor Binario
           Dim Dato As Byte() = New Byte() {&H43, &H61, &H63, &H61}
           Dim InvertByte As String = Nothing
           For N As Integer = 0 To 3
               InvertByte = CStr(Conversion.Hex(Dato(N))) & InvertByte '&H61636143
           Next N

           Dim intValueBinary As Integer = Convert.ToInt32(InvertByte, 16) ' -->1633902915
           WSHType.InvokeMember("RegWrite", BindingFlags.InvokeMethod, Nothing, Shell,
              New Object()  {"HKEY_LOCAL_MACHINE\SOFTWARE\MiClave\Valor_Binario",
                intValueBinary,
                "REG_BINARY"})

           Marshal.ReleaseComObject(Shell)

       End If
   End Sub
End Class



Para leer usar RegRead

Código (vbnet) [Seleccionar] Expandir

     
    Dim Shell As Object = Nothing
       Dim WSHType As Type = Type.GetTypeFromProgID("WScript.Shell")
       If Not WSHType Is Nothing Then
           Shell = Activator.CreateInstance(WSHType)
       End If
       If Not Shell Is Nothing Then
           Try
               MessageBox.Show(CStr(WSHType.InvokeMember("RegRead",
                                                         System.Reflection.BindingFlags.InvokeMethod,
                                                         Nothing,
                                                         Shell,
                      New String() {"HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProductName"})))
               System.Runtime.InteropServices.Marshal.ReleaseComObject(Shell)
           Catch ex As Exception
               MessageBox.Show("no hay ningún valor")
           End Try
       End If





No hace falta  decir que también se puede hacer, aunque innecesariamente, con funciones API,

[Tomas1982]

Mi hermano me resulto de mucho lo que me facilitaste.

[okik]

Se me ha olvidado comentar que con VBScript para modificar claves protegidas hay que cambiar a X64 en 64bits como comenté en un principio. Por ejemplo si se quiere añadir un valor a:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion

De lo contrario se creará en:

HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion

Si no se quiere hacer esto pues hay que hacer lo que comentó @Elektro y usar
la clase Microsoft.Win32. A no ser que alguien conozca alguna forma, yo he estado probando sin éxito.


chau

[Eleкtro]

Respetando las formas del usuario que ha usado My, en tal caso debe compilar como x64. Que tras probar su ejemplo comprobé que era por eso, por compilar como AnyCPU.

Hola.

Pero vamos a ver, ¿yo hablo en Chino y no se me entiende?, jeje  . Como ya mencioné, los miembros de My.Computer.Registry son limitados, poco o nada personalizables, motivo por el cual esa metodología no funcionará;
una solución sería reemplazar su uso por la class Microsoft.Win32.RegistryKey, metodología que si funcionará indiferentemente de la arquitectura del ensamblado... siempre y cuando se le especifique apropiadamente el visor del registro como en el primer ejemplo que ya proporcioné en mi primer comentario. Ahí dejé un código perfectamente funcional, deberías probarlo antes de desconfiar, descartar y/o criticar que sea un código capaz de resolver el problema... macho.

ACCESO AL REGISTRO MEDIANTE VBSCRIPT

Disculpa por la siguiente corrección que voy a hacerte Okik, de verdad no lo hago a mala fe como si estuviese molestado por lo que he comentado arriba ni nada parecido, solo que considero que esto que voy a decir puede servir de ayuda para que un programador pueda aprender a diferenciar correctamente lo que está haciendo y así esa persona pueda hablar con la propiedad de la palabra en el futuro:

Ese bloque de código que has proporcionado no es VBScript, es VB.NET, ya que para elaborar el código estás usando el lenguaje VB.NET, estás compilando bajo .NET Framework, y estás corriendo código .NET administrado, excepto por que estás creando una instancia de un objeto COM, "WScript.Shell" (código no administrado), pero esto no convierte ese bloque de código en algo que se le pueda llamar VBS, más que nada por que ese código en VBS no lo puedes compilar, ni tampoco estás hibridando el código .NET con VBS, sino que simplemente estás usando un objeto COM que estamos acostumbrados a ver y utilizar en VBS, pero nada más, y esto es una diferencia muy importante.



@Tomas1982

Me he perdido en el hilo y ya no tengo demasiado claro si sigues teniendo algún problema o no, puesto que el compañero Okik parece que ya te resolvió todas o casi todas las dudas. Si falta algo por aclarar le echaré un ojo a este hilo de vez en cuando.

En general te diré que para utilizar ciertos miembros y classes, primero y según las circunstancias deberás añadir una referencia al ensamblado correspondiente (en el explorador de soluciones click derecho en donde pone "Referencias" > "Añadir Referencia" y entonces eliges el archivo.dll), y segunda y opcionálmente puedes utilizar la sentencia Imports (using en C#) para importar el espacio de nombres que contiene esa class y/o también para crear un Alias y así acortar el nombre, por ejemplo:

Código (vbnet) [Seleccionar] Expandir

Imports Microsoft.Win32
Imports Reg = Microsoft.Win32.Registry

Public Class Class1

   ' Simplemente te muestro tres maneras de hacer lo mismo:
   Sub Method()
       Microsoft.Win32.Registry.SetValue(...) ' Especificando el espacio de nombres completo.
       Registry.SetValue(...) ' Especificando solamente el nombre de la clase.
       Reg.SetValue(...) ' Especificando el Alias.
   End Sub

End Class

Dicho esto, cabe mencionar que algunos miembros solo están disponibles en las versiones más actuales de .NET Framework. Si te encuentras con un problema que consiste en que para poder importar una class y/o utilizar uno de sus miembros necesitas usar la versión 4.0 (o superior) de .NET Framework, entonces simplemente hazlo a menos que exista algún buen motivo que te impida hacerlo, ya que esa es la linea recta y más directa para resolver el problema, de lo contrario, si no haces eso, te encontrarás con la ineludible necesidad de buscar tediosas alternativas poco "naturales" como puedes comprobar en la investigación del compañero Okik con las alternatvas que te proporcionó (me refiero, eso es lo que uno puede tratar de hacer si uno no está dispuesto a compilar para .NET Framework 4.0), cuando simplemente podrías modificar el framework objetivo en las propiedades de tu proyecto a .NetFx 4.0 o superior y así ponerle una solución mucho más sencilla y amistosa al problema actual.

¡Un saludo a los dos!

[okik]

Disculpa por la siguiente corrección que voy a hacerte Okik, de verdad no lo hago a mala fe como si estuviese molestado por lo que he comentado arriba ni nada parecido, solo que considero que esto que voy a decir puede servir de ayuda para que un programador pueda aprender a diferenciar correctamente lo que está haciendo y así esa persona pueda hablar con la propiedad de la palabra en el futuro:

Ese bloque de código que has proporcionado no es VBScript, es VB.NET, ya que para elaborar el código estás usando el lenguaje VB.NET, estás compilando bajo .NET Framework, y estás corriendo código .NET administrado, excepto por que estás creando una instancia de un objeto COM, "WScript.Shell" (código no administrado), pero esto no convierte ese bloque de código en algo que se le pueda llamar VBS, más que nada por que ese código en VBS no lo puedes compilar, ni tampoco estás hibridando el código .NET con VBS, sino que simplemente estás usando un objeto COM que estamos acostumbrados a ver y utilizar en VBS, pero nada más, y esto es una diferencia muy importante.

Sea como fuere es una forma de correr VBS en NET y compatible con Option Strict ON. No se cual es el problema, ni a que viene la corrección, si es que eso es una corrección. Claro, convierto una sentencia VBScript  en un objeto ¿y qué? ¿Cual es el problema? ¿qué hay que corregir?

Ya expliqué que de forma clásica, es decir como en VB6 no era compatible con Optin Sctrict ON y que encontré la forma de hacerlo de otra manera ¿Cuál es el problema?

Es una forma de correr esto:

Código (vbnet) [Seleccionar] Expandir


Option Strict Off
...

Set WSH = CreateObject("Wscript.Shell")
x = WSH.RegWrite("HKEY_LOCAL_MACHINE\Software\Prueba\", "Dato", "REG_SZ")



WshShell Object

chau