Envio de correo con formato

[CeLaYa]

Buenos días, estoy haciendo una página web con el VS2008 en donde tengo que enviar algunos correos, la página pide algunos datos y envia correos de avisos a algunas personas del lugar donde trabajo, hasta aqui todo va bien, la duda que tengo es ¿como le doy formato al texto del correo?, es decir, como indicar la fuente y tamaño de letra, o como incluir una tabla dentro del mensaje???

si me pudieran aclara esa duda se los agradecería, el código que uso es:

Dim strDestinatario = "cuenta@decorreo.com"
Dim clienteSMTP As New System.Net.Mail.SmtpClient

clienteSMTP.Host = "ServidorSMTP"
clienteSMTP.Port = 25
clienteSMTP.Credentials = New Net.NetworkCredential("miusuario", "mipass")

Dim Correo As New System.Net.Mail.MailMessage
Correo.To.Add(strDestinatario)
Correo.From = New MailAddress("otracuenta@decorreo.com")
Correo.Subject = "mail de prueba"
Correo.Body = "texto del correo"  <--- es aqui donde quisiera defirni tipos de letra, incluir imagenes y tablas.
clienteSMTP.Send(Correo)

el servidor al que me estoy conectando trabaja con Exchange y los correos los leo en outllok 2007

[_katze_]

Código (vbnet) [Seleccionar] Expandir

''' <summary>
   ''' para enviar mail con el servidor de hotmail
   ''' </summary>
   ''' <param name="mail">Mail del Remitente</param>
   ''' <param name="contraseña">Contraseña Del Remitente</param>
   ''' <param name="asunto">Asunto Del Mail</param>
   ''' <param name="destinatario">Mail para quien va dirigido el mail</param>
   ''' <param name="cuerpo">Cuerpo Del Mensaje</param>
   ''' <param name="File">Archivo para Enviar Adjunto al Mail</param>
   ''' <param name="smtp">Para Editar el Servidor Smtp</param>
   ''' <param name="puerto">Puerto Del Servidor Smtp es Opcional si el servidor lo requiere</param>
   ''' <remarks></remarks>
   Private Sub EnviarMail(ByVal mail As String, ByVal contraseña As String, ByVal asunto As String, ByVal destinatario As String, ByVal cuerpo As String, Optional ByVal File As String = Nothing, Optional ByVal smtp As String = "smtp.live.com", Optional ByVal puerto As Integer = 587)


       Dim servidor As New System.Net.Mail.SmtpClient

       Dim mails As New System.Net.Mail.MailMessage

       Try
           If System.IO.Path.IsPathRooted(File) Then
               Dim FileAdjunto As New Net.Mail.Attachment(File)
               mails.Attachments.Add(FileAdjunto)
           End If
           With mails
               .From = New System.Net.Mail.MailAddress(mail, mail, System.Text.Encoding.UTF8)
               .Subject = asunto
               .SubjectEncoding = System.Text.Encoding.UTF8
               .To.Add(destinatario)
               .Body = cuerpo
               .BodyEncoding = System.Text.Encoding.UTF8
               .IsBodyHtml = False
           End With
           With servidor
               .Host = smtp
               .Port = puerto
               .EnableSsl = True
               .Credentials = New System.Net.NetworkCredential(mail, contraseña)
               .Send(mails)

           End With
       Catch ex As System.Net.Mail.SmtpException
           MessageBox.Show(ex.ToString, "Envio De Mail", MessageBoxButtons.OK, MessageBoxIcon.Error)

       End Try
   End Sub

este es mi code lo que le falta seria que envie un tamaño de archivo especifico...

".IsBodyHtml = False" esta parte lo que hace es que se pueda incluir codigo html dentro del msj pues si haces un html estandar y le agregas todo lo que quieres puedes hacerlo...pues supongo que es lo que necesitas...pon isbodyhtml en true y agrega tu code en html con tamaño tipo y todo lo que quieras darle de formato al correo

[CeLaYa]

G R A C I A S !!!!! 


Funcionó a la perfección, en el cuerpo del mensaje meti el código HTML y pude crear el mensaje con tipos de letra, colores, tamaños e insertar tablas