Modificar ejecutable VisualBasic en la instalación

[dust564]

Llevo varios días con una idea rondando la cabeza, pero por mucho que he buscado no he encontrado como hacerlo.

Tengo una aplicación (ya completamente funcional) hecha en Visual Basic con Visual Studio 2012 que requiere para varias funciones un número de cuatro dígitos que viene ya en el ejecutable, pero me gustaría que éste fuese distinto en cada instalación pero sin almacenarlo en un archivo o en el registro.

No sé si me explico. Poniendo un ejemplo:

Tengo una aplicación que al abrirla muestra un Label en el que pone "0000", lo que en el código sería así:

Código [Seleccionar] Expandir

Label1.Text = "0000"

Y la idea es que a la hora de instalarlo en el ordenador ese número cambie por uno aleatorio, de forma que una vez abierta mostrase un texto distinto en cada ordenador:

PC1: 1234
PC2: 5678

La duda es si esto se puede hacer y cómo...

Salu2

[nolasco281]

Hola podrías usar la función random para que te genere un número Aleatorio
Acá un ejemplo

Código (vbnet) [Seleccionar] Expandir

Dim numeroAleatorio As New Random()
Label1.Text = System.Convert.ToString(numeroAleatorio.Next)

También puedes usar rangos etc

Código (vbnet) [Seleccionar] Expandir


'Rango de 1000 a 10,000
Dim rnd1 As New Random()
Dim N As Integer = rnd1.Next(1000, 10000)
'Console.WriteLine("{0:0000}", N)
RadLabel39.Text = "PCI: " + N.ToString

'Genera números aleatorios de 4 dígitos desde 0 a 9999
Dim rnd1 As New Random()
Dim N As Integer = rnd1.Next(9999)
'Console.WriteLine("{0:0000}", N)
RadLabel39.Text = "PCI: " + N.ToString

También puedes ver Rnd y Randomize en msdn.

Saludos.

Pd: Si no es lo que buscas seguro alguien te ayuda.

[Eleкtro]

¿Por qué tienes pegas con almacenar la configuración en un archivo?, una solución sería hacer lo que te comentó @nolasco281, pero usando la infraestructura Settings para que la aletoriedad se produzca una única vez por instalación.

Ej:

Código (vbnet) [Seleccionar] Expandir

If Not My.Settings.IsRandomized Then
  My.Settings.RandomValue = ' Generar valor aleatorio
  My.Settings.IsRandomized = True
End If

lbl.text = My.Settings.RandomValue.ToString

Teniendo en cuenta que esos datos se guardan en un archivo de configuración pero es la solución menos compleja, de lo contrario las opciones que te quedan son llamar a la app mediante argumentos para pasarle un número específico (para esto debes controlar los argumentos desde la app, e iniciar la app desde la consola o un acceso directo para pasarle dicho número), automatizar la compilación de la app en tiempo de ejecución desde el instalador (editando previamente "X" valor estático del código fuente antes de compilar, para aplicar dicha aletoriedad por instalación, claro está), o automatizar el parcheo de "X" bytes de la app compilada para modificar el valor, para esto primero debes localizar los bytes que hacen referencia a ese valor "aleatorio" en un editor hexadecimal o como veas.

En realidad ninguna de esas alternativas es dificil mientras sepas cómo hacerlo.

Saludos

[dust564]

nolasco281: Como generar el número aleatorio ya se hacerlo, el problema es que no sé implantarlo. Aún así gracias por la contestar 

Eleкtro: El motivo por el que tengo pegas para almacenar el número en un archivo de configuración... es que ese número es el que utiliza el programa para cifrar todos los archivos que utiliza, por eso me gustaría poder grabar un número único en cada ejecutable.

He estado viendo que se puede crear un instalador para el prograda directamente desde Visual Studio, ¿con ese instalador podría hacerlo? ¿O con que aplicación podría automatizar el parcheo...?

La situación real es esta:

