Crear control personalizado, para mostrar una regla con zoom y pan.

[Harold23]

Hola, muy buenas tardes;

Estoy intentando crear un control personalizado en VS2017, que me permita mostrar una regla en los bordes superior e izquierdo con marcas de texto, basado en un sustema de unidades, sea milímetros o metros. He empeza tratando de crear los efectos ZOOM y PAN, dibujando un rectángulo de ejemplo, y funciona bien.

Mi idea es obtener esto(obvien el rectángulo, que lo dibujé para probar el ZOOM y PAN, pero si las líneas de referencia del cursor):



Para ello en VS he creado un proyecto de tipo UserControl, y el código que he usado es el siguiente:

Código (vbnet) [Seleccionar] Expandir

''' <summary>
''' Control personalizado para mostrar gráficos vectoriales.
''' </summary>
Public Class Canvas

    Inherits System.Windows.Forms.UserControl

#Region "Constructor"

    ''' <summary>
    ''' Constructor predeterminado del control de usuario.
    ''' </summary>
    Public Sub New()

        ' Esta llamada es exigida por el diseñador.
        InitializeComponent()

        ' Agregue cualquier inicialización después de la llamada a InitializeComponent().

        'Se asigna ciertas propiedades de inicio para el control.
        '---------

        'El control se mostrará acoplado al panel donde se desee insertar.
        Me.Dock = DockStyle.None
        'Dado que es un control para dibujar, se adiciona la propiedad de DoubleBuffer para reducir el parpadeo.
        Me.SetStyle(ControlStyles.AllPaintingInWmPaint, True)
        Me.SetStyle(ControlStyles.OptimizedDoubleBuffer, True)
        Me.SetStyle(ControlStyles.UserPaint, True)
        Me.Cursor = Cursors.Cross
    End Sub

#End Region

#Region "Variables"
    ''' <summary>
    ''' Verifica si un botón del Mouse se ha presionado dentro de un control.
    ''' </summary>
    Private _mousePress As Boolean = False
    ''' <summary>
    ''' Variable que guarda posición del Mouse en el evento Down de un control. Esto
    ''' ocurre cuando se presiona un botón del Mouse en un control.
    ''' </summary>
    Private _mouseDown_Location As PointF
    ''' <summary>
    ''' Posición actual del mouse cuando se activa el evento MouseMove.
    ''' </summary>
    Private _mousePositionMove As PointF
    Private _TraslationX_Graphics_old As Single = 0F
    Private _TraslationY_Graphics_old As Single = 0F
    ''' <summary>
    ''' Variable para guardar el valor que debe trasladarse el Objeto Graphics en el eje X, durante el Zoom
    ''' para que siempre el foco del zoom sea de acuerdo a la posición del punntero del Mouse.
    ''' </summary>
    Private _TraslationX_Graphics As Single = 0F
    ''' <summary>
    ''' Variable para guardar el valor que debe trasladarse el Objeto Graphics en el eje Y, durante el Zoom
    ''' para que siempre el foco del zoom sea de acuerdo a la posición del punntero del Mouse.
    ''' </summary>
    Private _TraslationY_Graphics As Single = 0F
    ''' <summary>
    ''' Escala de zoom que debe aplicarse en ScaleTransform del Graphics, el cual se aciva con el evento MouseWheel.
    ''' </summary>
    Private _zoom As Single = 1.0F
    ''' <summary>
    ''' Escala del zoom inmediatamente anterior del que ahora tiene la variable zoom. Esta variable siempre se calcula
    ''' en el evento MouseWheel.
    ''' </summary>
    Private _zoom_old As Single = 1.0F
    ''' <summary>
    ''' Incremento del zoom que se realiza en el evento MouseWheel.
    ''' </summary>
    Const _zoom_increment As Single = 0.1F
    ''' <summary>
    ''' Mínimo zoom que se puede aplicar a los dibujos.
    ''' </summary>
    Const _zoom_min As Single = 0.1F
    ''' <summary>
    ''' Máximo zoom que se puede aplicar a los dibujos.
    ''' </summary>
    Const _zoom_max As Single = 5.0F


#End Region