Tengo un programa en varias aulas de informática para varias tareas, entre ellas evitar que ejecuten juegos. Al iniciarse, la aplicación recupera del registro la configuración (incluido si debe activarse o no) cifrada con ese número y la descifra para aplicarla. Si detecta que algún valor no está o no puede descifrarlo con la clave, bloquea el ordenador.

Hasta ahí bien, pero viene el problema. Los ordenadores comparten el mismo programa pero no las mismas restricciones, de forma que copiando los valores de registro de un ordenador con el programa desactivado y pegándolos en el ordenador bloqueado consiguen desactivar la aplicación...

Por eso me gustaría que cada ordenador (cada ejecutable, para ser exacto) tuviese una clave única, y que al copiar los valores de un ordenador a otro lo reconozca como no válido...

[Eleкtro]

Hasta ahí bien, pero viene el problema. Los ordenadores comparten el mismo programa pero no las mismas restricciones, de forma que copiando los valores de registro de un ordenador con el programa desactivado y pegándolos en el ordenador bloqueado consiguen desactivar la aplicación...

Si el problema es ese entonces la primera solución que te ofrecí de usar Settings no te serviría, ya que el archivo de configuración sigue esta estructura, donde el hash sería el mismo en cada PC:

Código [Seleccionar] Expandir

c:\Users\<username>\AppData\Local o Roaming\<companyname>\<appdomainname>_<eid>_<hash>\<verison>

Ejemplo real:

Código [Seleccionar] Expandir

C:\Users\Administrador\AppData\Local\ElektroStudios\MasterMusik_Reports.exe_Url_q2a441mf5bc330sftjmvcdv30vohiv0o\2.0.0.0\user.config

De todas formas para otras cosas te puede interesar, aquí puedes conocer más detalles de su arquitectura, aunque es un artículo bastante antiguo:
➢ Using My.Settings in Visual Basic 2005



A ver si lo he entendido bien, sino corrígeme.

Tu tienes algo PARECIDO a este ejemplo, en el código fuente:

Código (vbnet) [Seleccionar] Expandir

Dim value As Integer = 0

Select Case value

   Case Is = 0
       ' Activar aplicaciones.

   Case Is = 1
       ' Denegar aplicaciones.

   Case Else
       ' ...

End Select
(muy resumido)

¿Pero cómo decides si Value debe ser 0 o 1 al distribuirr y ejecutar el programa?, es decir, si el programa lo ejecutase yo en mi PC, ¿cómo se decide si se deben activar esas cosas que mencionas?, ¿se decide por un número?, ¿pero entonces cómo se decide el número que yo debo tener, no era aleatorio?, que lio, estoy algo espeso y no lo llego a pillar del todo.

De todas formas, ¿podrías mantener una conexión con los PCs de esas aulas? (mediante sockets), en ese caso lo que podrías hacer es administrar las activaciones de forma remota basándote en el HWID (Hardware ID) de cada equipo conectado,
de lo contrario, y si tienes acceso físico a esas aulas, entonces también puedes obtener manualmente el HWID de cada PC ejecutando un programa específico en ese PC que devuelva el HWID, es decir, obtienes los HWID de cada PC, luego creas una lista/array con los HWID predefinidos en tu código fuente y así administras las activaciones al distribuir la app, simplemente comprobando si el HWID dle equipo actual corresponde con algún HWID de la lista que compilaste.

Te dejo unas funciones que tal vez te podrían servir para pensar en algún enfoque, estas funciones sirven para obtener el identificador del procesador y de la placa base de un PC, y para cifrar un string mediante el algoritmo AES:

Código (vbnet) [Seleccionar] Expandir

   ''' <remarks>
   ''' *****************************************************************
   ''' Title : Get CPU Identifier
   ''' Author: Elektro
   ''' Date  : 03-June-2015
   '''
   ''' Required Namespaces:
   ''' <see cref="System.Management"/>
   '''
   ''' Usage Example:
   ''' Dim Value as String = GetCpuId()
   ''' *****************************************************************
   ''' </remarks>
   ''' <summary>
   ''' Gets the motherboard ID of the current computer machine.
   ''' </summary>
   ''' <returns>The motherboard ID.</returns>
   Public Shared Function GetCpuId() As String

       Using wmi As New ManagementObjectSearcher("select ProcessorID from Win32_Processor")

           Using query As ManagementObjectCollection = wmi.Get

               Return DirectCast(query(0), ManagementObject).Properties("ProcessorID").Value.ToString

           End Using

       End Using

   End Function

Código (vbnet) [Seleccionar] Expandir


   ''' <remarks>
   ''' *****************************************************************
   ''' Title : Get Motherboard Identifier
   ''' Author: Elektro
   ''' Date  : 03-June-2015
   '''
   ''' Required Namespaces:
   ''' <see cref="System.Management"/>
   '''
   ''' Usage Example:
   ''' MsgBox(GetMotherboardId)
   ''' *****************************************************************
   ''' </remarks>
   ''' <summary>
   ''' Gets the motherboard ID of the current computer machine.
   ''' </summary>
   ''' <returns>The motherboard ID.</returns>
   Public Shared Function GetMotherboardId() As String

       Using wmi As New ManagementObjectSearcher("select SerialNumber from Win32_BaseBoard")

           Using query As ManagementObjectCollection = wmi.Get

               Return DirectCast(query(0), ManagementObject).Properties("SerialNumber").Value.ToString

           End Using

       End Using

   End Function