#Region "Eventos"

    Protected Overrides Sub OnPaint(e As PaintEventArgs)
        MyBase.OnPaint(e)

        Dim g As Graphics = e.Graphics

        'Envío el objeto Graphics, para que dibuje teniendo en cuenta las transformaciones.
        TransformarGraphics(g)
        DrawLineReferencieMouse(Me._mousePositionMove, g)

    End Sub

    Protected Overrides Sub OnMouseDown(e As MouseEventArgs)
        MyBase.OnMouseDown(e)
        'Se obtiene la posición actual del Mouse.
        Me._mousePositionMove = e.Location

        'Se verifica que ha presionado el botón izquierdo del Mouse.
        If e.Button = MouseButtons.Left Then
            '
            'Se verifica que no se tiene g
            If Not Me._mousePress = True Then

                Me._mousePress = True
                '
                'Obtiene las coordenadas del puntero del Mouse cuando se presionó el Mouse.
                Me._mouseDown_Location = e.Location
                Me._TraslationX_Graphics_old = Me._TraslationX_Graphics
                Me._TraslationY_Graphics_old = Me._TraslationY_Graphics
            End If

            Me.Invalidate(False)

        End If

    End Sub

    Protected Overrides Sub OnMouseMove(e As MouseEventArgs)
        MyBase.OnMouseMove(e)

        'Se obtiene la posición actual del Mouse.
        Me._mousePositionMove = e.Location

        'Se verifica que ha presionado el botón izquierdo del Mouse.
        If e.Button = MouseButtons.Left Then
            '
            'Se cambia el icono del cursor.
            Dim ms As MemoryStream = New MemoryStream(My.Resources.hold_1)
            Me.Cursor = New Cursor(ms)
            '
            'Posición actual del puntero del mouse.
            Dim mousePosNow As PointF = e.Location
            'Variable para saber cuanto debe desplazarse el objeto gráfico de acuerdo a la
            'posición guardada en el evento MouseDown y la actual en este evento.
            Dim deltaX, deltaY As Single
            'Se haya los valores de desplazamiento.
            deltaX = mousePosNow.X - Me._mouseDown_Location.X
            deltaY = mousePosNow.Y - Me._mouseDown_Location.Y
            '
            'Se obtiene DE NUEVO el desplazamiento que debe realizarse en el Objeto Graphics, teniendo en cuenta
            'el valor pasado de dichos traslados obtenidos en el el evento MouseDown+ el nuevo delta de desplazamiento
            'teniendo en cuenta de dividir dicho valor con el valor actual del zoom.
            Me._TraslationX_Graphics = (Me._TraslationX_Graphics_old + (deltaX / Me._zoom))
            Me._TraslationY_Graphics = (Me._TraslationY_Graphics_old + (deltaY / Me._zoom))
            '
            '
            'Obligo a redibujar el control.
            Me.Invalidate(False)

        End If

    End Sub


    Protected Overrides Sub OnMouseUp(e As MouseEventArgs)
        MyBase.OnMouseUp(e)
        '
        'Este evento ocurre cuando el puntero del Mouse se encuentra sobre el control
        'y soltó un botón del Mouse.
        '
        'Se indica que ya no se encuentra presionado el botón del Mouse.
        Me._mousePress = False
        'Se cambia el icono del cursor, cuando se suelta el botón del mouse que actualmente se presionaba.
        Me.Cursor = Cursors.Cross
        Me.Invalidate(False)
    End Sub

    Protected Overrides Sub OnMouseWheel(e As MouseEventArgs)

        MyBase.OnMouseWheel(e)
        '
        'Actualizo el valor del zoom actual, antes de que se calcule el nuevo en este evento.
        Me._zoom_old = Me._zoom

        'Verifico que el paso de la muesca del mouse se hace hacia arriba.(>zoom).
        If e.Delta > 0 Then
            '
            'Se incrementa el zoom, de acuerdo a la variable constante de la clase. Se
            'tiene en cuenta que no se sobrepase del mayor valor del zoom.
            Me._zoom = Math.Min(Me._zoom + _zoom_increment, _zoom_max)
        Else
            '
            'Para el caso de disminución del Mouse, establezco un mínimo valor para no tener
            'problemas de OverFlow. El mínimo valor del zoom
            Me._zoom = Math.Max(Me._zoom - _zoom_increment, _zoom_min)
        End If
        '
        'Se obtiene la posición actual del Mouse.
        Dim mousePosNow As PointF = e.Location
        'Variables para saber el valor de los deltas entre la posición actual del mouse
        'y la ubicación de la parte superior izquierda del PictureBox.
        Dim deltaX, deltaY As Single
        deltaX = mousePosNow.X - Me.Location.X
        deltaY = mousePosNow.Y - Me.Location.Y
        'Variable que guardan el valor teniendo en cuenta el zoom inmediatamente
        'anterior de los desplazamientos que sufrió el Graphics.
        Dim oldGraphicsX As Single
        Dim oldGraphicsY As Single
        oldGraphicsX = ((deltaX / Me._zoom_old))
        oldGraphicsY = ((deltaY / Me._zoom_old))
        'Variable para guardar los nuevos desplazamientos que debe sufrir el Graphics,
        'para que el centro del foco del Zoom sea la ubicación actual del Mouse.
        Dim newGraphicsX As Single
        Dim newGraphicsY As Single
        newGraphicsX = ((deltaX / Me._zoom))
        newGraphicsY = ((deltaY / Me._zoom))
        '
        'Los nuevos valores de Traslado del objeto Graphics se obtiene.
        Me._TraslationX_Graphics = newGraphicsX - oldGraphicsX + Me._TraslationX_Graphics
        Me._TraslationY_Graphics = newGraphicsY - oldGraphicsY + Me._TraslationY_Graphics

        'Se obtiene la posición actual del Mouse.
        Me._mousePositionMove = mousePosNow

        'Se obliga a redibujar el control.
        Me.Invalidate(False)

    End Sub