Código (vbnet) [Seleccionar] Expandir

   ''' <remarks>
   ''' *****************************************************************
   ''' Title : AES Encryptor
   ''' Author: Elektro
   ''' Date  : 03-June-2015
   '''
   ''' Required Namespaces:
   ''' <see cref="System.IO"/>
   ''' <see cref="System.Security.Cryptography"/>
   ''' <see cref="System.Text"/>
   '''
   ''' Usage Example:
   ''' Dim encrypted As String = AESEncryptor("Hello World!", key:="My Encryption Key", size:=128)
   ''' *****************************************************************
   ''' </remarks>
   ''' <summary>
   ''' Encrypts an string using AES algorithm.
   ''' </summary>
   ''' <param name="str">The string to encrypt.</param>
   ''' <param name="key">The encryption key.</param>
   ''' <param name="size">The key size. 128, 192 or 256 bits.</param>
   ''' <param name="salt">The key salt.</param>
   ''' <param name="mode">The encryption mode.</param>
   ''' <returns>The encrypted string.</returns>
   Public Function AESEncryptor(ByVal str As String,
                                ByVal key As String,
                                ByVal size As Integer,
                                Optional ByVal salt As Byte() = Nothing,
                                Optional ByVal mode As CipherMode = CipherMode.ECB) As String

       If (size <> 128) AndAlso (size <> 192) AndAlso (size <> 256) Then
           Throw New ArgumentException(message:="Key size for this algorithm should be 128, 192 or 256.", paramName:="keySize")

       ElseIf (salt IsNot Nothing) AndAlso (salt.Length < 8) Then
           Throw New ArgumentException(message:="Salt should contain at least 8 bytes.", paramName:="salt")

       ElseIf salt Is Nothing Then
           salt = {&H49, &H76, &H61, &H6E, &H20, &H4D, &H65, &H64}

       End If

       Using crypto As Aes = Aes.Create()

           Dim pdb As Rfc2898DeriveBytes = New Rfc2898DeriveBytes(key, salt:=salt)

           crypto.KeySize = size ' 128, 192 or 256 Bits.
           crypto.Key = pdb.GetBytes(cb:=(size \ 8)) ' 16, 24, or 32 or Bytes (128, 192 or 256 Bits).
           crypto.IV = pdb.GetBytes(cb:=16) ' 16 Bytes (128 Bits).
           crypto.Mode = mode

           Using ms As New MemoryStream()

               Using cs As New CryptoStream(ms, crypto.CreateEncryptor(), CryptoStreamMode.Write)

                   Dim strBytes As Byte() = Encoding.Unicode.GetBytes(str)
                   cs.Write(strBytes, 0, strBytes.Length)
                   cs.Close()

               End Using

               Return Convert.ToBase64String(ms.ToArray)

           End Using

       End Using

   End Function

   ''' <remarks>
   ''' *****************************************************************
   ''' Title : AES Decryptor
   ''' Author: Elektro
   ''' Date  : 03-June-2015
   '''
   ''' Required Namespaces:
   ''' <see cref="System.IO"/>
   ''' <see cref="System.Security.Cryptography"/>
   ''' <see cref="System.Text"/>
   '''
   ''' Usage Example:
   ''' Dim decrypted As String = AESDecryptor("JRVQnb2q7f3BtIDaq5Tdcqu2+2GYGEMLyQrBT9mMjgw=", key:="My Encryption Key", size:=128)
   ''' *****************************************************************
   ''' </remarks>
   ''' <summary>
   ''' Decrypts a previously encrypted string using AES algorithm.
   ''' </summary>
   ''' <param name="str">The encrypted string to decrypt.</param>
   ''' <param name="key">The key used for encryption.</param>
   ''' <param name="size">The key size used for encryption. 128, 192 or 256 bits.</param>
   ''' <param name="salt">The key salt used for encryption.</param>
   ''' <param name="mode">The encryption mode.</param>
   ''' <returns>The decrypted string.</returns>
   Public Function AESDecryptor(ByVal str As String,
                                ByVal key As String,
                                ByVal size As Integer,
                                Optional ByVal salt As Byte() = Nothing,
                                Optional ByVal mode As CipherMode = CipherMode.ECB) As String

       If (size <> 128) AndAlso (size <> 192) AndAlso (size <> 256) Then
           Throw New ArgumentException(message:="Key size for this algorithm should be 128, 192 or 256.", paramName:="keySize")

       ElseIf (salt IsNot Nothing) AndAlso (salt.Length < 8) Then
           Throw New ArgumentException(message:="Salt should contain at least 8 bytes.", paramName:="salt")

       ElseIf salt Is Nothing Then
           salt = {&H49, &H76, &H61, &H6E, &H20, &H4D, &H65, &H64}

       End If

       Using crypto As Aes = Aes.Create()

           Dim pdb As New Rfc2898DeriveBytes(key, salt)

           crypto.KeySize = size ' 128, 192 or 256 Bits.
           crypto.Key = pdb.GetBytes(cb:=(size \ 8)) ' 16, 24, or 32 or Bytes (128, 192 or 256 Bits).
           crypto.IV = pdb.GetBytes(cb:=16) ' 16 Bytes (128 Bits).
           crypto.Mode = mode

           Using ms As New MemoryStream()

               Using cs As New CryptoStream(ms, crypto.CreateDecryptor(), CryptoStreamMode.Write)

                   Dim cipherBytes As Byte() = Convert.FromBase64String(str)
                   cs.Write(cipherBytes, 0, cipherBytes.Length)
                   cs.Close()

               End Using

               Return Encoding.Unicode.GetString(ms.ToArray)

           End Using

       End Using

   End Function

Saludos

[dust564]

Éste es el código que el programa lee al iniciarse y bajo el que decide si se activa o no:

Código (vbnet) [Seleccionar] Expandir


'He cambiado el nombre de los valores a otros genericos.
'La aplicacion viene desactivada por defecto.
'Password seria el codigo de cuatro digitos que decia al principio.

Dim regdat1E = My.Computer.Registry.GetValue(
    "HKEY_CURRENT_USER\Software\Mi Programa", "Entrada", Nothing)
Dim regdat1D as string
regdat1D = descifrar(Password, regdat1E)

If regdat1D = "Activado" then
''Bloque de codigo de activacion
Elseif regdat1D = "Desactivado" then
''Bloque de codigo si no hay que activar
Else
''Bloque de codigo si no hay info sobre la activacion.

La forma de desactivar el programa es abriendo el form principal del programa, desbloquearlo con la contraseña de usuario y elegir la opción de desactivar. Ésto edita la entrada del registro que indica si se activa o no al iniciarse.

Sin embargo me parece mejor idea la de administrar si se activa o no de manera remota, así que me pondré a modificar y probar. Muchas gracias Eleкtro