#End Region

#Region "Métodos"

    ''' <summary>
    ''' Realiza las transformaciones del Canvas, en este un escalamiento(zoom) y un traslado
    ''' de coordendas para que el zoom sea respecto a una posición en específica.
    ''' </summary>
    ''' <param name="canvas"></param>
    Private Sub TransformarGraphics(canvas As Graphics)

        'Borramos la superficie de dibujo y aplicacmos un color de fondo.
        canvas.Clear(Color.Black)
        'Suavizado de los pixeles para disminuir el parpadeo al redibujar.
        'canvas.PixelOffsetMode = Drawing2D.PixelOffsetMode.Half
        'canvas.InterpolationMode = Drawing2D.InterpolationMode.HighQualityBicubic
        canvas.SmoothingMode = Drawing2D.SmoothingMode.HighSpeed
        '
        'Se aplica el escalado actual del onjeto gráfico. Este valor se ajusta en el evento MouseWheel del Control de dibujado.
        canvas.ScaleTransform(Me._zoom, Me._zoom)
        '
        'Se traslada el origen de las coordenadas, para que el centro del zoom coincida
        'con la posición del mouse actual.
        canvas.TranslateTransform(Me._TraslationX_Graphics, _TraslationY_Graphics)
        '
        'Pindel para dibujado de los objetos.
        Dim pen As New Pen(Color.Red)
        'Establezco un ancho de la línea siempre de 1.5 pix, sin importar el zoom.
        pen.Width = 1.0F / Me._zoom
        'Patrón del tipo de línea a usar del Pen, con 20 pix de línea espaciadas cada 10 pix.
        Dim tipo_linea() As Single = {20, 10}
        'Asigno el tipo de línea personalizada.
        pen.DashStyle = Drawing2D.DashStyle.Custom
        'Asigno el tipo de línea.
        pen.DashPattern = tipo_linea
        pen.LineJoin = Drawing2D.LineJoin.Bevel
        'Dibuja un rectángulo de ejemplo para probar ZOOM y PAN.
        canvas.DrawRectangle(pen, 100, 150, 500, 400)

        Me.Invalidate(False)

    End Sub

    Private Sub DrawLineReferencieMouse(positionMouse As PointF, graphics As Graphics)

        graphics.PageUnit = GraphicsUnit.Pixel

        Dim pencil As New Pen(Color.White)
        Dim tipolinea As Single() = New Single() {10, 15}
        pencil.Width = 1 / Me._zoom
        pencil.ScaleTransform(Me._zoom, Me._zoom)

        pencil.DashPattern = tipolinea
        Dim width As Single = graphics.ClipBounds.Width
        Dim heigth As Single = graphics.ClipBounds.Height


        'Se dibuja la linea vertical
        graphics.DrawLine(pencil, (positionMouse.X) / Me._zoom - Me._TraslationX_Graphics, -Me._TraslationY_Graphics, (positionMouse.X) / Me._zoom - Me._TraslationX_Graphics, heigth - Me._TraslationY_Graphics)
        'Se dibuja la linea HORIZONTAL
        graphics.DrawLine(pencil, -Me._TraslationX_Graphics, positionMouse.Y / Me._zoom - Me._TraslationY_Graphics, width - Me._TraslationX_Graphics, positionMouse.Y / Me._zoom - Me._TraslationY_Graphics)

        Me.Invalidate(False)

    End Sub

#End Region
End Class

El problema es que cuando INTENTO correr el control personalizado en el proyecto de creación, no me muestra las propiedades a mano derecha y empieza a parpadear. Sé que esto pasa por el evento Paint, pero pues no se conceptualmente como solucionarlo.



De igual forma pasa, cuando intento usar el control en un proyecto de prueba, al agregarlo en el Form, se observa que parpadea, y cuando intento correr el Test, ni si quiera arranca.



Podrían ayudarme a solucionar esto. Mi idea es crea posteriormente un control para dibujar con GDI+ con sobre él, y quiero es mostrar unas reglas en dicho control en unidades varias, hacer el zoom y el pan, éstos dos últimos que ya funcionan en el ejemplo que acabé de pasar.

¿Podrían guiarme para crear dicho control personalizado, de una forma correcta?

Muchas gracias.

MOD: Etiqueta GeSHi. Imagenes adaptadas a lo permitido.

[Maurice_Lupin]

Hola,  Harold23

No he probado tu código, puedo comentarte en cuanto al parpadeo, cuando pintas directamente el control es posible notar el pintado de píxeles (por eso se ve un feo parpadeo), para evitarlo se pinta en memoria primero y luego se vuelca esto en el método paint, se le llama la técnica del double buffer.

Me parece que en vb.net es más sencillo, se puede habilitar.
https://msdn.microsoft.com/es-es/library/3t7htc9c(v=vs.110).aspx

Aquí un ejemplo completo, está en C# pero es casi lo mismo en vb.net
https://www.codeproject.com/Articles/12870/Don-t-Flicker-Double-Buffer

Saludos.

[Eleкtro]

El problema es que cuando INTENTO correr el control personalizado en el proyecto de creación, no me muestra las propiedades a mano derecha y empieza a parpadear. Sé que esto pasa por el evento Paint, pero pues no se conceptualmente como solucionarlo.

Fíjate bien en lo que haces, cuando se dispara por primera vez el evento Control.Paint de tu UserControl, entras en un círculo vicioso volviendo a disparar el mismo evento una y otra vez como un búcle infinito, esto es por culpa de las llamadas que estás haciendo a Control.Invalidate() dentro del bloque de los métodos TransformarGraphics() y DrawLineReferencieMouse(), literálmente hablando estás colapsando la cola de mensajes del control/la aplicación/el diseñador de Visual Studio, todo.

Para evitarlo sencillamente elimina las llamadas a Control.Invalidate(), a simple vista no parece ser realmente necesario, y en caso de necesitarlo pues simplemente crea una variable booleana que sirva como señal para determinar si el control necesita invalidación, de esta forma evitar entrar en ese "búcle infinito"...

Código (vbnet) [Seleccionar] Expandir

Private needsValidation As Boolean = True

Private Sub TransformarGraphics(g As Graphics)
   ' ...
   ' Aquí no es necesario hacer nada, solamente invalidarías al terminar todas las operaciones de dibujado, en el método DrawLineReferencieMouse.
   ' ...
End Sub

Private Sub DrawLineReferencieMouse(pt As PointF, g As Graphics)
   ' ...
   If (Me.needsValidation) Then
       Me.needsValidation = False
       Me.Invalidate(invalidateChildren:=False)
   Else
       Me.needsValidation = True
   End If
   ' ...
End Sub

...Tan solo te muestro cual sería una solución a ese tipo de problema, pero como ya he comentado no necesitas invalidar nada... al menos a simple vista.

Ten en cuenta también la propiedad Component.DesignMode, mediante esta propiedad deberías evaluar si tu control está siendo usado en tiempo de diseño o en tiempo de ejecución para evitar operaciones de dibujado que resulten innecesarias...

Código (vbnet) [Seleccionar] Expandir

If Not MyBase.DesignMode Then
   ' DIBUJAR
Else
   ' NO DIBUJAR
End If

Con respecto al flickering o parapadeo, bueno, las constantes e infinitas invalidaciones que haces sobre el control es lo que causa ese parpadeo, una vez lo hayas arreglado deberías dejar de sufrir más parpadeos, pero en general te diré que el doble búfer es tan solo una ayuda para reducir (que no eliminar) el flickering. No existe ninguna forma posible para erradicar por completo la posibilidad de producir flickering en WinForms/GDI/GDI+, cuanto más complejas sean las operaciones de dibujado, más alta será la probabilidad, es inevitable, aunque según en que escenario y si haces las cosas bien entonces se puede reducir el flickering hasta que parezca casi imperceptible; si eso te preocupa entonces lo más sensato que podrías hacer es migrar a la tecnología WPF, allí no tendrás ese problema.

EDITO: Ah, por cierto... en tu código no estás liberando objetos administrados que internamente generan recursos no administrados (residuos), como por ejemplo las instancias de la clase Pen.

Saludos!